 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Travis Barton wrote:
>
> Ken,
> Hi again, is there anyway you could help me out with pov ray? I
> viewed those web pages and they have good resources but I am mainly
> looking for how to create text and also how to use all the different
> textures like S_Cloud1. If you could please help me then just mail me
> or reply back. Thanks.
> Travis Barton
Your best bet for learning the basic use of these features is by going
through Docs and the included scene files provided with the program. Each
of the scenes were provided to illustrate a feature in pov. Look in the
objects directory for a file called ttf.pov for an example of how to use
the text feature in pov. There are literaly dozens of examples for how
to use the various textures.
The basic syntax for using textures is:
#include "clouds.inc"
sphere{<0,0,0>,1 texture { S_Cloud1 } }
--
Ken Tyler
mailto://tylereng@pacbell.net
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Yea I know, about #include but how do you know that it's S_Cloud1?
Travis Barton wrote:
> Ken,
> Hi again, is there anyway you could help me out with pov ray? I
> viewed those web pages and they have good resources but I am mainly
> looking for how to create text and also how to use all the different
> textures like S_Cloud1. If you could please help me then just mail me
> or reply back. Thanks.
> Travis Barton
>
> Travis Barton wrote:
>
> > Could anyone please send me some good tutorials for pov ray? I just
> > downloaded the program yesterday and I have basic skills for the
> > software. Thanks.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Travis Barton wrote:
>
> Yea I know, about #include but how do you know that it's S_Cloud1?
My mistake. It's been a long time since I have even looked at the include
file since I usualy make all of my own.
Then include files that have multilayed textures are formated in such a
way that each texture component is predeclared as individual pigments.
It is later then combined in a declared texture statement. The S_Cloud1
you reference is one of those predeclared pigment statments. By itself
it probably will not look good as a cloudy sky and requires the other
components to look right. If you really want to try it as a stand alone
texture you would use it like this:
Note: the include I mentioned earlier should have been skies.inc
and not clouds.inc
#include "skies.inc"
sphere { < 0, 0, 0 >,1
texture {
pigment { S_Cloud1 }
} // end texture
scale 200 // scale the sky to the size needed for your scene
} // end sphere
Usualy most people use the premade textures in that file like this:
#include "skies.inc"
sphere { < 0, 0, 0 >, 1
texture { T_Cloud1 }
scale 200 // scale the sky to the size needed for your scene
} // end sphere
All of the includes use a similar scheme to note which is a texture by
using a "T" in the declaration. For example T_Stone_1A, T_Gold_5E etc.
--
Ken Tyler
mailto://tylereng@pacbell.net
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Ken,
How do I add text to my graphics? Also, what all can I do with that
text? Thanks again.
Travis
Travis Barton wrote:
> Yea I know, about #include but how do you know that it's S_Cloud1?
>
> Travis Barton wrote:
>
> > Ken,
> > Hi again, is there anyway you could help me out with pov ray? I
> > viewed those web pages and they have good resources but I am mainly
> > looking for how to create text and also how to use all the different
> > textures like S_Cloud1. If you could please help me then just mail me
> > or reply back. Thanks.
> > Travis Barton
> >
> > Travis Barton wrote:
> >
> > > Could anyone please send me some good tutorials for pov ray? I just
> > > downloaded the program yesterday and I have basic skills for the
> > > software. Thanks.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Travis Barton wrote:
>
> Ken,
> How do I add text to my graphics? Also, what all can I do with that
> text? Thanks again.
> Travis
Ken's quick tutorial for using the Pov text object
First let's start with the basic syntax of the text object. One of the
things that confuses most people is that htey try to use one of the fonts
that is in their windows font directory. If you try this make sure that
you provide the fullo path to the directory that your windows fonts are
in or Pov will not be able to find them.
e.g. text { ttf "c:\windows\fonts\myfont.ttf" 1,0 }
Render the following to see how the basic text object looks.
camera { location < 0, 0, -5> look_at 0}
light_source { <-10,10,-30> rgb 1}
text { ttf "timrom.ttf" "POV" .5,0 translate x*-.9 pigment { rgb 2}}
background { rgb .35}
The next example shows how to add raised text to another objects surface.
camera { location < 0, 0, -5> look_at 0}
light_source { <-10,10,-30> rgb 1}
union {
box { -1,1 scale<1.25,1,.25>translate <0,.5,.5> pigment { red 1}}
text { ttf "timrom.ttf" "POV" .5,0 translate x*-1 pigment { rgb 2}}
}
background { rgb .35}
This last example shows how to subtract text from another object using a
CSG operation.
camera { location < 0, 0, -5> look_at 0}
light_source { <-10,10,-30> rgb 1}
difference {
box { -1,1 scale<1.25,1,.25>translate <0,.5,.5> pigment { red 1}}
text { ttf "timrom.ttf" "POV" .5,0 translate x*-1 pigment { rgb 2}}
}
background { rgb .35}
The above three examples show how to use the internal Pov text object but
there is another method for adding any kind of picture or text to an object
using the image map operation. This will require you to supply your own image
for the code below to work. Your best bet is to go into a paint program that
has a text feature, spell whatever you want over a background color of your
choice, and then save it as a .gif file called text.gif.
camera { location < 0, 0, -5> look_at 0}
light_source { <-10,10,-30> rgb 1}
box { -0.5, 0.5
pigment {
image_map { gif "text.gif" interpolate 2 }
translate -0.5
}
scale<2.5, 2, 2.5>
}
With the text object this next suggestion is a bit redundant but there
are time is has it's attraction. There is a program called Elefont that
offers a few different text manipulation abilities you will not be able
to do in pov. On of these is the ability to bevel text among other things.
It has direct support for Pov file format. You can download a copy at:
http://www.armanisoft.ch/
Be sure to check out the other utility called spiralizer while you are
there. It is a pretty trick little tool.
The last and least desirable method is to take your completed image into
a paint program and add it in as a post processing step. Purest Pov artist
stick their nose up at people that do this but to each their own.
--
Ken Tyler
mailto://tylereng@pacbell.net
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Ken wrote:
>
> Travis Barton wrote:
> >
If you feel particularly bold (and have a Win95-system) you could have a peek at
my SoftText-program. I actually gave it a webpage! It's at
http://www.xs4all.nl/~remcodek/softtext.html
Regards,
Remco
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Ken,
Ok, last question cause I know I am bothering you. Ok, how do I add
like a glassly or ice looking texture to the font?
Thanks,
Travis
Travis Barton wrote:
> Ken,
> How do I add text to my graphics? Also, what all can I do with that
> text? Thanks again.
> Travis
>
> Travis Barton wrote:
>
> > Yea I know, about #include but how do you know that it's S_Cloud1?
> >
> > Travis Barton wrote:
> >
> > > Ken,
> > > Hi again, is there anyway you could help me out with pov ray? I
> > > viewed those web pages and they have good resources but I am mainly
> > > looking for how to create text and also how to use all the different
> > > textures like S_Cloud1. If you could please help me then just mail me
> > > or reply back. Thanks.
> > > Travis Barton
> > >
> > > Travis Barton wrote:
> > >
> > > > Could anyone please send me some good tutorials for pov ray? I just
> > > > downloaded the program yesterday and I have basic skills for the
> > > > software. Thanks.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Travis Barton wrote:
>
> Ken,
> Ok, last question cause I know I am bothering you. Ok, how do I add
> like a glassly or ice looking texture to the font?
>
> Thanks,
> Travis
You will find that I am if nothing else a very patient person who enjoys
sharing my feeble knowelge of the program with others. If you have a question
and I know the answer I will offer it in as timely manner as possible.
// setting a max trace level with clear object is important. If you fail
// to do so you will see a lot of black spots. This is mainly true for
// complex shapes and objects - like text object for example - if you
// do not get rid of the black spots with the first number you try keep
// raising it 5 units at a time until they do dissapear.
This first example is simply a glass like text object while the second
I added a bump surface normal to roughen up the surface kind of like
a frosty ice finish might appear. Try varying the number after the
"bump" keyword, the frequency, and the scale for different effects
global_settings{max_trace_level 25}
camera { location < 0, 0, -1.7> look_at 0}
light_source { <-15,1,-50> rgb 1}
text { ttf "timrom.ttf" "POV" .5,0
translate<-1,0,0>
pigment { rgbf .9 }
interior { ior 1.44 }
}
global_settings{max_trace_level 25}
camera { location < 0, 0, -1.7> look_at 0}
light_source { <-15,1,-50> rgb 1}
text { ttf "timrom.ttf" "POV" .5,0
translate <-1,0,0>
pigment { rgbf .9 }
finish { ambient .3 diffuse .1 specular 1 roughness .001 reflection .2}
interior { ior 1.44 }
normal { bumps 2 scale .01 frequency 30 }
}
background { rgb .6}
--
Ken Tyler
mailto://tylereng@pacbell.net
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
I stand in awe of your patient assistance to Mr. Barton. After the third
message my teeth were grinding so hard my wife wanted to know "what is that
weird sound you are making?".
As another recipient of your patient tutelage I just want to express my
thanks to you for the help you provide to the rest of the POV community.
--
Jim
Check out my web site http://www.kressworks.com/
It'll blow your mind (politically), stimulate your senses (artistically)
and provide scientific insights that boggle the mind!
Ken <tyl### [at] pacbell net> wrote in message
news:378### [at] pacbellnet...
>
>
> Travis Barton wrote:
> >
> > Ken,
> > Ok, last question cause I know I am bothering you. Ok, how do I
add
> > like a glassly or ice looking texture to the font?
> >
> > Thanks,
> > Travis
>
> You will find that I am if nothing else a very patient person who enjoys
> sharing my feeble knowelge of the program with others. If you have a
question
> and I know the answer I will offer it in as timely manner as possible.
>
> // setting a max trace level with clear object is important. If you fail
> // to do so you will see a lot of black spots. This is mainly true for
> // complex shapes and objects - like text object for example - if you
> // do not get rid of the black spots with the first number you try keep
> // raising it 5 units at a time until they do dissapear.
>
> This first example is simply a glass like text object while the second
> I added a bump surface normal to roughen up the surface kind of like
> a frosty ice finish might appear. Try varying the number after the
> "bump" keyword, the frequency, and the scale for different effects
>
> global_settings{max_trace_level 25}
>
> camera { location < 0, 0, -1.7> look_at 0}
> light_source { <-15,1,-50> rgb 1}
>
> text { ttf "timrom.ttf" "POV" .5,0
> translate<-1,0,0>
> pigment { rgbf .9 }
> interior { ior 1.44 }
> }
>
>
>
>
> global_settings{max_trace_level 25}
>
> camera { location < 0, 0, -1.7> look_at 0}
> light_source { <-15,1,-50> rgb 1}
>
> text { ttf "timrom.ttf" "POV" .5,0
> translate <-1,0,0>
> pigment { rgbf .9 }
> finish { ambient .3 diffuse .1 specular 1 roughness .001 reflection .2}
> interior { ior 1.44 }
> normal { bumps 2 scale .01 frequency 30 }
> }
> background { rgb .6}
>
>
> --
> Ken Tyler
>
> mailto://tylereng@pacbell.net
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Jim Kress <jim### [at] kressworkscom> wrote:
: As another recipient of your patient tutelage I just want to express my
: thanks to you for the help you provide to the rest of the POV community.
This is the good Ken. You have not seen is bad brother yet... ;)
--
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):5;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
