Hi!

I have a huge scene where I have many many objects with glowing media inside
"interior { media { emission <0.6,0.8,1>*.05 } }". How can I create a shine
around these glowing objects without post processing? Can this be done with fog
or media? The Light-saber approach where one needs to create a larger version of
these objects, putting some other media inside would not be possible for me.

Any Ideas anyone?

Post a reply to this message

"CAD-Andi" <nomail@nomail> schreef in bericht 
news:web.4d857a70705a2775b642fbb20@news.povray.org...
> Hi!
>
> I have a huge scene where I have many many objects with glowing media 
> inside
> "interior { media { emission <0.6,0.8,1>*.05 } }". How can I create a 
> shine
> around these glowing objects without post processing? Can this be done 
> with fog
> or media? The Light-saber approach where one needs to create a larger 
> version of
> these objects, putting some other media inside would not be possible for 
> me.
>
> Any Ideas anyone?

I am working on a night scene with halos around light sources. I use an 
emission media with a spherical density.

Thomas

Post a reply to this message

Am 20.03.2011 04:54, schrieb CAD-Andi:
> I have a huge scene where I have many many objects with glowing media inside
> "interior { media { emission<0.6,0.8,1>*.05 } }". How can I create a shine
> around these glowing objects without post processing? Can this be done with fog
> or media? The Light-saber approach where one needs to create a larger version of
> these objects, putting some other media inside would not be possible for me.

The latter would be the usual way to go though.

Another approach would be to place the camera inside a transparent 
sphere with ior, and add an averaged texture in front: One (stronger) 
sub-texture being totally invisible, the other (weaker) sub-texture 
having high-frequency perturbed normals. To be used with strong 
anti-aliasing or focal blur. However, this approach is only useful for 
creating halos around exceptionally bright objects.

Post a reply to this message

"Thomas de Groot" <tDOTdegroot@interDOTnlANOTHERDOTnet> wrote:

>
> I am working on a night scene with halos around light sources. I use an
> emission media with a spherical density.
>
> Thomas

Hi Thomas!
Do you happen to have a small code example to get me started? Would be awesome!

Andi

Post a reply to this message

> Hi!
>
> I have a huge scene where I have many many objects with glowing media inside
> "interior { media { emission<0.6,0.8,1>*.05 } }". How can I create a shine
> around these glowing objects without post processing? Can this be done with fog
> or media? The Light-saber approach where one needs to create a larger version of
> these objects, putting some other media inside would not be possible for me.
>
> Any Ideas anyone?
>
>

The normal way is to add some slightly larger object around the 
concerned object and fill that with a media using a spherical or 
cylindrical pattern.

Fog can't do what you want.

The outer object don't need to ba a larger version of your object. It 
just need to surround the part(s) you want to shine.

The fact that your scene is huge and that there are many glowing objects 
will make this tedious.

Clipka's suggestion looks promising, but will be computionaly intensive.
It may be possible to place refractive objects with averaged normals 
around your glowing objects. Low ior (no more than 1.1) and STRONG 
normals, NO reflection and NO highlight on those.
This way, the added computations are limited to the area surrounding the 
glowing objects.
It will render slower than the added emissive media objects.



Alain

Post a reply to this message

Am 20.03.2011 17:52, schrieb Alain:

> Clipka's suggestion looks promising, but will be computionaly intensive.
> It may be possible to place refractive objects with averaged normals
> around your glowing objects. Low ior (no more than 1.1) and STRONG
> normals, NO reflection and NO highlight on those.
> This way, the added computations are limited to the area surrounding the
> glowing objects.
> It will render slower than the added emissive media objects.

Slowdown can also be mitigated to some degree by adding "no_shadow 
no_reflection no_radiosity" to those refractive objects.

Post a reply to this message

"CAD-Andi" <nomail@nomail> schreef in bericht 
news:web.4d8600f95784deadb642fbb20@news.povray.org...
> "Thomas de Groot" <tDOTdegroot@interDOTnlANOTHERDOTnet> wrote:
>
>>
>> I am working on a night scene with halos around light sources. I use an
>> emission media with a spherical density.
>>
>> Thomas
>
> Hi Thomas!
> Do you happen to have a small code example to get me started? Would be 
> awesome!
>

Of course. This is the code I use.

//-----------------------------------------------start code

#local HaloScale    = 100;
#local colLum       = rgb <1.0, 1.0, 0.9>; // light color
#local haloTurb     = 0.1;                 // outer halo turbulence
#local haloStrength = 0.5;                 // inner and outer halo intensity 
(outer halo is 50% inner halo intensity)
#local DensityShift = 0.9;         // shifts the density within the media

#local DensityHalo =
density {
  spherical
  turbulence haloTurb
  color_map {
    [0.4 rgb 0]
    [0.8 colLum*haloStrength*0.05]
    [1.0 colLum*haloStrength*0.5]
  }
  scale <1, 1, 1>
  translate DensityShift*y
}

#local mediaHalo =
media {
  emission haloStrength*0.5
  intervals 1
  samples 100
  confidence 0.9999
  variance 1/10
  density {DensityHalo}
}

#declare LampHalo =
sphere {0, 1
  texture {pigment {rgb 0 transmit 1} finish {ambient 0 diffuse 0}}
  interior {media {mediaHalo}}
  hollow no_shadow
  translate -DensityShift*y
  scale HaloScale
  translate <-0.09911, 1.861, 0.0> //locate halo center a bit within the 
lamp shade
}

#declare LampHalo2 =
sphere {0, 1
  texture {pigment {rgb 0 transmit 1} finish {ambient 0 diffuse 0}}
  interior {
    media {
      scattering {1, (colLum*0.05)/200}
    }
  }
  hollow no_shadow
  scale 200
  translate <Max.x, Max.y, 1>
}

#macro Lamp(Force,Area,FD)
light_source {
  <-0.6221, 3.953, 0.0>,
  colLum*Force
  #if (Area)
    area_light
    <1.0, 0, 0> <0, 0, 1.0>
    3, 3
    adaptive 1
    jitter
    circular
    orient
  #end
  fade_distance FD
  fade_power 2
  //looks_like {sphere {0, 1.0 pigment {rgb <1,1,1>} finish {emission 1}}}
}
#end //of macro

//-----------------------------------------------end code

Thomas

Post a reply to this message