Alain escribió:
> So, what's killing you is the aa with the micro normals.
> Increasing the resolution will have the benefit of reducing the aa work, 
> increasing the chance that adjacent pixels difference to be under the aa 
> treshold.
> 

Did you try uncommenting the focal blur line?

Post a reply to this message

/* wip 2.  more parametrized and using tips by Alain and elsewhere...
* DOF on (very light, just for testing AA other than supersampling
* normals off
* area_light off
* fresnel reflections on
* refractions on
* caustics on

* rendertime: 1:54 min on P4 3.00 800x600
*/



#local HQ = 0;			/* general high quality */
//#local FT = 0; //<0,0,0,.3,.68>;	/* filter/transmit */
#local FT = <0,0,0,.6,.38>;	/* filter/transmit */
#local AREALIGHTS = 0;
#local NORMALS = 0;
#local DOF = 1;			/* depth of field camera blur */
#local REFLECTIONS = 1;
#local REFRACTION = 1.55; 	/* 0, nothing; 1.55 glass; 1.33 water etc */
#local MEDIA = 0;
#local CAUSTICS = 1;
#local CAUSTICSgather = 1;
#local CRAZY = 0;


global_settings {
	#if (CRAZY)
	max_trace_level 40
	//adc_bailout .08
	#end
	#if (HQ)
	max_trace_level 40
	adc_bailout .02
	#else
	max_trace_level 60
	adc_bailout .06
	#end

	#if (CAUSTICS)
	photons {
		#if (CAUSTICSgather)
		save_file "cups-wip2.phm"
		count image_width*image_height
		max_trace_level 30
		adc_bailout .02
		#else
		load_file "cups-wip2.phm"
		#end
	}
	#end
}

background { rgb 1 }


#local cup =
	lathe { bezier_spline
     48, //nr points
     /*   0*/ <0, 2.8571826>, <174.28571, 2.8571826>, 
<197.14286,2.8571826>, <197.14286,2.8571826>,
     /*   1*/ <197.14286, 2.8571826>, <197.14286, 2.8571826>, 
<211.42857,-2.8571174>, <228.57143,14.285683>,
     /*   2*/ <228.57143, 14.285683>, <245.71429, 31.428583>, 
<242.85714,85.714283>, <242.85714,85.714283>,
     /*   3*/ <242.85714, 85.714283>, <242.85714, 85.714283>, 
<265.71429,80.000003>, <291.42857,105.71428>,
     /*   4*/ <291.42857, 105.71428>, <317.14286, 131.42857>, 
<308.57143,108.57143>, <308.57143,185.71428>,
     /*   5*/ <308.57143, 185.71428>, <308.57143, 262.85714>, 
<308.57143,742.85714>, <308.57143,742.85714>,
     /*   6*/ <308.57143, 742.85714>, <308.57143, 742.85714>, 
<317.14286,737.14285>, <308.57143,754.28571>,
     /*   7*/ <308.57143, 754.28571>, <300, 771.42857>, <288.57143,780>, 
<280,768.57143>,
     /*   8*/ <280, 768.57143>, <271.42857, 757.14285>, 
<294.28571,165.71428>, <277.14286,148.57143>,
     /*   9*/ <277.14286, 148.57143>, <260, 131.42857>, 
<231.42857,131.42857>, <217.14286,105.71428>,
     /*  10*/ <217.14286, 105.71428>, <202.85714, 80.000003>, 
<205.71429,54.285713>, <185.71429,45.714283>,
     /*  11*/ <185.71429, 45.714283>, <165.71429, 37.142883>, 
<2.8571429,2.8571826>, <0,2.8571826>

		sturm
		scale y*.8
		scale 1/1000
	}

#local cup2 = lathe { bezier_spline
     60, //nr points
     /*   0*/ <0, -1.7382813e-05>, <0, 18.571383>, <0,15.178483>, 
<0,15.178483>,
     /*   1*/ <0, 15.178483>, <6.25, 16.964183>, <27.321429,13.571383>, 
<31.250001,14.642783>,
     /*   2*/ <31.250001, 14.642783>, <31.250001, 14.642783>, 
<47.197559,12.769183>, <57.321429,20.675883>,
     /*   3*/ <57.321429, 20.675883>, <64.070661, 25.946983>, 
<67.105608,35.385283>, <69.58272,39.821383>,
     /*   4*/ <69.58272, 39.821383>, <72.837451, 45.650183>, 
<84.294576,84.731483>, <86.071436,102.5>,
     /*   5*/ <86.071436, 102.5>, <87.857146, 120.35714>, 
<85.357146,145>, <82.142856,165.71429>,
     /*   6*/ <82.142856, 165.71429>, <78.966586, 186.1836>, 
<91.342866,204.15811>, <96.071426,208.57143>,
     /*   7*/ <96.071426, 208.57143>, <101.42857, 213.57142>, 
<106.78572,215>, <107.5,210.71428>,
     /*   8*/ <107.5, 210.71428>, <108.21429, 206.42857>, 
<103.92858,210.71428>, <99.642856,187.85714>,
     /*   9*/ <99.642856, 187.85714>, <95.357146, 165>, 
<103.92858,148.57143>, <104.64286,125.71428>,
     /*  10*/ <104.64286, 125.71428>, <105.35715, 102.85714>, 
<101.42858,87.142853>, <97.857149,75.000003>,
     /*  11*/ <97.857149, 75.000003>, <94.285715, 62.857143>, 
<80.115281,24.737083>, <76.428572,19.821483>,
     /*  12*/ <76.428572, 19.821483>, <72.142858, 14.107183>, 
<64.730914,9.7242826>, <64.464285,5.7142826>,
     /*  13*/ <64.464285, 5.7142826>, <64.071714, -0.18991738>, 
<61.964286,-1.7382813e-05>, <61.964286,-1.7382813e-05>,
     /*  14*/ <61.964286, -1.7382813e-05>, <61.964286, -1.7382813e-05>, 
<0,-1.7382813e-05>, <0,-1.7382813e-05>
	sturm
	scale .002*2
	scale (x+z)*.7
	translate y*1.7382813e-05
}

#macro tex( col )
material {
	texture {
	pigment { rgbft col + FT }
	//pigment { rgbt 1 }
	#if (NORMALS) normal { bumps .1 scale .002 } #end
	#if (1)
	finish { ambient .06 diffuse .4 brilliance 1.2
			specular .92
			#if (NORMALS)
			roughness .04
			#else
			roughness .01
			#end
			metallic .07
			#if (REFLECTIONS)
			reflection { .06,.5 metallic .07 fresnel 1 exponent 1.2 falloff 2 }
			conserve_energy
			#end
	}
	#end
	}
	interior {
		#if (REFRACTION) ior REFRACTION #end
		fade_power 2 fade_distance .02 fade_color rgbft col+FT
		#if (MEDIA)
	    media {
                 intervals 8 samples 2,6
                 emission 3.81*(col)
                 absorption 12*(1-col)
                 #if (CRAZY) scattering { 0, (col)*7 extinction 1 } #end
				scale .2
                 #if (1)
                 density {
					bumps scale .002
                     color_map {[0 rgb 1][.5 rgb 1][.56 rgb 0][1 rgb 0]}
                 }
                 #end
         }
		#end
	}
}
	photons { target refraction on }
hollow
#end

union {
	plane { y 0
		pigment { rgb 1 }
		//pigment { checker rgb .6 rgb 1 rotate y*35 }
		finish { ambient .1 diffuse .7  specular 1 roughness .2 }
		photons { collect on refraction on }
	}
	object { cup translate z*.7 tex( <.9,.86,.4> ) }
	#if (1)
	object { cup translate z*(.7+1.3) tex( <1,.96,.84> ) }
	object { cup translate 0 tex( <.7,.8,1> ) }
	object { cup translate x*.7 tex(<1,1,1> )}
	object { cup translate x*.7+z*.7 tex(<.96,1,.67> )}
	object { cup translate x*.7+z*.7*2 tex(<.7,1,.7> )}
	object { cup2 translate -x*.7 tex(<1,.6,.6> ) }
	object { cup2 translate -x*.7+z*(.0+1.3) tex(<.5,.5,.8> ) }
	object { cup translate -x*.7*2+z*(-.7+1.3) tex(<.7,1,.94> ) }
	#end
	light_source { 1.8*(3-z*5-x) 1.2
		#if (AREALIGHTS)
		area_light x,z,5,5 jitter circular adaptive 0
		#end
		photons { refraction on }
	}
	hollow

	//rotate -y*45
	rotate -x*30
	translate <.1,-1/2.6,4.0> //z*2.6-y/3+x*.1
}

  light_source { -z*8 .7 shadowless }

  camera { angle 50
	#if (DOF)
	aperture .04 blur_samples 60 confidence 1 focal_point y/2.2+z*4.5
	#end
}

Post a reply to this message

Attachments:
Download 'cups-wip2.jpg' (39 KB)

Preview of image 'cups-wip2.jpg'

Nice. The glass material looks more convincing. I also like your new glasses, 
much more elegant.

Now, how about adding some dispersion...

nemesis nous apporta ses lumieres en ce 2008/01/30 14:37:

> #macro tex( col )
> material {
>     texture {
>     pigment { rgbft col + FT }
>     //pigment { rgbt 1 }
>     #if (NORMALS) normal { bumps .1 scale .002 } #end
>     #if (1)
>     finish { ambient .06 diffuse .4 brilliance 1.2
>             specular .92
>             #if (NORMALS)
>             roughness .04
>             #else
>             roughness .01
>             #end
>             metallic .07
>             #if (REFLECTIONS)
>             reflection { .06,.5 metallic .07 fresnel 1 exponent 1.2 
> falloff 2 }
>             conserve_energy
>             #end
>     }
>     #end
>     }
>     interior {
>         #if (REFRACTION) ior REFRACTION #end
>         fade_power 2 fade_distance .02 fade_color rgbft col+FT

dispersion 0.03#if(CRAZY)dispersion_samples 20 #else dispersion_samples 9 #end

>         #if (MEDIA)
>         media {
>                 intervals 8 samples 2,6
>                 emission 3.81*(col)
>                 absorption 12*(1-col)
>                 #if (CRAZY) scattering { 0, (col)*7 extinction 1 } #end
>                 scale .2
>                 #if (1)
>                 density {
>                     bumps scale .002
>                     color_map {[0 rgb 1][.5 rgb 1][.56 rgb 0][1 rgb 0]}
>                 }
>                 #end
>         }
>         #end
>     }
> }
>     photons { target refraction on }
> hollow
> #end
> 


-- 
Alain
-------------------------------------------------
You know you've been raytracing too long when you call in sick in order to render.
David Kraics

Post a reply to this message

Alain escribió:
> Now, how about adding some dispersion...

And don't use CPU time as an excuse :)

Post a reply to this message

Nicolas Alvarez wrote:
> Alain escribió:
>> Now, how about adding some dispersion...
> 
> And don't use CPU time as an excuse :)

you guys are amazing!  I'll add dispersion, and next you'll want media 
ON in the material!  :P

but really, the best tip so far was the adc_bailout control variable. 
What an amazing speed boost for so little loss in quality... BTW, 
Nicolas, there is adc_bailout and max_trace_level specifically in the 
global photons block as well.  Did you try that with the scene you 
rendered for Sven?  Perhaps it'd drop down as well...

well, obviously normals are off in this scene so I'll test that eventually.

About the new bezier curve:  I think I'm getting the hang of it, but 
it's still not perfect.  It shows some sharp divisions between one curve 
segment and the next.  But now I think I know the reason:  the control 
points should be further away from the tangential point.  It's much 
easier to draw the curve and then edit the points to tweak the curve.

Next render, I hope I get some progress in that front...

Post a reply to this message

nemesis nous apporta ses lumieres en ce 2008/01/31 13:17:
> Nicolas Alvarez wrote:
>> Alain escribió:
>>> Now, how about adding some dispersion...
>>
>> And don't use CPU time as an excuse :)
> 
> you guys are amazing!  I'll add dispersion, and next you'll want media 
> ON in the material!  :P
> 
> but really, the best tip so far was the adc_bailout control variable. 
> What an amazing speed boost for so little loss in quality... BTW, 
> Nicolas, there is adc_bailout and max_trace_level specifically in the 
> global photons block as well.  Did you try that with the scene you 
> rendered for Sven?  Perhaps it'd drop down as well...
> 
It's an override. If not specified, the photons will inherit the general 
settings. If you set those, the photon's max_trace_level and adc_bailout will 
replace the general values only for the photons computing.

-- 
Alain
-------------------------------------------------
WARNING: The consumption of alcohol is a major factor in dancing like a retard.

Post a reply to this message

For this one, I posted the zipped source files and inkscape svg for 
curve editing in p.b.s-f.

Here's an update with photons, normals (in some cups) and area_lights. 
It was taking more time than I wanted.  I have to go to work! :P


marked the image to point out areas in which the curve segments seem too 
sharp.  It seems no matter how much I tweak the curves in inkscape they 
do still show up in povray, though seem completely smooth in inkscape.

The second scene better shows the curve.  It seems refraction in the 
first one only makes things worse.  Yes, I know sturm should do better, 
but it really doesn't help, as the second cup model uses sturm and to no 
good.

any thoughts?

Post a reply to this message

Attachments:
Download 'cups-wip3-questions.png' (470 KB) Download 'vase.png' (155 KB)

Preview of image 'cups-wip3-questions.png'

Preview of image 'vase.png'

nemesis <nam### [at] gmailcom> wrote:
 Yes, I know sturm should do better,
> but it really doesn't help, as the second cup model uses sturm and to no
> good.
>
> any thoughts?



Does the help file apply here?
//The following list shows all objects for which the Sturmian root solver can be
used
// lathe (only with quadratic splines




*************************



Everyone is probably bored with this but it has been an optical eyeopener.
was away for a week root canalling, so this will seem way late.

IMAGE   13:
back cup restored to orig color for final radiosity, marking subtle-changes
image
tighted up area light
echof(vlength(lv)) = 11.75
arraylen = .8

Global
      max_trace_level 15
      adc_bailout .02
      (assumed_gamma default)

radiosity pass w/previous photon map (Global assumed_gamma 2.0 - radiosity rends

count 30
nearest_count 8
gray_threshold 0.02
minimum_reuse .0095
brightness 0.2



have we done all pov can do to this image yet? :p

All fimages were:
Preset INI file is 'QUICKRES.INI', section is '[640x480, AA 0.3]'.

What I think I learned

//sturm
//The following list shows all objects for which the Sturmian root solver can be
used
// lathe (only with quadratic splines)

//hollow     extra hollow in union

area light length needed adjusting for the scene 0.8 from 1.0 was noticeable
what really happened:

Parsing Options
  Input file: glasses13rad.pov (compatible to version 3.63)
  Remove bounds........On
  Split unions.........Off

Output Options
  Image resolution 640 by 480 (rows 1 to 480, columns 1 to 640).
  Output file: glasses13rad.png, 24 bpp PNG
  Graphic display......On  (gamma: 2.2)
  Mosaic preview.......Off
  CPU usage histogram..Off
  Continued trace......Off
Tracing Options
  Quality:  9
  Bounding boxes.......On   Bounding threshold: 3
  Light Buffer.........On
  Vista Buffer.........On   Draw Vista Buffer....Off
  Antialiasing.........On  (Method 1, Threshold 0.300, Depth 3, Jitter 1.00)
  Clock value:    0.000  (Animation off)

Scene Statistics
  Finite objects:            9
  Infinite objects:          1
  Light sources:             2
  Total:                    12

Render Statistics
Image Resolution 640 x 480

Pixels:           319210   Samples:          546930   Smpls/Pxl: 1.71
Rays:            7629558   Saved:           2313696   Max Level: 15/15

Ray->Shape Intersection          Tests       Succeeded  Percentage

Lathe                         53356754        32372248     60.67
Lathe Bound                   53356754        42364921     79.40
Plane                         49921022         4233572      8.48
Bounding Box                 349147797       111281847     31.87
Vista Buffer                   2918700         1976984     67.74


Roots tested:              63832664   eliminated:                    0
Calls to Noise:                   0   Calls to DNoise:              10

Shadow Ray Tests:          44638470   Succeeded:              28407418
Reflected Rays:             3964830   Total Internal:           893837
Refracted Rays:             3070967
Transmitted Rays:                26

Radiosity samples calculated:             1790 (0.15 %)
Radiosity samples reused:              1192958

Smallest Alloc:                  50 bytes
Largest  Alloc:              327728 bytes
Total Alloc calls:             3336         Free calls:           3328
Peak memory used:          10847845 bytes


Total Scene Processing Times
  Parse Time:    0 hours  0 minutes  0 seconds (0 seconds)
  Photon Time:   0 hours  0 minutes  2 seconds (2 seconds)
pervious pass:
Photon Time:   0 hours  1 minutes  14 seconds (74 seconds)
  Render Time:   1 hours 57 minutes 56 seconds (7076 seconds)
  Total Time:    1 hours 57 minutes 58 seconds (7078 seconds)
POV-Ray finished


There is likely something here to discuss regarding settings and output results.
Nice technique with all the switches and the genius behind the photons and
texture.

aQ takes Nemesis for ride in the grav-A ship. Notice there are no seat belts
needed.

oh craap now I see "dispersion_samples"
it never ends, this evolution image file could have been better and shown more
optional results.

Post a reply to this message

Attachments:
Download 'evolution.jpg' (278 KB)

Preview of image 'evolution.jpg'

really impressive, man!  You take povray rendering tests far more metodically
and seriously than I'd ever hope for! :)

"alphaQuad" <alp### [at] earthlinknet> wrote:
> Global
>       max_trace_level 15
>       adc_bailout .02
>       (assumed_gamma default)
>
> radiosity pass w/previous photon map (Global assumed_gamma 2.0 - radiosity rends

> count 30
> nearest_count 8
> gray_threshold 0.02
> minimum_reuse .0095
> brightness 0.2

oh, simple yet nice...

> // lathe (only with quadratic splines)



standard drawing curve primitive in all vector graphics programs I know of.

> //hollow     extra hollow in union

yeah, I went extra paranoid in case I was testing media for the material... :P

>   Total Time:    1 hours 57 minutes 58 seconds (7078 seconds)

well, of course normals not used. ;)

> aQ takes Nemesis for ride in the grav-A ship. Notice there are no seat belts
> needed.

that was a sweet ride, thanks. :)

I think I liked 11 the best, both the colors, coloured reflections and slightly
brighter photon mapping. :)

> oh craap now I see "dispersion_samples"
> it never ends, this evolution image file could have been better and shown more
> optional results.

someone could come up with a really nice and detailed marble material for the
ground (or table top). :)

Post a reply to this message

>>   Total Time:    1 hours 57 minutes 58 seconds (7078 seconds)
> 
> well, of course normals not used. ;)

Well, stop saying "I envy your renderfarm" and use it. Send me a zip 
with the scene and all needed includes (even the standard .incs that 
come with POV-Ray!), and image size, aa settings, and animation 
settings. Also, a rough render time estimate, so I know how many tiles 
to break it in. I'll send you back the image/animation.

Post a reply to this message