I've been using Moray and Povray for years however for the life of me I
cannot seem to get the photon or Media functions to work. I've look for a
good tutorial but can't find any. I'm hoping someone can point me in the
right direction in the way of a either a tutorial or some really simple
directions. Once I know how to make it work simply I can figure out the
advanced functions.

SO the simplest thing I can see to make would be a spotlight that reacts
with dust or smoke in the air. Were you actually see the cone of light as it
shine down from the source to the target. Moray says you have to create a
media file in textures, but it gives you no idea on how to do so or how to
apply it. I'm using Moray 3.3 and the Beta 3.5 with Povray 3.5.

Any suggestions or directions would be greatly.. GREATLY appreciated.

Thanks in advance.

Greg

Post a reply to this message

"GMC" <gmc### [at] speakeasynet> wrote in message news:3dd341e3@news.povray.org...

<snip>

Here's the simplest scene I could come up with that uses both media and photons,
but you're right - a good tutorial would be an asset.

#version 3.5;

#include "colors.inc"
#include "textures.inc"

global_settings {
  assumed_gamma 1.0
  photons {
    spacing 0.01 // larger = worse
  }
}

camera {
  location  <0.0, 10, -20.0>
  look_at   <0.0, 0,  0.0>
}

light_source {
  0*x
  color rgb <1,1,1>
  spotlight
  translate <40, 80,0>
  point_at <0, 0, 0>
  radius 1
  falloff 2
}

media {scattering{1, rgb 0.1} method 3}

plane{y,0 pigment{Gray}} // this object won't affect photons, but will show them

cylinder{<2,5,0>,<2.1,5,0>,1
  texture{pigment{White} finish{Mirror}}
  photons{ // this object will affect photons
    target
    refraction on
    reflection on
  }
}

Post a reply to this message

Hey Tom -

Thanks for the note and suggestion. Your suggestion shows how it works and I
get it, the problem I'm having is doing it in Moray.

When I look on the Media tab on the Scene Setting configuration screen, it
says that Named Media Must be created in the texture editor and given a
name. They will then appear here. There is empty list box next to this
statement. My problem is I'm not sure how to create this Name Media texture
in the editor so it will appear in this list box. I've created standard
textures using the media statement but it never appears in this box nor does
it seem to work. Any ideas on this?

Greg

"Tom Melly" <tom### [at] tomandlucouk> wrote in message
news:3dd3d1b7@news.povray.org...
> "GMC" <gmc### [at] speakeasynet> wrote in message
news:3dd341e3@news.povray.org...
>
> <snip>
>
> Here's the simplest scene I could come up with that uses both media and
photons,
> but you're right - a good tutorial would be an asset.
>
> #version 3.5;
>
> #include "colors.inc"
> #include "textures.inc"
>
> global_settings {
>   assumed_gamma 1.0
>   photons {
>     spacing 0.01 // larger = worse
>   }
> }
>
> camera {
>   location  <0.0, 10, -20.0>
>   look_at   <0.0, 0,  0.0>
> }
>
> light_source {
>   0*x
>   color rgb <1,1,1>
>   spotlight
>   translate <40, 80,0>
>   point_at <0, 0, 0>
>   radius 1
>   falloff 2
> }
>
> media {scattering{1, rgb 0.1} method 3}
>
> plane{y,0 pigment{Gray}} // this object won't affect photons, but will
show them
>
> cylinder{<2,5,0>,<2.1,5,0>,1
>   texture{pigment{White} finish{Mirror}}
>   photons{ // this object will affect photons
>     target
>     refraction on
>     reflection on
>   }
> }
>
>
>

Post a reply to this message

"gregmcd" <gmc### [at] speakeasynet> wrote in message news:3dd40b42@news.povray.org...

> in the editor so it will appear in this list box. I've created standard
> textures using the media statement but it never appears in this box nor does
> it seem to work. Any ideas on this?
>

Oops, replied by email - but basically right-click on the media label in the
texture-editor and give it a name (no spaces). Don't worry about values used for
other aspects of the texture, since they will be ignored. BTW note that
atmospheric media will be slower than media contained by an object.

That said, until Moray is 3.5 compat., you'd be better off adding media by hand
in 3.5 where it's both easier and quicker than 3.1

Post a reply to this message

"gregmcd" <gmc### [at] speakeasynet> wrote in message news:3dd40b42@news.povray.org...
> Hey Tom -
>
> Thanks for the note and suggestion. Your suggestion shows how it works and I
> get it, the problem I'm having is doing it in Moray.
>

BTW one thing to bear in mind with media is that, unlike most things in pov, it
is very scale-dependant.

By this I mean that if you scale all elements in a non-media scene by the same
amount, the scene will appear the same (a sphere of radius 1 viewed at a
distance of 10 units will look the same as a sphere of radius 10 viewed at a
distance of 100 units).

Try playing with the myScale value in the scene below, and note the alternative
line in the media definition that makes the media "scalable"....

// Persistence of Vision Ray Tracer Scene Description File
// File: ?.pov
// Vers: 3.5
// Desc: Basic Scene Example
// Date: mm/dd/yy
// Auth: ?
//

#version 3.5;

#declare myScale = 10;

#declare myMedia =
media {    // atmospheric media sample
  intervals 10
  scattering { 1, rgb 0.03} // this won't scale - as you scale up, the media
becomes more opaque..
  //scattering { 1, rgb 0.03/myScale } //..but this will scale since the media
is thinned.
  samples 1, 10
  confidence 0.9999
  variance 1/1000
  ratio 0.9
}

#include "colors.inc"
#include "textures.inc"

global_settings {
  assumed_gamma 1.0
}

camera {
  location  <0.0, 0, -50.0>*myScale
  look_at   <0.0, 0,  0.0>
}

light_source {
  0*x
  color rgb <1,1,1>
  translate <40, 80,0>*myScale
}

plane{-z,-50 pigment{brick} scale myScale}

sphere{0,5 pigment{bozo pigment_map{[0 White][1 Black]}} translate x*10 scale
myScale}
sphere{0,5 pigment{rgbf 1} interior{media{myMedia}} hollow translate x*-10 scale
myScale}

Post a reply to this message

> Any suggestions or directions would be greatly.. GREATLY appreciated.

Make *sure* that any object you're filling with media has the Hollow box 
checked...

I can't remember how many times I've forgotten that...  :)

Jamie.

Post a reply to this message

> When I look on the Media tab on the Scene Setting configuration screen, it
> says that Named Media Must be created in the texture editor and given a
> name. They will then appear here. There is empty list box next to this
> statement. My problem is I'm not sure how to create this Name Media texture
> in the editor so it will appear in this list box. I've created standard
> textures using the media statement but it never appears in this box nor does
> it seem to work. Any ideas on this?

The Media tab in the Scene settings box is only for scene level media 
(the media equivalent of fog).

To use media inside a container object, you create the material with an 
interior, add a media type, and make sure you've got the hollow box 
checked for the container object and any other objects in may be inside.

If you want, I can email you a small sample .mdl for you to look at, but 
you may have to wait until Sunday, as I'm visiting friends over the 
weekend.

Jamie.

Post a reply to this message

It is not a very good idea to put a scene level media because it slows the
render.
As says Jamie, it is smarter to put your media in a container.
If you want a scene media, you must create a material in the texture editor.
Give this material an interior and a media
Make sure you give a name to the MEDIA (select the media level, right click
chose Poperties/rename)
Your media should appear in medial list of scene settings now.

Marc

Post a reply to this message

Jamie -

That would be GREAT! I don't mind the wait.  That would make things 3000%
clearer.  I know that this should be really simple, but I don't seem to be
able to get it. Thanks again for the offer Jamie.

Greg

"Jamie Davison" <jam### [at] ntlworldcom> wrote in message
news:MPG.183e2681d3d6c9aa989c19@news.povray.org...
> > When I look on the Media tab on the Scene Setting configuration screen,
it
> > says that Named Media Must be created in the texture editor and given a
> > name. They will then appear here. There is empty list box next to this
> > statement. My problem is I'm not sure how to create this Name Media
texture
> > in the editor so it will appear in this list box. I've created standard
> > textures using the media statement but it never appears in this box nor
does
> > it seem to work. Any ideas on this?
>
> The Media tab in the Scene settings box is only for scene level media
> (the media equivalent of fog).
>
> To use media inside a container object, you create the material with an
> interior, add a media type, and make sure you've got the hollow box
> checked for the container object and any other objects in may be inside.
>
> If you want, I can email you a small sample .mdl for you to look at, but
> you may have to wait until Sunday, as I'm visiting friends over the
> weekend.
>
> Jamie.

Post a reply to this message