 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Am 05.08.2013 09:03, schrieb Jaime Vives Piqueres:
> Yeah, this one looks amazing, but is even better if I hide her eyes with
> my finger... then, suddenly, the skin looks almost real, specially her
> lips.
Speaking of eyes: While that render I mentioned before is still running,
I've conjured up a procedural iris texture that will feature in a later
render.
Post a reply to this message
Attachments:
Download 'eyes.png' (566 KB)
Preview of image 'eyes.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
> Am 05.08.2013 09:03, schrieb Jaime Vives Piqueres:
>> Yeah, this one looks amazing, but is even better if I hide her eyes with
>> my finger... then, suddenly, the skin looks almost real, specially her
>> lips.
>
> Speaking of eyes: While that render I mentioned before is still running,
> I've conjured up a procedural iris texture that will feature in a later
> render.
>
It's probably one of the best iris I've ever seen, just next to some
actual iris photos...
Care to share it?
Alain
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Am 05.08.2013 23:45, schrieb Alain:
> It's probably one of the best iris I've ever seen, just next to some
> actual iris photos...
Thanks. I was actually quite surprised how easy it was to achieve.
> Care to share it?
Here it is; note that it is a UV-mapped texture designed to fit the DAZ
Genesis eyes; for other models, the main material (M_Iris) may need some
tweaking. Also note that the DAZ Genesis model has separate geometry for
the iris and the cornea; if this is not the case for your model, you
will also need to tweak the finish.
(Ah, and last not least, the slight "cat's pupil" effect in the image I
posted is in the geometry, not the material.)
--------------------------------------------------------------------
#declare P_Iris_Shadowed = pigment { color rgb 0 }
#declare P_Iris_Base = pigment {
granite
color_map {
[ 0.0 color srgb <0.4,0.5,0.3> ] // <-- primary color
[ 1.0 color srgb <0,0,0> ]
}
translate z
scale 0.5
}
#declare P_Iris_A = pigment {
P_Iris_Base
scale 0.7
warp { black_hole <0,0,0>, 1 strength 1 falloff 2 }
}
#declare P_Iris_B = pigment {
granite
pigment_map {
[ 0.0 color srgb <0.7,0.7,0.3> ] // <-- secondary color
[ 0.3 P_Iris_Base ]
}
scale 0.7
warp { black_hole <0,0,0>, 1 strength 1 falloff 2 }
}
#declare M_Iris = material {
texture {
pigment {
uv_mapping
spherical
pigment_map {
[0.2 P_Iris_Shadowed]
[0.3 P_Iris_A ]
[0.4 P_Iris_A ]
[0.5 P_Iris_B ]
[0.6 P_Iris_B ]
[0.65 P_Iris_Shadowed]
}
translate <1,1,0>
warp { repeat 2*x }
scale 0.25
}
finish { ambient 0 diffuse albedo 0.6 specular albedo 0 emission 0 }
}
}
--------------------------------------------------------------------
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 6-8-2013 4:25, clipka wrote:
> Am 05.08.2013 23:45, schrieb Alain:
>> It's probably one of the best iris I've ever seen, just next to some
>> actual iris photos...
>
> Thanks. I was actually quite surprised how easy it was to achieve.
>
>> Care to share it?
>
> Here it is; note that it is a UV-mapped texture designed to fit the DAZ
> Genesis eyes; for other models, the main material (M_Iris) may need some
> tweaking. Also note that the DAZ Genesis model has separate geometry for
> the iris and the cornea; if this is not the case for your model, you
> will also need to tweak the finish.
That's great, thanks a lot!
I shall try that with the Poser models. They have separate irises too.
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Not as easy as I thought (naively) ;-)
This is the best I can do presently using Poser's Simon, by commenting out:
[0.2 P_Iris_Shadowed]
in the material, otherwise the iris becomes totally black. Also, the
texture is not right even then.
This probably has to do with /how/ the iris is uv_mapped in the first
place. I shall have to go back to the figure and work upwards to see
where I need to tweak things.
Thomas
Post a reply to this message
Attachments:
Download 'poserfiguretest.png' (403 KB)
Preview of image 'poserfiguretest.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
For testing purposes, I used a fill-in light to lessen the shadows
around the eyes in the preceding image.
To do justice to the model /and/ to Ive's excellent skin texture macro,
this is the image /without/ the fill-in.
Thomas
Post a reply to this message
Attachments:
Download 'poserfiguretest.png' (366 KB)
Preview of image 'poserfiguretest.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Am 06.08.2013 09:54, schrieb Thomas de Groot:
> Not as easy as I thought (naively) ;-)
>
> This is the best I can do presently using Poser's Simon, by commenting out:
>
> [0.2 P_Iris_Shadowed]
>
> in the material, otherwise the iris becomes totally black. Also, the
> texture is not right even then.
>
> This probably has to do with /how/ the iris is uv_mapped in the first
> place. I shall have to go back to the figure and work upwards to see
> where I need to tweak things.
The current DAZ people use a UV mapping scheme for the eye textures that
has the irises in the bottom left and bottom right quadrant (each one
almost filling the quadrant entirely), while the sclerae separately
occupy the top left and top right quadrant.
The Poser people (at least G2) instead use a scheme where the irises sit
amid the sclerae in the left and right half of the texture; thus the
irises are at a totally different place, and also a lot smaller.
This might help to get you started:
-----------------------------------------
#declare M_Iris = material {
texture {
pigment {
uv_mapping
spherical
pigment_map {
[0.2 P_Iris_Shadowed]
[0.3 P_Iris_A ]
[0.4 P_Iris_A ]
[0.5 P_Iris_B ]
[0.6 P_Iris_B ]
[0.65 P_Iris_Shadowed]
}
scale 0.5 // <-- each copy of the iris is smaller
translate <1,2,0> // <-- iris centers are at different y
warp { repeat 2*x }
scale 0.25
}
finish { ambient 0 diffuse albedo 0.6 specular albedo 0 emission 0 }
}
}
-----------------------------------------
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Thanks Christoph, I think I got it now with the following changes:
//--------------------------------------
#declare M_Iris =
material {
texture {
pigment {
uv_mapping
spherical
pigment_map {
[0.1 P_Iris_Shadowed]
[0.2 P_Iris_A ]
[0.4 P_Iris_A ]
[0.5 P_Iris_B ]
[0.6 P_Iris_B ]
[0.65 P_Iris_Shadowed]
}
scale 0.37
translate <0.99, 2.075, 0>
warp { repeat 2*x }
scale 0.25
}
finish { ambient 0 diffuse albedo 0.6 specular albedo 0 emission 0 }
}
}
//--------------------------------------
While this works for SimonG2, tweaking may be probably be necessary for
the other figures.
Note that a brownish line around the iris may appear. This comes from
the sclera map and shows a little part of the original iris as the iris
mesh does not cover exactly the image (or vice versa). This can
relatively well be solved by scaling down and translating a tiny bit the
pigment in the sclera material. This is done in the present image.
Thomas
Post a reply to this message
Attachments:
Download 'poserfiguretest.png' (409 KB)
Preview of image 'poserfiguretest.png'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
> Am 05.08.2013 23:45, schrieb Alain:
>> It's probably one of the best iris I've ever seen, just next to some
>> actual iris photos...
>
> Thanks. I was actually quite surprised how easy it was to achieve.
>
>> Care to share it?
>
> Here it is; note that it is a UV-mapped texture designed to fit the DAZ
> Genesis eyes; for other models, the main material (M_Iris) may need some
> tweaking. Also note that the DAZ Genesis model has separate geometry for
> the iris and the cornea; if this is not the case for your model, you
> will also need to tweak the finish.
>
> (Ah, and last not least, the slight "cat's pupil" effect in the image I
> posted is in the geometry, not the material.)
>
The iris been distinct from the cornea surely play an important role in
the beleivability.
Alain
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Two more versions. I'm not sure which lighting setup I like better - but
I do know that I'd really love to have MCPov's "render until I'm ok with
the noise" mode of operation right now... and/or faster SSLT, for that
matter.
Post a reply to this message
Attachments:
Download 'young_half_elf_woman_pov_scene 2013-08-07 0925.png' (481 KB)
Download 'young_half_elf_woman_pov_scene 2013-08-08 1300.png' (950 KB)
Preview of image 'young_half_elf_woman_pov_scene 2013-08-07 0925.png'
Preview of image 'young_half_elf_woman_pov_scene 2013-08-08 1300.png'
|
|
| |
| |
|
|
|
|
| |
