And quality, not to forget that.

UberPOV (current release) can be very fast with subsurface scattering and
area_light, however there's a caveat.
Using all the same scene, other than changing adaptive number for area light,
there's some kind of breakdown in quality of the shadows and SSS.

Here's the image put together from 3 separate renders of a corner of the chess
set scene I've been using with camera blur, radiosity, SSS and 2 area lights
(changed adaptive of both).
Render times shown. Please be aware I resized about 30% larger to make the
differences more visible but still exist at the original size.

Bob

Post a reply to this message

Attachments:
Download 'pr3711alpha up sss arealight compared.png' (400 KB)

Preview of image 'pr3711alpha up sss arealight compared.png'

Didn't say a couple things I should have...

The only subsurface scattering object is the lower portion of chess piece. The
chess board is simply wood patterns from sample files.

And the problem I'm seeing with UberPOV area_light is about the unsmooth
shadows, which is as though keyword 'jitter' were used.
Increasing adaptive helps eliminate that but also smears the shadows, and
obviously increases render time.

Again, no changes in things like SSS sampling or anything else is done between
renders.

Bob

Post a reply to this message

Am 21.11.2016 um 00:39 schrieb omniverse:

> The only subsurface scattering object is the lower portion of chess piece. The
> chess board is simply wood patterns from sample files.
> 
> And the problem I'm seeing with UberPOV area_light is about the unsmooth
> shadows, which is as though keyword 'jitter' were used.
> Increasing adaptive helps eliminate that but also smears the shadows, and
> obviously increases render time.
> 
> Again, no changes in things like SSS sampling or anything else is done between
> renders.

I can't recreate the problem here -- neither the jitter effect, nor the
difference in the width of the shadow.

I need the scene (ideally trimmed down to the bare minimum showing the
problem).

Post a reply to this message

clipka <ano### [at] anonymousorg> wrote:
> Am 21.11.2016 um 00:39 schrieb omniverse:
>
> I need the scene (ideally trimmed down to the bare minimum showing the
> problem).

Found out what makes the change happen. Camera blur messes with both the area
light and subsurface.

Couldn't easily post all that's in the scene and include files so luckily this
was simple enough.

/* test of UberPOV area_light and adaptive.
DOF=on causes jittered area light shadows.
POV-Ray 3.7.1.1 alpha has smooth shadows. */

#version 3.7;

// features to use
#local Rad=on; // slow
#local SSS=on; // very slow
#local ArL=on; // slow
#local DOF=off; // very slow

global_settings
{
 assumed_gamma 1 // chess scene not preadjusted for srgb here
 #if (Rad=on)
 radiosity{
  recursion_limit 1
  brightness 1
  gray_threshold 0.67
  normal on
  brilliance on
 #if (SSS=on)
  subsurface on
 #end
 }
 #end
 #if (SSS=on)
 subsurface {samples 40,20}
 mm_per_unit 10
 #end
}

sky_sphere
{
 pigment
 {
  function {abs(y)}
  color_map
  {
   [0 srgb <1,0.8,0.5>]
   [0.1 srgb <0.6,0.9,1>]
   [0.2 srgb <0.5,0.8,1>]
   [0.5 srgb <0.2,0.6,0.9>]
   [1 srgb <0.1,0.5,0.9>]
  }
 }
}

plane { y, -2 pigment { srgb 1 } normal { crackle 0.7 } }

light_source
{
 -z*111, rgb <0.8,0.7,0.6>
 #if (ArL=on) // check using adaptive 3 or 4
 area_light <8,0,0>,<0,8,0>,6,6 adaptive 0 circular orient
 #end
 rotate <45,200,0>
}

light_source
{
 -z*111, rgb <0.2,0.3,0.4>
 #if (ArL=on)
 area_light <8,0,0>,<0,8,0>,4,4 adaptive 0 circular orient
 #end
 rotate <60,-30,0>
}

camera
{
 up y
 right image_width/image_height*x
 location -z*25
 look_at <0,-2,-4>
 angle 50
 #if (DOF=on)
 focal_point <0,4,4>
 aperture 1.33
 blur_samples 15,20
/* // no noticeable difference using this
 bokeh {
  pigment {
   hexagon rgb <0.5,0,0.25>, rgb <0.75,1,0>, rgb <0.25,0.75,0>
  }
 }
*/
 #end
 rotate <25,40,0>
}

sphere
{
 0, 5
 pigment
 {
  rgb <1,1,1>
 }
 finish
 {
  specular 0.5 roughness 0.05
  subsurface
  {
   translucency <1,1,1>
  }
  reflection
  {
   0, 0.5
   fresnel on
   exponent 0.8
  }
  conserve_energy
 }
}

Post a reply to this message

Am 21.11.2016 um 02:39 schrieb omniverse:

> Found out what makes the change happen. Camera blur messes with both the area
> light and subsurface.

Found the culprit.

The jitter effect is quasi-intentional (it's part of how it speeds up
stuff) and was no surprise for me.

The difference in the shadow falloff, on the other hand, is anything but
intentional, and will be fixed in the next build.

Post a reply to this message

Playing with parameters, I found out what's really making the difference for
UberPOV.

blur_samples min, max

Using only one number instead of two, 20 from maximum in this case, seems to
help smooth out shadow and subsurface dithering.

For render times are much shorter using UberPOV, except to get similar image
quality I still had to use adaptive 2 for the area lights.

And in doing that I discovered the render times to be equivalent if POV-Ray
3.7.0 official is set to adaptive 0. So this means same or very similar quality
for same render times.
Main thing being that UberPOV might be able to prove faster, albeit at some
expense of quality.

I haven't tried a variety of different settings for blur_samples and subsurface
samples so there's still some question as to which might be best for both
quality and speed.

I hope you can find something out about how area_light and camera blur might be
conflicting.

Bob

Post a reply to this message

clipka <ano### [at] anonymousorg> wrote:
> Am 21.11.2016 um 02:39 schrieb omniverse:
>
> > Found out what makes the change happen. Camera blur messes with both the area
> > light and subsurface.
>
> Found the culprit.
>
> The jitter effect is quasi-intentional (it's part of how it speeds up
> stuff) and was no surprise for me.
>
> The difference in the shadow falloff, on the other hand, is anything but
> intentional, and will be fixed in the next build.

Encouraging to hear. Posted what else I was finding from scene file changes, as
you will have seen before this.
Maybe if area light adaptive can be reduced from 2 to 1, possibly 0, that could
mean much faster render times versus official POV-Ray 3.7 and still retain
quality.

I'm going to hope so anyhow, and much good luck to you regardless of the
outcome.

Bob

Post a reply to this message