This has likely been asked before, and likely in a different forum,
but....

Glows were a fantastic feature of MegaPov.  I understand they weren't
"included" in Povray3.5, but has anyone come up with a way to fake them,
or recreate them accurately using just Povray3.5 code?  If so, I'd love
to hear how, and learn.  I want to stick with 3.5, but I really miss the
simplicity of "glow objects"...

-Lawrence

Post a reply to this message

Ghost <flu### [at] duratechindustriesnet> wrote:
> Glows were a fantastic feature of MegaPov.  I understand they weren't
> "included" in Povray3.5, but has anyone come up with a way to fake them,
> or recreate them accurately using just Povray3.5 code?  If so, I'd love
> to hear how, and learn.  I want to stick with 3.5, but I really miss the
> simplicity of "glow objects"...


-----------8<-----------8<-----------8<-----------8<-----------8<-----------
#macro Glow(GlowColor, Scale)
  sphere
  { 0, 1 hollow no_shadow
    pigment { rgbt 1 }
    interior
    { media
      { emission 1/Scale
        density
        { spherical density_map
          { [0 rgb 0][.5 rgb GlowColor*.5][1 rgb 1]
          }
        }
        samples 1,1 intervals 1 confidence .1
      }
    }
    scale Scale
  }
#end

camera { location -z*10 look_at 0 angle 35 }
plane { y,-2 pigment { checker rgb 1, rgb .5 } }

light_source
{ <-1.5,1,0>, <1,.5,0>
  looks_like { Glow(<1,.5,0>, .5) }
}
light_source
{ <2,.5,0>, <0,.5,1>
  looks_like { Glow(<0,.5,1>, 1) }
}
-----------8<-----------8<-----------8<-----------8<-----------8<-----------


-- 
plane{-x+y,-1pigment{bozo color_map{[0rgb x][1rgb x+y]}turbulence 1}}
sphere{0,2pigment{rgbt 1}interior{media{emission 1density{spherical
density_map{[0rgb 0][.5rgb<1,.5>][1rgb 1]}turbulence.9}}}scale
<1,1,3>hollow}text{ttf"timrom""Warp".1,0translate<-1,-.1,2>}//  - Warp -

Post a reply to this message

In article <3E9338D0.465D8046@duratechindustries.net>,
 Ghost <flu### [at] duratechindustriesnet> wrote:

> Glows were a fantastic feature of MegaPov.  I understand they weren't
> "included" in Povray3.5, but has anyone come up with a way to fake them,
> or recreate them accurately using just Povray3.5 code?  If so, I'd love
> to hear how, and learn.  I want to stick with 3.5, but I really miss the
> simplicity of "glow objects"...

They were included in the new MegaPOV, which is based on 3.5.

If you want plain official POV 3.5, the exact effect isn't possible. The 
effect glows simulated is possible by filling the scene with a thin 
scattering media and placing light sources where you want glows. This is 
actually more accurate than the glow patch, just a lot slower.

Another possibility is to put a light source in the center of a fully 
transparent sphere with a highlight. The highlight on the sphere lines 
up with the camera, making a fairly fast glow effect. This isn't perfect 
though, the sphere gets highlights from other light sources. You might 
be able to use light groups to avoid this.

You can also use spheres filled with emitting media with a spherical 
density pattern. This is fairly fast, you don't need very CPU intensive 
settings for emitting media with such a simple pattern, and you can get 
a lot of other effects with media.

And finally, you could use partially transparent textured planes or disc 
objects. This is what most lens flare includes do, in fact you might 
want to check them out. One problem: it won't look right in reflections 
or refractions...the "glows" are flat and have to be aligned to the 
point of view.

Only the first option, full-scene scattering media, actually simulates 
the same effect of the glow patch, but the other techniques are still 
useful.

-- 
Christopher James Huff <cja### [at] earthlinknet>
http://home.earthlink.net/~cjameshuff/
POV-Ray TAG: chr### [at] tagpovrayorg
http://tag.povray.org/

Post a reply to this message

On Tue, 08 Apr 2003 16:02:09 -0500, Ghost wrote:

> This has likely been asked before, and likely in a different forum,
> but....
> 
> Glows were a fantastic feature of MegaPov.  I understand they weren't
> "included" in Povray3.5, but has anyone come up with a way to fake them,
> or recreate them accurately using just Povray3.5 code?  If so, I'd love
> to hear how, and learn.  I want to stick with 3.5, but I really miss the
> simplicity of "glow objects"...
> 
> -Lawrence

My solution was to look at the entire scene through a mirror and declare 
the camera inside a macro. You would give the mirror a finish{reflection 1 
specular SomeBrightnessValue roughness GlowSize} and place light sources 
wherever you want your glows to be. I made an include file but it was 
incredibly awkward and not very accurate (since it used a plane mirror). I 
might revisit it if Real Life would ease off for a little while.

I posted an animation of my system in action a while ago:
http://news.povray.org/povray.binaries.animations/30872/?ttop=31809&toff=50

-- 
light_source#macro G(E)sphere{z+E*y*5e-3.04rotate-z*E*6pigment{rgbt#end{
20*y-10#local n=162;1}#while(n)#local n=n-.3;G(n)x}}G(-n).7}}#end//GregE

Post a reply to this message