Hallo!
The render of the image I had to propose for IRTC testing session is 
ended yesterday (I have posted a version without water).
My home hardware is a little obsolete and after a month render was at 
30%, so I've asked help to a friend with a more efficient machine, which 
completed the work in less than two weeks (ok, I need to upgrade my 
hardware).
I'm not happy of the final image because it is shady and the golden 
pieces composing the IRTC word doesn't shines as in my intention.
Sources in p.b.i.
Have a nice day,
;-)
Paolo

Post a reply to this message

Attachments:
Download 'irtc_200906_1280_aa.jpg' (176 KB)

Preview of image 'irtc_200906_1280_aa.jpg'

Paolo Gibellini <p.g### [at] gmailcom> wrote:
> Hallo!
> The render of the image I had to propose for IRTC testing session is
> ended yesterday (I have posted a version without water).
> My home hardware is a little obsolete and after a month render was at
> 30%, so I've asked help to a friend with a more efficient machine, which
> completed the work in less than two weeks (ok, I need to upgrade my
> hardware).
> I'm not happy of the final image because it is shady and the golden
> pieces composing the IRTC word doesn't shines as in my intention.
> Sources in p.b.i.
> Have a nice day,
> ;-)
> Paolo

I haven't tried to run the scene yet, but some thoughts from reading the file:

When doing water, I prefer to let the water interior do all the work:

rgbt 1.0 (completely clear)
diffuse 0.0 (if it's clear it won't do anything anyways)
use only fresnel reflection at full: reflection{0 1 fresnel on} with ior set to
1.33 (for water)

for the water colour and light fading you can use either

light fading read docs for full usage:
fade_distance (play with value that works)
fade_power (I prefer to use 1000 which kicks in the exponential function)
fade_colour (use this to control the colour of the water)

or you can use media which will give better results, but be slower.
Use absorption media with or without scattering

Here is the water I use for my BathTubs:
(http://news.povray.org/povray.binaries.images/thread/%3Cweb.494744dd800e72a4c67b294d0%40news.povray.org%3E/?ttop=30059
8&toff=50&mtop=294124)

#declare WCol=rgb <0.51373, 0.70588, 0.70588>;// Water colour, based on coastal
water
#local FD=-25/ln(0.58);  //Fade distance, alter the first number for the
distance, the odd ln(0.58) is from experimenting to emulate exponential as best
as I can.

#declare MWater=
  material{
    texture{
      pigment{rgbt 1}
      finish{conserve_energy  diffuse 0.0  ambient 0  reflection{0 1 fresnel on
metallic 0}}
    }
    interior{
      ior 1.33
      media{
        absorption rgb 1-WCol
        density{rgb 1/FD}
      }
    }
  }



-tgq

Post a reply to this message

Paolo Gibellini <p.g### [at] gmailcom> wrote:
> Hallo!
> The render of the image I had to propose for IRTC testing session is
> ended yesterday (I have posted a version without water).
> My home hardware is a little obsolete and after a month render was at
> 30%, so I've asked help to a friend with a more efficient machine, which
> completed the work in less than two weeks (ok, I need to upgrade my
> hardware).
> I'm not happy of the final image because it is shady and the golden
> pieces composing the IRTC word doesn't shines as in my intention.
> Sources in p.b.i.
> Have a nice day,
> ;-)
> Paolo

Oh, in addition to my previous post: I also prefer to not use specular,
highlights, but keep it to reflection only and provide a background to reflect.
 While the colour and depth of water is defined by the interior colouring and
fading, the surface is best defined by what it reflects, even if it is just a
cloudy sky.

-tgq

Post a reply to this message

I ran the file (without rad or photons) and noted a couple more items:

The light_source:
 light_source{<0,2,2> color rgb <1, 1, 1>}
is located inside the water and causes problems with the light_fading.  Raise it
up out above the water level.  Then increase your fade_distance in the water.  I
got the following to work nicely (other than the water may be too blue, needs
more greeniness):

#declare t_water = texture {
    pigment{rgbt 1}
    normal {
        ripples 0.25   // 0.75
        frequency 0.1
        translate <-10,0,10>
    }
    finish {
 diffuse 0.0
 ambient 0.0
        reflection {0, 1 fresnel}
        conserve_energy
    }
}

#declare i_water =interior {
    ior 1.33
    fade_distance 3
    fade_power 1000
    fade_color rgb <0.217,0.552,0.877>
}

#declare m_acqua =material {
    texture {t_water}
    interior {i_water}
}


You are also using an isosurface for your water.  While this works and gives a
nice smooth ripply surface, isosurfaces are real time killers.  The water
surface can be acheived just as well with a heightfield which will speed it up
considerably.  I tweaked and the following is somewhat equivalent to your
isosurface:
Note that isosurfaces take their function from the X-Y plane, but are created on
the X-Z plane hence the swapping of Z and Y in the function
Also note that heightfields are created 1x1x1 so the function got scaled down by
adding the *35 and then the heightfield gets scaled up after.
The 600,600 is the resolution of the heightfield and can be increased/decreased
to change quality and speed:

#local FWATER = function{1-(1-sin(x*35*2*pi))*0.01-f_noise3d(x*35,y*35,0)*0.1}

#declare water=
intersection{
  height_field{function 600,600 {pattern{function{FWATER(x,y,z)}}} smooth}
  box{0 1}
  hollow
  scale <35,4,35>
  translate <-10,-3,-10>
}


I may have a few more suggestions to come yet.

-tgq

Post a reply to this message

OK, a couple final observations:

If you do want to use the iso rather than a heightfield, I noticed that your
isosurface is clipped too high and intersects with the floor, this will get
noticeable when the light fading is working properly.  Change your contained_by
box (This is likely also increasing your render time unecessarily)
   contained_by {box {<-10,-3,-10>, < 25, 1, 25>}}


If you are not happy with the way the lightfading is working switch to media,
with scattering only it doesn't add much render time: (be sure to add "hollow"
to your isosurface or heightfield object for it to work)

#declare WCol=rgb <0.217,0.552,0.877>;
#local FD=3;
#declare i_water =interior {
    ior 1.33
      media{
        absorption rgb 1-WCol
        density{rgb -ln(0.58)/FD}
      }
}


I did some very quick time comparisons for you:

1) Original iso with fading: 56s
2) Corrected iso (as above) with fading: 40s  (big increase! doesn't have to
calculate back intersections anymore
3) Corrected iso with media: 42s (only slight increase)
4) HF (600x600) with fading: 28s  (another big decrease!)
5) HF (600x600) with media: 30s  (again, only slight increase)

Also note that changin the resoltuion of the HF only increases parse time (and
memory usage) not render time.

Hope this has all been of some help to you.

-tgq

Post a reply to this message

Paolo Gibellini wrote:
> Hallo!
> The render of the image I had to propose for IRTC testing session is 
> ended yesterday (I have posted a version without water).
> My home hardware is a little obsolete and after a month render was at 
> 30%, so I've asked help to a friend with a more efficient machine, which 
> completed the work in less than two weeks (ok, I need to upgrade my 
> hardware).
> I'm not happy of the final image because it is shady and the golden 
> pieces composing the IRTC word doesn't shines as in my intention.
> Sources in p.b.i.
> Have a nice day,
> ;-)
> Paolo
> 
> ------------------------------------------------------------------------
> 
It looks quite nice imo

Post a reply to this message

>Trevor G Quayle  on date 11/09/2009 17:04 wrote:
> OK, a couple final observations:
> 
> If you do want to use the iso rather than a heightfield, I noticed that your
> isosurface is clipped too high and intersects with the floor, this will get
> noticeable when the light fading is working properly.  Change your contained_by
> box (This is likely also increasing your render time unecessarily)
>    contained_by {box {<-10,-3,-10>, < 25, 1, 25>}}
> 
> 
> If you are not happy with the way the lightfading is working switch to media,
> with scattering only it doesn't add much render time: (be sure to add "hollow"
> to your isosurface or heightfield object for it to work)
> 
> #declare WCol=rgb <0.217,0.552,0.877>;
> #local FD=3;
> #declare i_water =interior {
>     ior 1.33
>       media{
>         absorption rgb 1-WCol
>         density{rgb -ln(0.58)/FD}
>       }
> }
> 
> 
> I did some very quick time comparisons for you:
> 
> 1) Original iso with fading: 56s
> 2) Corrected iso (as above) with fading: 40s  (big increase! doesn't have to
> calculate back intersections anymore
> 3) Corrected iso with media: 42s (only slight increase)
> 4) HF (600x600) with fading: 28s  (another big decrease!)
> 5) HF (600x600) with media: 30s  (again, only slight increase)
> 
> Also note that changin the resoltuion of the HF only increases parse time (and
> memory usage) not render time.
> 
> Hope this has all been of some help to you.
> 
> -tgq
> 
> 
> 
> 
> 

Trevor, thank you sincerely for all your work: you probably spent a lot 
of time!
Now I'm beginning to test your suggestion in a more simple scene. I will 
post the results.
Thank you again,
   ;-)
Paolo

Post a reply to this message

>Jim Charter  on date 11/09/2009 20:25 wrote:
> Paolo Gibellini wrote:
>> Hallo!
>> The render of the image I had to propose for IRTC testing session is 
>> ended yesterday (I have posted a version without water).
>> My home hardware is a little obsolete and after a month render was at 
>> 30%, so I've asked help to a friend with a more efficient machine, 
>> which completed the work in less than two weeks (ok, I need to upgrade 
>> my hardware).
>> I'm not happy of the final image because it is shady and the golden 
>> pieces composing the IRTC word doesn't shines as in my intention.
>> Sources in p.b.i.
>> Have a nice day,
>> ;-)
>> Paolo
>>
>> ------------------------------------------------------------------------
>>
> It looks quite nice imo
Thank you, Jim!
I will try now Trevor's suggestions.
;-)
Paolo

Post a reply to this message

> Hallo!
> The render of the image I had to propose for IRTC testing session is 
> ended yesterday (I have posted a version without water).
> My home hardware is a little obsolete and after a month render was at 
> 30%, so I've asked help to a friend with a more efficient machine, which 
> completed the work in less than two weeks (ok, I need to upgrade my 
> hardware).
> I'm not happy of the final image because it is shady and the golden 
> pieces composing the IRTC word doesn't shines as in my intention.
> Sources in p.b.i.
> Have a nice day,
> ;-)
> Paolo
> 
> ------------------------------------------------------------------------
> 
Did you use photons? This is a case where "caustics" can avantageously 
be used.


Alain

Post a reply to this message

It makes me unhappy, too.   ;-)

Post a reply to this message