I am currently working on an image where I want some tubes to shine and glow
like neon light. I have added an image to show you the blue tubes I want to
be used as neon lights.

Anyone got a solution for good realistic neon lights? I am currently trying
to accomplish it using multiple lights in the tubes, but that increases the
rendertime bigtime too. Anyone got a better and maybe faster way to do
this?

Kind regards,
NumbC

Post a reply to this message

Attachments:
Download 'test001.jpg' (178 KB)

Preview of image 'test001.jpg'

> Anyone got a solution for good realistic neon lights? I am currently trying
> to accomplish it using multiple lights in the tubes, but that increases the
> rendertime bigtime too. Anyone got a better and maybe faster way to do
> this?

Radiosity could be worth a try. Just give them a high ambient value, so 
they'll emit light. Emitting media could be used instead of the ambient, 
would perhaps look better, but it's probably slower to render (don't 
forget to use "media on" in your radiosity-setttings).

HTH,
Florian

Post a reply to this message

NumbC nous apporta ses lumieres en ce 2005-09-07 12:19:
> I am currently working on an image where I want some tubes to shine and glow
> like neon light. I have added an image to show you the blue tubes I want to
> be used as neon lights.
> 
> Anyone got a solution for good realistic neon lights? I am currently trying
> to accomplish it using multiple lights in the tubes, but that increases the
> rendertime bigtime too. Anyone got a better and maybe faster way to do
> this?
> 
> Kind regards,
> NumbC
> 
> 
> ------------------------------------------------------------------------
> 
I'd use radiosity with a count over 300 for test, probably 1000 or more for final
render. It's 
obvioues that render time will be long. You need high count, because the tubes are
narrow and a low 
count will miss them to often leading to dark patches where it should be bright.
As the tubes are transparent, using emiting media should be considered, but this will
also increase 
rendering time.
You may want to remove or reduce the light inside that globe, it will make the light
enited by the 
tubes more visible.
Set default finish to ambient 0 with #default{finish{ambient 0}}.

Alain

Post a reply to this message

> As the tubes are transparent, using emiting media should be considered, but this
will also increase
> rendering time.
Emitting media is surprisingly fast. In the image below (of neon tubes)
http://news.povray.org/povray.binaries.images/thread/%3Cweb.42d71153a5704711500142a10%40news.povray.org%3E/?ttop=217682
&toff=100
I used an emitting media with a density map to get some variability in the
light. I also used some scene lighting to get a bit of a hazy glow in the
atmosphere around the lights.
I seem to remember it only took a few minutes, but sadly I lost the file
when my computer was replaced.
Joanne
http://www.onewhiteraven.com

Post a reply to this message

I would use MegaPov's glow feature. (Used to produce the image below which
is only partially rendered.) This was just a modification to one of the
sample scenes (written by Christoph Hormann) and the tube lights are
generated with the following code:

#version unofficial MegaPov 1.1;

#declare Brightness = 54;

#default {
  texture {
    pigment { color rgb 1.5 }
    finish { diffuse 1 ambient 0.0 }
  }
}


camera {
  location    <-92, -12, -35>
  direction   z*1.5
  right       1.33333*x
  look_at     <-73, 0.0, 0>
}



#macro Glow(Color)
  media {
    emission 1
    density {
      cylindrical
      poly_wave 5
      density_map {
        [0 rgb 0]
        [1 rgb Color]
      }
    }
    method 3
  }
#end


#declare ls = union {

  cylinder {
    <0, 0, 0> <0, 10, 0> 1
    hollow on
    pigment { rgbt 1 }
    interior { Glow(<1.0, 1, 1>*Brightness) }
    no_image
  }
  cylinder {
    <0, 0, 0> <0, 10, 0> 1
    hollow on
    pigment { rgbt 1 }
    interior { Glow(<0.1, 0.2, 1.0>*Brightness) }
    no_radiosity
  }
  rotate <-90, 0, 0>
  translate <-70, 24, 0>
}

object { ls rotate <0, -20, 0> }
object { ls rotate <0, 0, 0> }
object { ls rotate <0, 20, 0> }
object { ls rotate <0, 40, 0> }
object { ls rotate <0, 60, 0> }
object { ls rotate <0, 80, 0> }
object { ls rotate <0, 100, 0> }



Of course if you don't want simple shapes (cylinder, sphere box etc.) you
might have a bit more difficulty..

Sean

Post a reply to this message

Attachments:
Download 'glow.jpg' (53 KB)

Preview of image 'glow.jpg'

NumbC wrote:

> Anyone got a solution for good realistic neon lights? I am currently trying

I'm with everyone else:

radiosity+emitting media.

It seems your neons are torroidial, so use a torus function, something like:

#declare neon_light =
torus
{
     2, 0.1

         pigment { color rgbt 1 }
         finish { ambient 4.0 diffuse 0 reflection 0.5}
             hollow
         interior
         {
             media { emission rgb <1, 0.01, 0.001> *15

                 density
                 {
                    function { f_torus(x,y,z,2,0.05)}
                 }
             }
         }

}

The radiosity block I used:

     radiosity
     {
        pretrace_start 0.08
        pretrace_end 0.01
        low_error_factor .8
        count 100
        nearest_count 20
        recursion_limit 4
        error_bound 1
        brightness 1
        media on
     }

I'll attached a file of what this will look like. Please excuse me if 
the object looks similar. I liked it and wanted to make it look the same
(but makes a darn good demo-scene) :)

Adjust the colors in any way you wish. I chose a more typical red for 
the neon.

-- 
~Mike

Things! Billions of them!

Post a reply to this message

Mike Raiford wrote:
> NumbC wrote:
> 
>> Anyone got a solution for good realistic neon lights? I am currently 
>> trying
> 
> 
> I'm with everyone else:
> 
> radiosity+emitting media.
> 
> It seems your neons are torroidial, so use a torus function, something 
> like:
> 
> #declare neon_light =
> torus
> {
>     2, 0.1
> 
>         pigment { color rgbt 1 }
>         finish { ambient 4.0 diffuse 0 reflection 0.5}
>             hollow
>         interior
>         {
>             media { emission rgb <1, 0.01, 0.001> *15
> 
>                 density
>                 {
>                    function { f_torus(x,y,z,2,0.05)}
>                 }
>             }
>         }
> 
> }
> 
> The radiosity block I used:
> 
>     radiosity
>     {
>        pretrace_start 0.08
>        pretrace_end 0.01
>        low_error_factor .8
>        count 100
>        nearest_count 20
>        recursion_limit 4
>        error_bound 1
>        brightness 1
>        media on
>     }
> 
> I'll attached a file of what this will look like. Please excuse me if 
> the object looks similar. I liked it and wanted to make it look the same
> (but makes a darn good demo-scene) :)
> 
> Adjust the colors in any way you wish. I chose a more typical red for 
> the neon.
> 


-- 
~Mike

Things! Billions of them!

Post a reply to this message

Attachments:
Download 'neons.jpg' (9 KB)

Preview of image 'neons.jpg'

Sorry, not paying enough attention to the image you are trying to make. Glow
would only really work for spheres or cylinders. Don't think it could be
used for torus (I guess you could loop lots of spheres as done in one of
the mega pov demo scenes.)

Sean

Post a reply to this message

Thanks for the replies.

I did manage to get a fake sorta glow using emitting media, but I still
can't get the tubes to emit light. The effect I want at this point is to
have no light in the scene and use the tubes to light up.

I will spend this weekend to get better results and post them when I have
something worth showing.

Post a reply to this message

Mike Raiford <mra### [at] hotmailcom> wrote:
> I'll attached a file of what this will look like. Please excuse me if
> the object looks similar. I liked it and wanted to make it look the same
> (but makes a darn good demo-scene) :)

Glad you liked it and go ahead and use the idea ;) Love to see your end
result.

I couldn't wait until I got home so I started a new scene during my
lunchbreak at work. I have attached an example render which looks much more
promising than what I got earlier. I placed no lightsources in this scene
so the result is definately what I'm after.

And yes I know ... this sorta thing should be animated (on my to-do list)
LOL

I hope you like it and I will continue experimenting this weekend.

NumbC

Post a reply to this message

Attachments:
Download 'neon test 004.jpg' (68 KB)

Preview of image 'neon test 004.jpg'