 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
scott escreveu:
>> So, I don't really think you're quite there yet if this render is any
>> indication. I'm not really concerned with the shadows or caustics,
>> but with the fact that the blue glass behind comes up with almost the
>> same color after passing through the red glass:
>
> Is this one better? I think the blue shows through better now (I used
> colour picker in PSP to get the exact shade of red and blue from the
> original image).
whoa! So much friggin' better! You truly nailed it, man! Right colors
and right smooth shadows and caustics! Only one of the light box
reflections in the blue torus is coming filtered red...
did you drop the media inside the torii? Post the changes, man! if you
feel like it, that is. It's not GPL'd... :D
> For me the hardest part is getting the lighting correct now, either the
> torii are too bright or the floor is too dark in the reflections. Using
> Fresnel should give 100% reflection around the edges of the torii, so I
> don't know why the floor is coming out so dark.
Perhaps going from .5 to 1 in the fresnel block? I think I go from 0 to
1 as is?...
BTW, it's not finished yet, but perhaps you'll want to play with it
sometime. Yet another take on another Mehran Moghtadai's mentalray render:
http://i35.tinypic.com/2ll20c0.jpg
the original:
http://en.wikipedia.org/wiki/File:Glass_is_Liquide.jpg
made in Blender with the reference picture as blue print and rendered in
Lux in, so far, 4 hours on a Core 2 Duo (at work :P)
Lighting is not quite the same but worse: he seems to have gone for
surrealism as the liquid inside seems to go beyond the glass sides, like
as if molten with it...
If you're interested, I may later convert it to pov format.
--
a game sig: http://tinyurl.com/d3rxz9
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
> whoa! So much friggin' better! You truly nailed it, man! Right colors
> and right smooth shadows and caustics! Only one of the light box
> reflections in the blue torus is coming filtered red...
>
> did you drop the media inside the torii? Post the changes, man! if you
> feel like it, that is. It's not GPL'd... :D
> Perhaps going from .5 to 1 in the fresnel block? I think I go from 0 to 1
> as is?...
That's what I don't understand, Fresnel should determine the reflection %
based on the IOR and the angle, nothing else, I don't get what the other two
parameters do in this cae, or what I should set them to. I just use
reflection{1 fresnel on} for now - I hope that is physically correct.
Note this version below is not exactly the one that gave that image (I've
had a tweak with it this morning to try and get the floor reflection to
appear brighter). Anyway, here you go, for MCPOV:
#default { texture { pigment { color rgb 1 } finish { diffuse 1 ambient 0
montecarlo { mc_diffuse { 1 3 1 } } } } }
camera { angle 30 }
global_settings {
max_trace_level 100
adc_bailout 0.02
assumed_gamma 1.0
montecarlo{
mc_dof { mc_focal_distance 6 mc_lens_radius 0.002 }
}
}
// provide some ambient light...
sphere{ <0,0.5,0> 0.5
pigment {
gradient y
color_map {
[ 0.5 color rgb 0]
[ 0.8 color rgb 0 ]
[ 1.0 color rgb 1 ]
}
}
finish{ambient 2 diffuse 0}
translate <0,-0.5,0>
scale 1000
}
// background { rgb 0.0 }
#macro reflmat( fdcol )
texture {
pigment { color rgbt <0,0,0,1> }
finish {
diffuse 0 ambient .0
reflection{1 fresnel on}
conserve_energy
}
}
hollow
interior { ior 1.5 fade_color fdcol fade_power 2 fade_distance 0.002}
#end
// cena
union {
// chao
plane{ y 0
pigment { rgb 1 } finish { ambient .0 diffuse .99 }
}
// as duas semi-roscas: red (x) e blue (z)
union {
torus { 1.2,.16 reflmat( <0.15,0.45,1> ) rotate x*90
translate -y*.0 + x/3 }
torus { 2,.2 reflmat( <1,0.2,0.2> ) rotate x*90+y*90
translate -y*.4 }
translate -y/2
}
#local P1 = <-1,0,-1>;
#local P2 = < 1,0,-1>;
#local P3 = < 1,0,1>;
#local P4 = <-1,0,1>;
union{
triangle { P1,P2,P3
montecarlo { mc_portal { 6 4 1 1 } }
}
triangle { P1,P3,P4
montecarlo { mc_portal { 6 4 1 1 } }
}
#local d = 5; // Used to tweak the position of the light
scale d
translate y*4*d
translate x*0.35*d
pigment { rgb 1 }
finish { ambient 20 diffuse 0 }
}
rotate -y*30
rotate -x*30
translate z*6+y/5
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
weird. You have no filter component in the pigment, but it still filters light
as the shadows show...
I think you could also drop the DOF to bring down render times... would plain AA
be faster?
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
> weird. You have no filter component in the pigment, but it still filters
> light
> as the shadows show...
I have used fade_color inside the interior block to do the colouring.
> I think you could also drop the DOF to bring down render times... would
> plain AA
> be faster?
In MCPOV you get the DOF (and AA) for free. It's repeatedly sending rays
through the same pixel, the DOF just causes it to jitter the rays in a way
to simulate DOF rather than just plain AA.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"scott" <sco### [at] scott com> wrote:
> > weird. You have no filter component in the pigment, but it still filters
> > light
> > as the shadows show...
>
> I have used fade_color inside the interior block to do the colouring.
o_o
It`s true! Never gave much thought to it. I thought fade_color would only
affect the color of the object, not its shadows...
> > I think you could also drop the DOF to bring down render times... would
> > plain AA
> > be faster?
>
> In MCPOV you get the DOF (and AA) for free. It's repeatedly sending rays
> through the same pixel, the DOF just causes it to jitter the rays in a way
> to simulate DOF rather than just plain AA.
True too. It`s already sending a multitude of rays anyway...
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
scott schrieb:
> For me the hardest part is getting the lighting correct now, either the
> torii are too bright or the floor is too dark in the reflections. Using
> Fresnel should give 100% reflection around the edges of the torii, so I
> don't know why the floor is coming out so dark.
Looks to me like you're not getting the right illumination on your
floor, and that light intensity falls off drastically towards the
horizon...?
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
nemesis schrieb:
> Lighting is not quite the same but worse: he seems to have gone for
> surrealism as the liquid inside seems to go beyond the glass sides, like
> as if molten with it...
That's actually realistic.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
scott schrieb:
> That's what I don't understand, Fresnel should determine the reflection
> % based on the IOR and the angle, nothing else, I don't get what the
> other two parameters do in this cae, or what I should set them to. I
> just use reflection{1 fresnel on} for now - I hope that is physically
> correct.
To get physically correct results (well, as close as you get with
POV-Ray's "fresnel" feature), it should be:
reflection { 0, 1 fresnel on }
though for convenience the syntax
reflection { MAX fresnel on }
is interpreted as:
reflection { 0, MAX fresnel on }
so the syntax you use does work as well.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
clipka schrieb:
> scott schrieb:
>
>> That's what I don't understand, Fresnel should determine the
>> reflection % based on the IOR and the angle, nothing else, I don't get
>> what the other two parameters do in this cae, or what I should set
>> them to. I just use reflection{1 fresnel on} for now - I hope that is
>> physically correct.
>
> To get physically correct results (well, as close as you get with
> POV-Ray's "fresnel" feature), it should be:
>
> reflection { 0, 1 fresnel on }
>
> though for convenience the syntax
>
> reflection { MAX fresnel on }
>
> is interpreted as:
>
> reflection { 0, MAX fresnel on }
>
> so the syntax you use does work as well.
I have closely examined the code by now, to find out the following:
- The code does indeed implement the exact Fresnel equations for the
special case that the incident light is unpolarized, though I have not
the slightest clue how; the implemented function doesn't look anywhere
close to anything I've been able to find on the 'net so far. But the
values are flawless.
- when specifying "reflection{MIN,MAX fresnel on}", this will reduce the
maximum reflectivity to MAX, while at the same time increasing the
minimum reflectivity. However, MIN in this case is /not/ to be taken
literally as the minimum effective reflectivity; instead, it specifies a
kind of "zero reference" for reflectivity calculations; i.e. if the
minimum reflectivity according to the Fresnel equations would be
FRESNEL_MIN, the resulting effective minimum would be MIN +
FRESNEL_MIN*(MAX-MIN).
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
>> To get physically correct results (well, as close as you get with
>> POV-Ray's "fresnel" feature), it should be:
>>
>> reflection { 0, 1 fresnel on }
...
> - when specifying "reflection{MIN,MAX fresnel on}", this will reduce the
> maximum reflectivity to MAX, while at the same time increasing the minimum
> reflectivity. However, MIN in this case is /not/ to be taken literally as
> the minimum effective reflectivity; instead, it specifies a kind of "zero
> reference" for reflectivity calculations; i.e. if the minimum reflectivity
> according to the Fresnel equations would be FRESNEL_MIN, the resulting
> effective minimum would be MIN + FRESNEL_MIN*(MAX-MIN).
Thanks for the confirmation, it was something that was not really very clear
at all in the docs.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
