|
![](/i/fill.gif) |
#declare fuzzy_shadows=off;
#declare global_illumination=off;
global_settings{
#if(global_illumination=on)
radiosity{
count 300 error_bound .25
pretrace_start .04 pretrace_end .02
recursion_limit 1
normal on
low_error_factor 10
brightness 1
}
#end
assumed_gamma 1
photons{count 30000}
}
#default{finish{ambient 0 brilliance .7}}
camera{
fisheye
right x*.7 up y*.7
location<0,80,-80>
look_at 0
angle 20
}
background{rgb<.3 .4 .5>}
light_source{<1,2,-1>*100000,<1.3 1.25 1>*1.5 #if(fuzzy_shadows=on) area_light
x*70000,z*70000,12,12 jitter adaptive 1 orient circular #end}
light_source{<0,-1,-.5>*100000,<.3 .4 .5>*.25 shadowless
#if(fuzzy_shadows=on)area_light x*90000,z*90000,2,2 jitter adaptive 1 orient circular
#end}
#declare strands_Y=
pigment{
//cylindrical
boxed scale<1,10,1> rotate y*0
scale .75 translate .5 warp{repeat x} warp{repeat z}
frequency 3 sine_wave
//color_map{[.1 rgb 0][.3 rgb 1]}
}
#declare strands_X=
pigment{
//cylindrical
boxed scale<1,10,1> rotate y*0
rotate z*90 scale .75 translate .5 warp{repeat y} warp{repeat z}
frequency 3 sine_wave
//color_map{[.1 rgb 0][.3 rgb 1]}
}
#declare strands_Z=
pigment{
//cylindrical
boxed scale<1,10,1> rotate y*0
rotate x*90 scale .75 translate .5 warp{repeat x} warp{repeat y}
frequency 3 sine_wave
//color_map{[.1 rgb 0][.3 rgb 1]}
}
#declare rbbd=function{
pigment{
pigment_pattern{cells scale 2}
scale 2
pigment_map{
[.1 strands_Y]
[.5 strands_X]
[.9 strands_Z]
}
}
}
isosurface {
function{
max(
abs(x),
abs(y),
abs(z)
)
-9
-rbbd(x,y,z).grey
//-rbbd(z*2,y*2,x*2).grey/2
+.5
}
accuracy .01
evaluate 5, 1.2, 0.95
contained_by{box{<-10,-10,-10>,<10,10,10>}}
pigment{rgb .55}
finish{specular .85 roughness .05 brilliance 4}
hollow
rotate y*35
}
Post a reply to this message
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
"Samuel T. Benge" <stb### [at] hotmail com> wrote in message
news:405### [at] hotmail com...
> camera{
> fisheye
> right x*.7 up y*.7
> location<0,80,-80>
> look_at 0
> angle 20
> }
That's an interesting trick, I never knew you could use a fisheye lens like
that! I'm going to start using that in some of my scenes.
BTW, I've modified your definition so it takes account of the image dimensions:
camera{
fisheye
#local hyp=sqrt(image_width*image_width+image_height*image_height);
right x*image_width/hyp up y*image_height/hyp
location<0,80,-80>
look_at 0
angle 20
}
Cheers,
--
Tek
www.evilsuperbrain.com
Post a reply to this message
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
Tek wrote:
> That's an interesting trick, I never knew you could use a fisheye
> lens like that! I'm going to start using that in some of my scenes.
It's a neat trick alright, especially when you want a wide angle but
don't want heavy perspective distortions.
BTW, I used it in my animation Tunnel Ride:
http://runevision.com/3d/anims/
On the original topic - this isosurface sure is nice, and I was
surprised to see it render so fast!
Rune
--
3D images and anims, include files, tutorials and more:
rune|vision: http://runevision.com **updated Mar 9**
POV-Ray Ring: http://webring.povray.co.uk
Post a reply to this message
|
![](/i/fill.gif) |
|
![](/i/fill.gif) |
Rune wrote:
> It's a neat trick alright, especially when you want a wide angle but
> don't want heavy perspective distortions.
The fisheye lens is one of the things I like about POV. It's something
the 'big' graphics products don't give you, because they render images
not just with raytracing, but with other techniques.
> BTW, I used it in my animation Tunnel Ride:
> http://runevision.com/3d/anims/
I wish I had broadband... I'll have to take the time to download it
sometime.
> On the original topic - this isosurface sure is nice, and I was
> surprised to see it render so fast!
>
> Rune
Isn't there a 'fast isosurface' patch coming out? I can't wait for it :)
-Samuel Benge
Post a reply to this message
|
![](/i/fill.gif) |