|
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Lohmueller and Imagico give a good tutorial on water. That was a good help.
Lohmueller has a tutorial only about clouds, but I need something
different, interior or media or so, for the entire air body.
Still trying to find some ways to create an atmosphere...
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Le 16-02-10 21:35, Sven Littkowski a écrit :
> Hi,
>
> does anyone have a realistic way to simulate air and water?
>
> For the air, it should make everything fading in distance to a air blue
> and behave in all other ways also like atmosphere.
>
> And the water should have transparency that becomes more bluish in
> distance, simply like real water, too.
>
> I intend to use both inside a cylinder, where the air would be in the
> shape of a cylinder, and the water in the shape of a difference
> (cylinder/cylinder).
>
> Thanks a lot for your help.
>
For air, use a low density scattering media with a blueish tint, like
rgb<0.5, 0.7, 1>
Make sure that your container have the hollow option enabled. Simply
adding "hollow" is enough.
A quick and dirty alternative is the use of fog with the appropriate
colour. fog is fast and never interact with your light sources. It will
affect shadowed areas in the same way it affect lighted areas.
Appropriate for testing in the composition phase.
For the water, you can also use media, but, you can also use colour fading.
Adding refraction is crutial to get beleiveable water. Refraction is
turned on by having an ior in the interior block.
interior{ior 1.33 // typical water ior
fade_colour <0.4, 0.66, 0.9>
fade_distance SomeDistanceValue
fade_power 1 // or 1001
}
Adjust "SomeDistanceValue" as needed to get the result that you want.
Fading is compatible with the use of media.
You don't need the media if you want to model very limpid water, but
media is required if the water is to have any turbidity.
Colour fading is fast, very fast compared with scattering media, so, the
testing won't take much time.
Alain
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Le 16-02-11 09:41, Stephen a écrit :
> On 2/11/2016 12:45 PM, Sven Littkowski wrote:
>> Thanks. There are two keywords in it, which will help me now to
>> investigate better: scattering and absorption.
>>
>
> There is also emission which you could use for the central light source.
> I was going to mention Rune Johansen's "electric.inc" but that uses the
> glow keyword which requires MegaPov. So it will not work with the
> official PovRay.
> Nevertheless Rune's site does have some good include files that you
> might find useful. I often use his Grass Tex Include File and his
> Particle System is good too.
>
For the glow, you can use emissive media with an appropriate pattern.
The spherical pattern is often the best suitted one, followed by
cylindrical.
media{emission Colour}
This gives you an uniform glowing media.
sphere{0, 1 pigment{rgbt 1}
hollow
media{emission Colour density{spherical}}
}
gives you a spherical glowing media, contained within an unit sphere,
that goes from full strength at the center and drop to zero at the
surface of the sphere.
Alain
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Thanks. :-)
Not bad. But in my scenario, it is a bit different: there is an
illuminated day" side inside that hollow cylinder, but also a dark
"night" side. The illumination is done already by light sources at the
moment, or an emissive image maybe in the future.
The medium I need, would not need to glow. But it should give that blue
"dust" to the distance, and be brighter around a light or emission source.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
For the air, I am trying to use he code below. But I am getting an error:
"Fatal Error in Renderer: A POV-Ray internal nesting limit was reached."
cylinder // Air
{
< 0.0, 0.0, 0.0 > < 0.0, 0.0, 5000.0 > 1500.0
hollow
interior
{
ior 1.3
fade_distance 10
fade_power 1001
fade_color < 0.5, 0.7, 1.0 >
media
{
scattering
{
3
< 0.5, 0.65, 0.4 >
extinction 1.0
}
}
}
}
------------------------
For the water body, I am using successfully this (still dependent on the
blue of the future air medium):
difference // Water
{
cylinder { < 0.0, 0.0, 0.0 > < 0.0, 0.0, 5000.0 > 1500.0 }
cylinder { < 0.0, 0.0, -0.1 > < 0.0, 0.0, 5000.1 > MyWaterLevel }
material
{
texture
{
pigment { color rgbt < 0.2, 0.7, 0.3, 0.5 > }
finish
{
ambient 0.0
diffuse 0.0
emission 0.0
reflection
{
0.0, 1.0
falloff 5
fresnel on
}
specular 0.4
roughness 0.003
}
normal
{
function { f_ridged_mf(x, y, z, 0.1, 3.0, 7, 0.7, 0.7, 2) } 0.8
scale 0.13
}
}
interior
{
ior 1.3
fade_distance 10
fade_power 1001
fade_color < 0.8, 0.2, 0.2, 0.5 >
media
{
// absorption < 0.8, 0.6, 1.0, 0.5 >
scattering
{
3
< 0.5, 0.65, 0.4 >
extinction 1.0
}
}
}
}
normal
{
function { f_ridged_mf(x, y, z, 0.1, 3.0, 7, 0.7, 0.7, 2) }
0.8
scale < 0.13, 0.4, 0.13 >
}
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
UPDATE
For the air, I am using now successlessly the code below: it is just dark.
cylinder // Air
{
< 0.0, 0.0, 0.0 > < 0.0, 0.0, 5000.0 > 1500.0
hollow
interior
{
media
{
scattering
{
3
< 0.5, 0.7, 1.0 >
extinction 1.0
}
}
}
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 12-2-2016 7:34, Sven Littkowski wrote:
> UPDATE
>
> For the air, I am using now successlessly the code below: it is just dark.
>
Try this:
cylinder // Air
{
< 0.0, 0.0, 0.0 > < 0.0, 0.0, 5.000 > 1.500
hollow
pigment {rgbt 1}
interior
{
media
{
scattering
{
1
< 1.0, 0.7, 0.5 >/1000
extinction 1.0
}
}
}
scale 1000
}
(1) Note the scaling of the cylinder /and/ of the scattering.
(2) I changed the scattering colour
(3) The cylinder needs a transparent pigment
--
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On 12-2-2016 7:34, Sven Littkowski wrote:
> UPDATE
>
> For the air, I am using now successlessly the code below: it is just dark.
>
Try this:
cylinder // Air
{
< 0.0, 0.0, 0.0 > < 0.0, 0.0, 5.000 > 1.500
hollow
pigment {rgbt 1}
interior
{
media
{
scattering
{
3
< 1.0, 0.7, 0.5 >/1000
extinction 1.0
}
}
}
scale 1000
}
(1) Note the scaling of the cylinder /and/ of the scattering.
(2) I changed the scattering colour
(3) The cylinder needs a transparent pigment
--
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Note also that you can thicken or thinning the atmosphere by adding an
extra multiplicator to the scattering colour:
This will thicken the atmosphere:
scattering {3 < 1.0, 0.7, 0.5 >*1.5 /1000
extinction 1.0
}
This will thin it:
This will thicken the atmosphere:
scattering {3 < 1.0, 0.7, 0.5 >*0.5 /1000
extinction 1.0
}
--
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Note also that you can thicken or thin the atmosphere by adding an extra
multiplicator to the scattering colour:
This will thicken the atmosphere:
scattering {3 < 1.0, 0.7, 0.5 >*1.5 /1000
extinction 1.0
}
This will thin it:
scattering {3 < 1.0, 0.7, 0.5 >*0.5 /1000
extinction 1.0
}
--
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|