"Kenneth" <kdw### [at] earthlinknet> wrote:
> "Kenneth" <kdw### [at] earthlinknet> wrote:
>
> > I don't know very much about HDR at all, so this might be a very naive question:
> > Is it possible to apply a HDR image to the inside of a large, hollow sphere in
> > POV, then use that (with ambient 1) to generate the photons (and reflections in
> > the glass)?
>
> OOPS--sorry. That was a real faux-pas. I was thinking of radiosity.

Hi Ken,

It certainly is possible, that is what I did for the image I posted. Assuming
your HDR image is in latitude-longitude arrangement, you can use spherical
mapping:

sphere { 0, 10000
pigment{image_map {hdr "Map.hdr" interpolate 2 map_type 1} }
finish { diffuse 0 ambient 1 }
hollow on
}

....or something to that effect. Note that you will require either POV-Ray 3.7 or
MegaPOV, ML-Pov, etc. to use HDR format images.

In can you are wondering, an example of latitude-longitude arrangment is the
same as you would see on a rectangular map of the earth. You then 'wrap' it
around the sphere.

If your HDR image is in 'light probe' or 'mirrored ball' arrangement you would
need to use a program such as HDR Shop to apply a panoramic transformation into
latitude-longitude arrangement to use it with spherical mapping. I believe
MegaPOV has a new map_type 7 you could use to allow 'light probe' arrangements.


Anyway... you can then turn on radiosity in the usual manner and your scene will
be lit by the colour values from the image file.


sooperFoX

Post a reply to this message

-----BEGIN PGP SIGNED MESSAGE-----
Hash: SHA1

Kenneth wrote:
> I don't know very much about HDR at all, so this might be a very naive question:
> Is it possible to apply a HDR image to the inside of a large, hollow sphere in
> POV, then use that (with ambient 1) to generate the photons (and reflections in
> the glass)?

That would work except that radiosity will not generate photons.

- --
William Tracy
afi### [at] gmailcom -- wtr### [at] calpolyedu

You know you've been raytracing too long when you keep a notepad and
pencil by your bed in case you wake up with a new scene idea.
    -- fish-head
-----BEGIN PGP SIGNATURE-----
Version: GnuPG v1.4.6 (GNU/Linux)
Comment: Using GnuPG with Mozilla - http://enigmail.mozdev.org

iD8DBQFHXF78KrVIcTMekC8RAuv2AJ9MjF4FczSUNzBlnk1vtvT5kfc5CgCeOMk3
sv6NACXeKlKG1TuWmyKTswI=
=fKpy
-----END PGP SIGNATURE-----

Post a reply to this message

Not Shiny

Wow, Bill's experience really shows in 1st image of this thread.

Interested in the soft shadows, I attempt duplication.
I believe this was not Bill's method for the reflection in the apparent chrome.

#declare cb_=rgb<200,200,217>/255;
light_source {<10,10,0> color cb_*.4
#if (10)
    area_light z*20,y*20, 4,4 adaptive 1 jitter orient
#end
}
light_source {<0,10,-10> color cb_*.4
#if (10)
    area_light x*20,y*20, 4,4 adaptive 1 jitter orient
#end
}
#declare cb=rgb<200,200,200>/255;
light_source {<0,50,0> color cb*.5
#if (10)
    area_light x*20,z*20, 4,4 adaptive 1 jitter orient
#end
}

only minutes to render, then AA: 2 hours for this small image

I think Bill's entire scene would be most educational.

I see no reference to felt, fuzzy or furry.
(Exception: 3.5.12.6.4  Turbulence Warp octaves (fuzzy))
Sure looks like a gray felt platform to me.

Floor ambient 0.1, real low;
for the theory that it would
allow visibility of the effect of area lighting

Post a reply to this message

Attachments:
Download 'blob3.png' (150 KB)

Preview of image 'blob3.png'

alphaQuad nous apporta ses lumieres en ce 2007/12/09 22:58:
> Not Shiny
> 
> Wow, Bill's experience really shows in 1st image of this thread.
> 
> Interested in the soft shadows, I attempt duplication.
> I believe this was not Bill's method for the reflection in the apparent chrome.
> 
> #declare cb_=rgb<200,200,217>/255;
> light_source {<10,10,0> color cb_*.4
> #if (10)
>     area_light z*20,y*20, 4,4 adaptive 1 jitter orient
> #end
> }
Adaptive is almost useless with that area_light. Try with this one:
light_source{<10,10,0>color cb_*.4
	area_light z*20,y*20 17,17 adaptive jitter orient circular
}
And compare rendering times.
> light_source {<0,10,-10> color cb_*.4
> #if (10)
>     area_light x*20,y*20, 4,4 adaptive 1 jitter orient
> #end
> }
> #declare cb=rgb<200,200,200>/255;
> light_source {<0,50,0> color cb*.5
> #if (10)
>     area_light x*20,z*20, 4,4 adaptive 1 jitter orient
> #end
> }
> 
> only minutes to render, then AA: 2 hours for this small image
Your textures are very grainy. The floor is grainy, the knot is very grainy, 
your "soft" shadow is very grainy. Consequantly, most pixels need aa.
Scaling up will stretch the grains, reducing the contrast between adjacent 
pixels, resulting in less use of the aa procedure.
> 
> I think Bill's entire scene would be most educational.
> 
> I see no reference to felt, fuzzy or furry.
> (Exception: 3.5.12.6.4  Turbulence Warp octaves (fuzzy))
> Sure looks like a gray felt platform to me.
> 
> Floor ambient 0.1, real low;
> for the theory that it would
> allow visibility of the effect of area lighting
> 
> 
> 
> 
> 
> 
> ------------------------------------------------------------------------
> 
Your area_light array is to sparse, giving you those grainy penumbraes.
The optimum adaptive arrays are: 5*5, 9*9, 17*17, 33*33, 65*65,... This is due 
in the maner that the adaptive process works. The formulae for the optimum array 
size is: 2^n +1 where "n" is at least 1 more than the adaptive value.
As the surface that receive the shadow is close to the object, you can probably 
use adaptive 0 without problem.
With adaptive 0, I regularly use arrays of 17*17 or 33*33 with render times only 
slightly longer than with point lights.

-- 
Alain
-------------------------------------------------
EVERYTHING HAS A GENDER

You may not know this but many nonliving things have a gender...

An Hourglass is Female, because over time, the weight shifts to the bottom.

Post a reply to this message

"alphaQuad" <alp### [at] earthlinknet> wrote:
> Interested in the soft shadows, I attempt duplication.
> I believe this was not Bill's method for the reflection in the apparent
> chrome.

I didn't use any light sources, only an HDR image-map on the inside of a sphere,
and radiosity. You need MegaPOV or POV-Ray3.7 to do this. See here:

http://megapov.inetart.net/manual-1.2/tutorials_hdri.html#hdri_tutorial

I used the HDR probes on the link supplied in that tutorial.

> I think Bill's entire scene would be most educational.

I'll post it tomorrow (I don't have it on this machine...)

> Floor ambient 0.1, real low;
> for the theory that it would
> allow visibility of the effect of area lighting

Ambient should usually be set to 0 really, otherwise everything looks a little
washed out. If you use radiosity, everything that has ambient > 1 will emit
light like a light source.

Bill

Post a reply to this message

"Bill Pragnell" <bil### [at] hotmailcom> wrote:
> I'll post it tomorrow (I don't have it on this machine...)

Here it is:

----------
#version unofficial megapov 1.2;
#include "shapes.inc"
#include "colors.inc"

global_settings {
  assumed_gamma 1
  radiosity {
    pretrace_start 0.08
    pretrace_end 0.0025
    count 1000
    nearest_count 4
    error_bound 0.4
    recursion_limit 2
    low_error_factor 0.5
    gray_threshold 0.0
    minimum_reuse 0.001
    brightness 1
    adc_bailout 0.01/2 } }

camera {
  location <18, 15, -40>
  up y
  right x
  angle 22
  look_at 0 }

#macro Knot(a)
  (<sin(a) + 2*sin(2*a), 1.25*sin(3*a), cos(a) - 2*cos(2*a)>)
#end

blob {
  threshold 0.9
  #local ang = 0;
  #while (ang < 2*pi)
    sphere { Knot(ang), 1.5, 0.5 }
    #local ang = ang + 0.01;
  #end
  pigment { color Black }
  finish { ambient 0 diffuse 0 reflection { 1 } } }

sphere {
  <0, 0, 0>, 1000
  pigment {
    image_map {
      hdr "uffizi_probe.hdr"
      map_type 7
      interpolate 2 } }
  finish { ambient 1 diffuse 0 } }

object {
  Round_Box_Union(<-6, -3.1, -6>, <6, -2.5, 6>, 0.25
  pigment { color Gray25 }
  finish { ambient 0 } }

Post a reply to this message

"Bill Pragnell" <bil### [at] hotmailcom> wrote:
> Here it is:

Used hdr_environment.pov for the map but changed light multipliers to 1 for this
image.



Now I hope everyone notices, a picture is worth a thousand words. Thank you
Bill.
I learned much from that. It is the language of your soul and also the language
of rapid POV instruction. Is there a reason that "Round_Box_Union" does not
turn the color of reserved words? Mpov 1.2.1

Thrown out of programming class the first day when the teaching dork said, "To
get an A in my class you must know the football scores", needless to say, I
could not remain silent.

Last night on House, oh god I relate, the dork doctor, what's his name, asked
House, "You'd prefer vicodin over the company of people? House laughs and walks
way.

So I am on my own, but full comprehension of POV scripting method is quite a
challenge without input from these kind, generous people.

I may post more on this extraordinary episode of House in off-topic as it does
not belong here.
aQ

Post a reply to this message

Attachments:
Download 'blob4.png' (45 KB)

Preview of image 'blob4.png'

Alain <ele### [at] netscapenet> wrote:
> Your area_light array is to sparse, giving you those grainy penumbraes.
> The optimum adaptive arrays are: 5*5, 9*9, 17*17, 33*33, 65*65,... This is due
> in the maner that the adaptive process works. The formulae for the optimum array
> size is: 2^n +1 where "n" is at least 1 more than the adaptive value.
> As the surface that receive the shadow is close to the object, you can probably
> use adaptive 0 without problem.
> With adaptive 0, I regularly use arrays of 17*17 or 33*33 with render times only
> slightly longer than with point lights.

Must say, thank you Alain. That explains a great deal and a picture serves
little purpose here.

Real glad that I got keyword lookup working in my compilation. It is imperative
that all reserved words are well understood before proceeding. I should take
month off to read manuals but unlikely that I will. Even if I did I doubt I
would learn this. I read area lights but don't recall such info on optimum
adaptive arrays. Seems to me adaptive 0 would be the fastest possible.

But I am impressed with the effect the HDR light emission. And slightly more
impressed with your knowledge.

Thank you so very much,
aQ


> --
> Alain
> -------------------------------------------------
> EVERYTHING HAS A GENDER
>
> You may not know this but many nonliving things have a gender...
>
> An Hourglass is Female, because over time, the weight shifts to the bottom.

Post a reply to this message

"alphaQuad" <alp### [at] earthlinknet> wrote:
> "Bill Pragnell" <bil### [at] hotmailcom> wrote:
> > Here it is:

Nice. My camera def has a square aspect ratio, so your image looks a little
stretched... alter 'right' to suit your resolution, or use a square image!
Looks like I modified that box since making the original images, too :).

> I learned much from that. It is the language of your soul and also the language
> of rapid POV instruction. Is there a reason that "Round_Box_Union" does not
> turn the color of reserved words? Mpov 1.2.1

Yes - it's not a reserved word! It's a macro in shapes.inc. Have a look at the
docs, there are many useful macros and shapes in this file:
http://www.povray.org/documentation/view/3.6.1/468/

Bill

Post a reply to this message

"sooperFoX" <bon### [at] gmailcom> wrote:

> > "Kenneth" <kdw### [at] earthlinknet> wrote:

> > > Is it possible to apply a HDR image to the inside of a large, hollow sphere in
> > > POV, then use that (with ambient 1) to generate the photons (and reflections in
> > > the glass)?
> >
> > OOPS--sorry. That was a real faux-pas. I was thinking of radiosity.
>
> Hi Ken,
>
> It certainly is possible, that is what I did for the image I posted. ...

Thank you!  That gives me a *much* better understanding of how to use this HDR
process.  Cheers!

Ken

Post a reply to this message