Hi, I have found an interesting halo statement, which
produces a stunning fireball.
How could I convert that to a Povray's 3.6 media/interior statement?
I stripped down the original animation sequence to this:

  sphere { 0, 1
    pigment { color rgbt <1, 1, 1, 1> }
      halo {
        emitting
        spherical_mapping
        linear
        turbulence 1.5
        color_map {
          [ 0.0 color rgbt <1, 0, 0, 1> ]
          [ 0.5 color rgbt <1, 1, 0, 0.5> ]
          [ 1.0 color rgbt <1, 0, 0, 1> ]
        }
        frequency 2
        samples 20
      }
    hollow
  }

Thanks for help!

Post a reply to this message

Icetoaster <icetoaster_at_gmx.de> wrote:
> Hi, I have found an interesting halo statement, which
> produces a stunning fireball.
> How could I convert that to a Povray's 3.6 media/interior statement?

  Something like this is probably close (although probably not identical):

camera { location -z*5 look_at 0 angle 35 }

sphere
{ 0, 2 hollow
  pigment { rgbt 1 }
  interior
  { media
    { emission 1
      density
      { spherical density_map
        {
          [ 0.0 rgb <0, 0, 0> ]
          [ 0.25 rgb <.5, 0, 0> ]
          [ 0.5 rgb <1, 1, 0> ]
          [ 0.75 rgb <.5, 0, 0> ]
          [ 1.0 rgb <0, 0, 0> ]
        }
        turbulence 1.5
        frequency 2
      }
    }
  }
}


-- 
                                                          - Warp

Post a reply to this message

Thanks a lot!! Looks quite good!
It seems to be little bit asymmetric, but I guess, this will change when
I add some randomness and animation.

Icetoaster

Warp <war### [at] tagpovrayorg> wrote:
> Icetoaster <icetoaster_at_gmx.de> wrote:
> > Hi, I have found an interesting halo statement, which
> > produces a stunning fireball.
> > How could I convert that to a Povray's 3.6 media/interior statement?
>
>   Something like this is probably close (although probably not identical):
>
> camera { location -z*5 look_at 0 angle 35 }
>
> sphere
> { 0, 2 hollow
>   pigment { rgbt 1 }
>   interior
>   { media
>     { emission 1
>       density
>       { spherical density_map
>         {
>           [ 0.0 rgb <0, 0, 0> ]
>           [ 0.25 rgb <.5, 0, 0> ]
>           [ 0.5 rgb <1, 1, 0> ]
>           [ 0.75 rgb <.5, 0, 0> ]
>           [ 1.0 rgb <0, 0, 0> ]
>         }
>         turbulence 1.5
>         frequency 2
>       }
>     }
>   }
> }
>
>
> --
>                                                           - Warp

Post a reply to this message