On 19 Nov 1999 13:22:23 -0500, ing### [at] homenl (ingo) wrote:

>Peter Popov wrote:
>
>>On 19 Nov 1999 05:08:04 -0500, ing### [at] homenl (ingo) wrote:
>>
>>Will you please explain how you will animate this? Will you change the
>>value of  5° according to clock, or will you apply steps 1 to
>>11*clock?
>
>I'll vary the angle (1 - 10°) according to the clock. Not steps 1 to 
>11*clock.
>
>Ingo

Okay, I'll try to put up a #while loop to do it.


Peter Popov
ICQ: 15002700

Post a reply to this message

ingo wrote:
> 
> Peter Popov wrote:
> 
> >On Fri, 19 Nov 1999 17:19:44 +0100, Remco de Korte
> ><rem### [at] xs4allnl> wrote:
> >
> >>I don't know if I understand your method exactly but I did a similar
> >>thing with a reasonable result using sin/cos-functions. ........
> >
> >But will this keep the distance between two consequitive spheres
> >constant? I don't think so, and unless your fish is made of natural
> >rubber, it's gonna hurt big time :)
> 
> Exactly the reason why I don't want to use the sin / cos method.
> 
> Ingo
> 
> --
> Photography: http://members.home.nl/ingoogni/
> Pov-Ray    : http://members.home.nl/seed7/

How much stress will that cause?
And you're not telling me that you've never had to stretch while moving
haven't you?
Anyway, it's probably bad physics for a robot, but it works (for me) in
an image.
If the distance between sphere's really would be the problem you could
easily change your calculations to provide for that. That wouldn't
change the fact that if you had a really 3D-body there still would be
some stretching (inside vs outside of curve).

Remco

Post a reply to this message

>How much stress will that cause?
>And you're not telling me that you've never had to stretch while moving
>haven't you?
>Anyway, it's probably bad physics for a robot, but it works (for me) in
>an image.

That's true, but it's like YKYHBRTLW You create a motor using every part 
..... even the ones that don't show ..... just for authenticity. 


Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message

On 19 Nov 1999 13:22:23 -0500, ing### [at] homenl (ingo) wrote:

>Peter Popov wrote:
>
>>On 19 Nov 1999 05:08:04 -0500, ing### [at] homenl (ingo) wrote:
>>
>>Will you please explain how you will animate this? Will you change the
>>value of  5° according to clock, or will you apply steps 1 to
>>11*clock?
>
>I'll vary the angle (1 - 10°) according to the clock. Not steps 1 to 
>11*clock.
>
>Ingo

//try this

#declare Pos=array[11]

#declare i=0;
#while (i<11) #declare Pos[i]=<i,0,0>; #declare i=i+1; #end

#declare i=1;
#while (i<11)
  #declare Pos[i]=vrotate((Pos[i]-Pos[i-1]),<0,0,10*clock>)+Pos[i-1];
  #declare i=i+1;
#end
Peter Popov
ICQ: 15002700

Post a reply to this message

Peter Popov wrote:

>//try this
>
>#declare Pos=array[11]
>
>#declare i=0;
>#while (i<11) #declare Pos[i]=<i,0,0>; #declare i=i+1; #end
>
>#declare i=1;
>#while (i<11)
>  #declare Pos[i]=vrotate((Pos[i]-Pos[i-1]),<0,0,10*clock>)+Pos[i-1];
>  #declare i=i+1;
>#end

No, I'm afraid that's not what I'm looking for. What I expected to see is 
the spheres arranged in a arc, about one quarter of a circle.

mmm, all spheres end up on a circle, the length of the arcsegment between 
two spheres is known (1 in this case). The angle between the two vectors 
from the spheres to the center of the circle = 10° (when clock=1).The 
circle will always go through the origin, where the first sphere is.
With this, I think the radius and centerposition of the circle can be 
calculated. Once this circle is known, take the distance frome any sphere 
on the x-axis to the origin. Take an arcsegment of the circle with the same 
length and put the sphere there.
Would it work? I'll sleep over this and try if I can figure it out 
tomorrow.

Thanks Peter for your effort.

Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message

On 19 Nov 1999 17:52:36 -0500, ing### [at] homenl (ingo) wrote:

>No, I'm afraid that's not what I'm looking for. What I expected to see is 
>the spheres arranged in a arc, about one quarter of a circle.
>
>mmm, all spheres end up on a circle, the length of the arcsegment between 
>two spheres is known (1 in this case). The angle between the two vectors 
>from the spheres to the center of the circle = 10° (when clock=1).The 
>circle will always go through the origin, where the first sphere is.
>With this, I think the radius and centerposition of the circle can be 
>calculated. Once this circle is known, take the distance frome any sphere 
>on the x-axis to the origin. Take an arcsegment of the circle with the same 
>length and put the sphere there.
>Would it work? I'll sleep over this and try if I can figure it out 
>tomorrow.
>
>Thanks Peter for your effort.
>
>Ingo

I got your intentions wrong. This should do what you want, as
described in your original post.

#declare Pos=array[11]

#declare i=0;
#while (i<11) #declare Pos[i]=<i,0,0>; #declare i=i+1; #end

#declare i=0;
#while (i<10)
  #declare j=i+1;
  #while (j<11)
    #declare Pos[i]=
    vrotate((Pos[j]-Pos[i]),<0,0,10*clock>)+Pos[i];
    #declare j=j+1;
  #end
  #declare i=i+1;
#end

If it doesn't, I'll look at it tomorrow.


Peter Popov
ICQ: 15002700

Post a reply to this message

ingo wrote:
> 
> >How much stress will that cause?
> >And you're not telling me that you've never had to stretch while
> moving
> >haven't you?
> >Anyway, it's probably bad physics for a robot, but it works (for me)
> in
> >an image.
> 
> That's true, but it's like YKYHBRTLW You create a motor using every
> part
> ..... even the ones that don't show ..... just for authenticity.
> 
> Ingo
> 
> --
> Photography: http://members.home.nl/ingoogni/
> Pov-Ray    : http://members.home.nl/seed7/

I was obviously missing the point.
I would suggest a recursive macro.

Remco

Post a reply to this message

Peter Popov wrote:

>I got your intentions wrong. This should do what you want, as
>described in your original post.
>
>#declare Pos=array[11]
>
>#declare i=0;
>#while (i<11) #declare Pos[i]=<i,0,0>; #declare i=i+1; #end
>
>#declare i=0;
>#while (i<10)
>  #declare j=i+1;
>  #while (j<11)
>    #declare Pos[i]=
>    vrotate((Pos[j]-Pos[i]),<0,0,10*clock>)+Pos[i];
>    #declare j=j+1;
>  #end
>  #declare i=i+1;
>#end

Sorry but no, ten spheres end up at <10,0.9,0> and one at <10,0,0>.

Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message

I think there is a more serious problem with the sin cos solution.

The sin cos solution prevents non unique positions along the x axis.  Many
kinds of aquatic animals, maybe some fish, would bend their bodies around so
much that there might be two points of the body at some given x.

Remco de Korte wrote:

> ingo wrote:
> >
> > I'm trying to animate the tail of an ASCII-fish. I figured out how to
> > do it
> > the long way but I'm looking for a short cut.
> >
> > Concider eleven spheres on a string from the origin to <10,0>.
> > 1. rotate the whole string 5° around the origin.
> > 2. leave the first sphere in its position. rotate the whole string 5°
> > around the current position of the second sphere.
> > 3. leave the first and second sphere in its position. rotate the whole
> > string 5° around the current position of the third sphere.
> > .
> > .
> > .
> > 10. rotate the eleventh sphere 5° around the current position of the
> > tenth
> > sphere.
> >
> > Now, is there a direct way to calculate the position of a sphere,
> > without
> > going through the above loop. What will the position of sphere 7 be
> > when
> > the rotation angle is 5°?
> >
> > Ingo
> >
> > --
> > Photography: http://members.home.nl/ingoogni/
> > Pov-Ray    : http://members.home.nl/seed7/
>
> I don't know if I understand your method exactly but I did a similar
> thing with a reasonable result using sin/cos-functions. This gives a
> nice curve. The position of each sphere is based on its place in the
> string _plus_ a clock value. This way the first sphere will move also.
> This is easy to avoid by moving the whole string relative to the
> translation of this first sphere. Sounds far more complicated then it
> actually is 8)
>
> Groeten!
>
> Remco

Post a reply to this message

ingo wrote:

>mmm, all spheres end up on a circle, the length of the arcsegment
>between two spheres is known (1 in this case)........

Got it, I think:

#declare Pos=array[11]

#declare i=0;
#while (i<11) 
   #declare Pos[i]=<i,0,0>; 
   #declare i=i+1; 
#end

#declare Angle   = radians(10*clock);
#declare Length  = Pos[1].x-Pos[0].x;
#declare Radius  = Length/Angle;
#declare Lcord   = (Radius/sin(0.5*pi-(Angle/2)))*sin(Angle);
#declare Ccenter = <-0.5*Lcord, Radius, 0>;

#declare i=0;
#while (i<11)
   #if (Pos[i].x=0)
      // do nothing
   #else
      #declare L= Pos[i].x;
      #declare Alpha= L/Radius;
      #declare Pos[i]=
(vrotate(<0,-radius,0>,<0,0,degrees(Alpha)>))+Ccenter;
   #end
   #declare i=i+1; 
#end

#declare i=0;
#while (i<11) 
   sphere{ Pos[i],0.2 pigment {rgb <1,0,0>}}
   #declare i=i+1; 
#end


Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message

This just crashed my UVPOV during the creation of the bounding slabs. It
said something about Reallocing Finite to 33...

Post a reply to this message

TonyB wrote:

>This just crashed my UVPOV during the creation of the bounding slabs. It
>said something about Reallocing Finite to 33...
>

Ooops, posted it a bit too ethousiastic.
Add after the #declare Angle statement
#if (Angle !=0)
   and before the last #declare i=0
#end

Also the x-coordinate value of Ccenter seems to be not ok yet.


Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message

Greg M. Johnson wrote:
> 
> I think there is a more serious problem with the sin cos solution.
> 
> The sin cos solution prevents non unique positions along the x axis.
> Many
> kinds of aquatic animals, maybe some fish, would bend their bodies
> around so
> much that there might be two points of the body at some given x.
> 
> Remco de Korte wrote:
> 

I don't understand. This is just the thing that makes sin or cos a
reasonable choice, I thought. 
I'm obviously missing something very important here. The only thing that
I have to support my choice is a working animation that does what it
should do for me, but, admittedly, is probably not what a hardcore
pov-er would consider realistic.

Regards,

Remco

Post a reply to this message

Remco de Korte wrote:

>Greg M. Johnson wrote:
>> 
>> I think there is a more serious problem with the sin cos solution.
>> 
>> The sin cos solution prevents non unique positions along the x axis.
>> Many
>> kinds of aquatic animals, maybe some fish, would bend their bodies
>> around so
>> much that there might be two points of the body at some given x.
>> 
>> Remco de Korte wrote:
>> 
>
>I don't understand. This is just the thing that makes sin or cos a
>reasonable choice, I thought.......

For a simple fishtail you're right. But sometimes it's a sport doing thing 
a certain way. Run a 60 frame animation of the below scene (~5 minutes), it 
shows what Greg means.

#version 3.1;
global_settings {assumed_gamma 1.0}
light_source {
   < 500, 500,-500>
   rgb 1
}
camera {
   location  <4, 0, -10>
   look_at   <4, 0.0,0.0>
   angle 90
}
// generates number between min & max
// based on Value between 0, 1.
#macro Vmm(Min,Max,Value)
   (Min+((Max-Min)*Value))
#end //macro

#declare Pos=array[150]

#declare i=0;
#while (i<150) 
   #declare Pos[i]=<i/10,0,0>; 
   #declare i=i+1; 
#end

#declare Angle   = radians(Vmm(-4,4,clock));
#if (Angle !=0)
   #declare Length  = Pos[1].x-Pos[0].x;
   #declare Radius  = Length/Angle;
   #declare Ccenter = <0, Radius, 0>;
   
   #declare i=0;
   #while (i<150)
      #if (Pos[i].x=0)
         // do nothing
      #else
         #declare L= Pos[i].x;
         #declare Alpha= L/Radius;
         #declare Pos[i]=
(vrotate(<0,-Radius,0>,<0,0,degrees(Alpha)>))+Ccenter;
      #end
      #declare i=i+1; 
   #end
#end

#declare i=0;
#while (i<150) 
   sphere{ Pos[i],0.3 pigment {rgb <1,0,0>}}
   #declare i=i+1; 
#end


Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message

ingo wrote:
> 
> Remco de Korte wrote:
> 
> >Greg M. Johnson wrote:
> >>
> >> I think there is a more serious problem with the sin cos solution.
> >>
> >> The sin cos solution prevents non unique positions along the x
> axis.
> >> Many
> >> kinds of aquatic animals, maybe some fish, would bend their bodies
> >> around so
> >> much that there might be two points of the body at some given x.
> >>
> >> Remco de Korte wrote:
> >>
> >
> >I don't understand. This is just the thing that makes sin or cos a
> >reasonable choice, I thought.......
> 
> For a simple fishtail you're right. But sometimes it's a sport doing
> thing
> a certain way. Run a 60 frame animation of the below scene (~5
> minutes), it
> shows what Greg means.
> 
> #version 3.1;
> global_settings {assumed_gamma 1.0}
> light_source {
>    < 500, 500,-500>
>    rgb 1
> }
> camera {
>    location  <4, 0, -10>
>    look_at   <4, 0.0,0.0>
>    angle 90
> }
> // generates number between min & max
> // based on Value between 0, 1.
> #macro Vmm(Min,Max,Value)
>    (Min+((Max-Min)*Value))
> #end //macro
> 
> #declare Pos=array[150]
> 
> #declare i=0;
> #while (i<150)
>    #declare Pos[i]=<i/10,0,0>;
>    #declare i=i+1;
> #end
> 
> #declare Angle   = radians(Vmm(-4,4,clock));
> #if (Angle !=0)
>    #declare Length  = Pos[1].x-Pos[0].x;
>    #declare Radius  = Length/Angle;
>    #declare Ccenter = <0, Radius, 0>;
> 
>    #declare i=0;
>    #while (i<150)
>       #if (Pos[i].x=0)
>          // do nothing
>       #else
>          #declare L= Pos[i].x;
>          #declare Alpha= L/Radius;
>          #declare Pos[i]=
> (vrotate(<0,-Radius,0>,<0,0,degrees(Alpha)>))+Ccenter;
>       #end
>       #declare i=i+1;
>    #end
> #end
> 
> #declare i=0;
> #while (i<150)
>    sphere{ Pos[i],0.3 pigment {rgb <1,0,0>}}
>    #declare i=i+1;
> #end
> 
> Ingo
> 
> --
> Photography: http://members.home.nl/ingoogni/
> Pov-Ray    : http://members.home.nl/seed7/

I tried rendering it but I still don't understand.
I admit this doesn't look good, but I didn't know the exact settings for
the animation(clock-values). What I did see was that there's no sin or
cos in your source so that doesn't clarify it to me either.
I'm sorry.
Still, it's not my problem 8)

Ciao!

Remco

Post a reply to this message

Just to make sure I totally misunderstand, render this:

#version 3.1;
global_settings {assumed_gamma 1.0}
light_source {
   < 500, 500,-500>
   rgb 1
}
camera {
   location  <4, 0, -10>
   look_at   <4, 0.0,0.0>
   angle 90
}

#declare yy_off=sin(clock*10*pi/5);

#declare xx=0; #while (xx<=10)
  #declare yy=sin((xx+clock*10)*pi/5)-yy_off; 
  #sphere{<xx,yy,0>,.5 pigment{rgb<1,0,0>}}
#declare xx=xx+1;#end

with clock going from 0 to 1 (the number of frames is up to you, I tried
20). Apart from the fact that the distance between the spheres isn't
constant (which is easy to fix) what's wrong with it? I guess this is
not what you're looking for but I don't see what is.
And as for Greg's remark ("The sin cos solution prevents non unique
positions along the x axis.") this shows that there's no problem there.
I didn't say you had to use sin AND cos, just one of them is enough, or
use a clever combination to get more interesting wave-forms (I have a
little program that can illustrate that).

Bye,

Remco

Post a reply to this message

Remco de Korte wrote:
>
>I tried rendering it but I still don't understand.
>I admit this doesn't look good, but I didn't know the exact settings for
>the animation(clock-values). 

0 to 1.
I think we're talking a bit "langs elkaar heen".
My point with the anim was to illustrate that you can have non-unique x-
values because there are no sin / cos functions.

>What I did see was that there's no sin or
>cos in your source so that doesn't clarify it to me either.
>I'm sorry.
>Still, it's not my problem 8)

And I've solved mine :)

>Just to make sure I totally misunderstand, render this:
>[...]
>with clock going from 0 to 1 (the number of frames is up to you, I tried
>20). Apart from the fact that the distance between the spheres isn't
>constant (which is easy to fix) what's wrong with it? I guess this is
>not what you're looking for but I don't see what is.

There's noting wrong. My main problem was the non constant distances and 
that's solved.

>And as for Greg's remark ("The sin cos solution prevents non unique
>positions along the x axis.") this shows that there's no problem there.
>I didn't say you had to use sin AND cos, just one of them is enough, or
>use a clever combination to get more interesting wave-forms (I have a
>little program that can illustrate that).

SinCos? I've seen it on your page, not tried it yet, but I will.

Thank you, and Peter, for your comments. It helped me solve my problem.

Tsjuus,
Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message

ingo wrote:
> 
> Remco de Korte wrote:
> >
> >I tried rendering it but I still don't understand.
> >I admit this doesn't look good, but I didn't know the exact settings
> for
> >the animation(clock-values).
> 
> 0 to 1.
> I think we're talking a bit "langs elkaar heen".
> My point with the anim was to illustrate that you can have non-unique
> x-
> values because there are no sin / cos functions.
> 

Okidoki, and my point was that using sin or cos you can do everything
you want 8)
(as a matter of fact, at school I refused to give any attention to sin
or cos and now it is the part of math I use the most)

Remco

Post a reply to this message

On 20 Nov 1999 04:13:41 -0500, ing### [at] homenl (ingo) wrote:

>Peter Popov wrote:
>
>>I got your intentions wrong. This should do what you want, as
>>described in your original post.
>>
>>#declare Pos=array[11]
>>
>>#declare i=0;
>>#while (i<11) #declare Pos[i]=<i,0,0>; #declare i=i+1; #end
>>
>>#declare i=0;
>>#while (i<10)
>>  #declare j=i+1;
>>  #while (j<11)
>>    #declare Pos[i]=
>>    vrotate((Pos[j]-Pos[i]),<0,0,10*clock>)+Pos[i];
>>    #declare j=j+1;
>>  #end
>>  #declare i=i+1;
>>#end
>
>Sorry but no, ten spheres end up at <10,0.9,0> and one at <10,0,0>.
>
>Ingo

Sorry, that was a typo. it should read

#declare Pos=array[11]

#declare i=0; #while (i<11) #declare Pos[i]=<i,0,0>; #declare i=i+1;
#end

#declare i=0;
#while (i<10)
  #declare j=i+1;
  #while (j<11)
    #declare Pos[j]=  // here was the typo
    vrotate((Pos[j]-Pos[i]),<0,0,10*sin(2*pi*clock)>)+Pos[i];
    //the previous line was modified to make a cyclic anim
    #declare j=j+1;
  #end
  #declare i=i+1;
#end

I actually tested it this time :), and it worked.


Peter Popov
ICQ: 15002700

Post a reply to this message

Here's an example of use of the "non sin cos" solution.

Look at "Does a snake's tail move?" in p.b.a, an entry at 1/23/99.

I serially rotated part of the snake's tail relative to the rest of the
snake.  I used sin & cos to rotate the snake.  I did not use, however, sin
or cos to displace body segments a distance along a line normal to the
x-axis. Look at my code included therein......

Remco de Korte wrote:

> ingo wrote:
> >
> > Remco de Korte wrote:
> > >
> > >I tried rendering it but I still don't understand.
> > >I admit this doesn't look good, but I didn't know the exact settings
> > for
> > >the animation(clock-values).
> >
> > 0 to 1.
> > I think we're talking a bit "langs elkaar heen".
> > My point with the anim was to illustrate that you can have non-unique
> > x-
> > values because there are no sin / cos functions.
> >
>
> Okidoki, and my point was that using sin or cos you can do everything
> you want 8)
> (as a matter of fact, at school I refused to give any attention to sin
> or cos and now it is the part of math I use the most)
>
> Remco

Post a reply to this message