 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
here is a source of an iso, when rendering i get the result attached to this
message.
i do not understand why I get a flat shape,
probably there are problems calculating the normal
Or maybe something else...
If anyone knows what the problem might be...
Ill be glad to thank him
thanks for reading
Oded
the source :
#version unofficial MegaPov 0.6
#declare g = (1+sqrt(5))/2
#declare V1 = (3*g+1)*0.02
#declare V2 = (4*g+3)*0.02
isosurface {
function {
if(-1-V1*x-V2*y,1,0)+
if(-1-V1*x+V2*y,1,0)+
if(-1+V1*x-V2*y,1,0)+
if(-1+V1*x+V2*y,1,0)+
if(-1-V1*y-V2*z,1,0)+
if(-1-V1*y+V2*z,1,0)+
if(-1+V1*y-V2*z,1,0)+
if(-1+V1*y+V2*z,1,0)+
if(-1-V1*z-V2*x,1,0)+
if(-1-V1*z+V2*x,1,0)+
if(-1+V1*z-V2*x,1,0)+
if(-1+V1*z+V2*x,1,0)
}
threshold 1.5
contained_by { box {<-10,-10,-10>,<10,10,10>}}
method 1
pigment {rgb<0,1,1>}
no_shadow
}
light_source {<14,14,14> rgb<1,1,1>}
camera {
location <14,14,14>
look_at <0,0,0>
}
Post a reply to this message
Attachments:
Download 'isostar.jpg' (12 KB)
Preview of image 'isostar.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Oded wrote:
>
> here is a source of an iso, when rendering i get the result attached to this
> message.
> i do not understand why I get a flat shape,
> probably there are problems calculating the normal
> Or maybe something else...
> If anyone knows what the problem might be...
> Ill be glad to thank him
> thanks for reading
> Oded
>
I'm not sure what shape you wanted ;-), but how about:
function {
(-V1*x-V2*y)&
(-V1*x+V2*y)&
(V1*x-V2*y)&
(V1*x+V2*y)&
(-V1*y-V2*z)&
(-V1*y+V2*z)&
(V1*y-V2*z)&
(V1*y+V2*z)&
(-V1*z-V2*x)&
(-V1*z+V2*x)&
(V1*z-V2*x)&
(V1*z+V2*x)
}
leading to the attached shape.
Christoph
--
Christoph Hormann <chr### [at] gmx de>
Homepage: http://www.schunter.etc.tu-bs.de/~chris/
Post a reply to this message
Attachments:
Download 'isotest_01.jpg' (3 KB)
Preview of image 'isotest_01.jpg'
|
|
| |
| |
|
|
From: Bill DeWitt
Subject: Re: can any one tell me what's wrong with my iso?
Date: 15 Oct 2000 16:55:27
Message: <39ea19bf@news.povray.org>
|
|
|
| |
| |
|
|
"Christoph Hormann" <Chr### [at] schunteretctu-bsde> wrote :
>
> function {
> (-V1*x-V2*y)&
> (-V1*x+V2*y)&
> (V1*x-V2*y)&
> (V1*x+V2*y)&
> (-V1*y-V2*z)&
> (-V1*y+V2*z)&
> (V1*y-V2*z)&
> (V1*y+V2*z)&
> (-V1*z-V2*x)&
> (-V1*z+V2*x)&
> (V1*z-V2*x)&
> (V1*z+V2*x)
> }
I find this fascinating and have no hope of figuring it out. My
love/hate relationship with Isosurface continues.
Post a reply to this message
|
|
| |
| |
|
|
From: Tor Olav Kristensen
Subject: Re: can any one tell me what's wrong with my iso?
Date: 15 Oct 2000 20:06:18
Message: <39EA463D.1F0F451F@online.no>
|
|
|
| |
| |
|
|
There's nothing wrong with your ISO. =)
Oded wrote:
>
> here is a source of an iso, when rendering i get
> the result attached to this message.
> i do not understand why I get a flat shape,
> probably there are problems calculating the normal
> Or maybe something else...
> If anyone knows what the problem might be...
The problem is your camera position and your
light setting.
See code below my suggestion for a new scene with
your iso-surface.
The first enclosed image shows your ISO-shape.
This function also generates an interesting shape:
(The second enclosed image with the red shape)
function {
(-V1*x -V2*y)*
(-V1*x +V2*y)*
( V1*x -V2*y)*
( V1*x +V2*y)*
(-V1*y -V2*z)*
(-V1*y +V2*z)*
( V1*y -V2*z)*
( V1*y +V2*z)*
(-V1*z -V2*x)*
(-V1*z +V2*x)*
( V1*z -V2*x)*
( V1*z +V2*x)
}
Tor Olav
--
mailto:tor### [at] hotmailcom
http://www.crosswinds.net/~tok/tokrays.html
#version unofficial MegaPov 0.5;
#include "colors.inc"
#declare g = (1 + sqrt(5))/2;
#declare V1 = (3*g + 1)*0.02;
#declare V2 = (4*g + 3)*0.02;
isosurface {
function {
if(-1 - V1*x - V2*y, 1, 0)+
if(-1 - V1*x + V2*y, 1, 0)+
if(-1 + V1*x - V2*y, 1, 0)+
if(-1 + V1*x + V2*y, 1, 0)+
if(-1 - V1*y - V2*z, 1, 0)+
if(-1 - V1*y + V2*z, 1, 0)+
if(-1 + V1*y - V2*z, 1, 0)+
if(-1 + V1*y + V2*z, 1, 0)+
if(-1 - V1*z - V2*x, 1, 0)+
if(-1 - V1*z + V2*x, 1, 0)+
if(-1 + V1*z - V2*x, 1, 0)+
if(-1 + V1*z + V2*x, 1, 0)
}
threshold 1.5
contained_by { box { 10*<-1, -1, -1>, 10*<1, 1, 1> } }
method 1
pigment { color Cyan }
no_shadow
}
background { color Blue/2 }
light_source { 100*(V1*x - V2*z) color Gray60 }
light_source { 100*(V1*x + V2*y) color White }
camera {
location <2, 4, -7>*8
look_at <0, 0, 0>
angle 25
}
Post a reply to this message
Attachments:
Download 'test_iso01.jpg' (10 KB)
Download 'test_iso04.jpg' (10 KB)
Preview of image 'test_iso01.jpg'
Preview of image 'test_iso04.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Bill DeWitt wrote:
> "Christoph Hormann" <Chr### [at] schunteretctu-bsde> wrote :
> >
> > function {
> > (-V1*x-V2*y)&
> > (-V1*x+V2*y)&
> > (V1*x-V2*y)&
> > (V1*x+V2*y)&
> > (-V1*y-V2*z)&
> > (-V1*y+V2*z)&
> > (V1*y-V2*z)&
> > (V1*y+V2*z)&
> > (-V1*z-V2*x)&
> > (-V1*z+V2*x)&
> > (V1*z-V2*x)&
> > (V1*z+V2*x)
> > }
>
> I find this fascinating and have no hope of figuring it out. My
> love/hate relationship with Isosurface continues.
It's just an intersection of twelve planes in the form Ax+By+Cz. With a
dodecahedron I believe it is possible to orient it in such a way that
each plane only requires two of these components.
--
David Fontaine <dav### [at] faricynet> ICQ 55354965
My raytracing gallery: http://davidf.faricy.net/
Post a reply to this message
|
|
| |
| |
|
|
From: Bill DeWitt
Subject: Re: can any one tell me what's wrong with my iso?
Date: 15 Oct 2000 23:02:29
Message: <39ea6fc5@news.povray.org>
|
|
|
| |
| |
|
|
"David Fontaine" <dav### [at] faricynet> wrote :
>
> It's just an intersection of twelve planes in the form Ax+By+Cz. With a
> dodecahedron I believe it is possible to orient it in such a way that
> each plane only requires two of these components.
http://www.shianet.org/~reneenew/calc.html might tell you why the
phrase "it's just" made me chuckle...
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tor Olav Kristensen wrote:
>
> There's nothing wrong with your ISO. =)
>
> The problem is your camera position and your
> light setting.
>
> See code below my suggestion for a new scene with
> your iso-surface.
>
I must admit that i didn't even check if it worked somehow :-) The if(,,)
construct was very unfamiliar to me.
After thinking a bit about it, i believe it is probably the most simple way to
create this particular shape, using a CSG of planes would be quite more
complicated.
On the other hand it does not work with 'method 2' and things like surface
perturbation with noise3d and pigment functions.
Christoph
--
Christoph Hormann <chr### [at] gmxde>
Homepage: http://www.schunter.etc.tu-bs.de/~chris/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Christoph Hormann wrote:
> ...
> I must admit that i didn't even check if it worked somehow :-) The if(,,)
> construct was very unfamiliar to me.
I found out what it really does 1 hour ago :)
> After thinking a bit about it, i believe it is probably the most simple way to
> create this particular shape, using a CSG of planes would be quite more
> complicated.
I've done this with CSG and it's not much more complicated - but, yes, the
CSG-code looks uglier.
> On the other hand it does not work with 'method 2' and things like surface
> perturbation with noise3d and pigment functions.
Ehhh... I know nothing about this.
You see - I'm a newbie to MegaPOV and iso-surfaces.
Tor Olav
--
mailto:tor### [at] hotmailcom
http://www.crosswinds.net/~tok/tokrays.html
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tor Olav Kristensen wrote:
>
> > On the other hand it does not work with 'method 2' and things like surface
> > perturbation with noise3d and pigment functions.
>
> Ehhh... I know nothing about this.
> You see - I'm a newbie to MegaPOV and iso-surfaces.
>
just have a function like:
#declare fnBumps=function { noise3d(x*12, y*12, z*12) }
or
#declare fnBumps=function { pigment { agate color_map {[0 rgb 0][1 rgb 1]} } }
and add/substract it to/from the isosurface function like this:
isosurface{
function { (sqrt(x*x + y*y + z*z) -0.9) -fnBumps(x,y,z)*0.1 }
method 2
accuracy 0.001
eval
contained_by{ sphere{ <0,0,0> 1.2 } }
}
Christoph
--
Christoph Hormann <chr### [at] gmxde>
Homepage: http://www.schunter.etc.tu-bs.de/~chris/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Christoph Hormann wrote:
> ...
> #declare fnBumps=function { noise3d(x*12, y*12, z*12) }
>
> or
>
> #declare fnBumps=function { pigment { agate color_map {[0 rgb 0][1 rgb 1]} } }
>
> and add/substract it to/from the isosurface function like this:
>
> isosurface{
> function { (sqrt(x*x + y*y + z*z) -0.9) -fnBumps(x,y,z)*0.1 }
> method 2
> accuracy 0.001
> eval
> contained_by{ sphere{ <0,0,0> 1.2 } }
> }
OK - Now I understand what you mean.
Thank you for showing me this.
Tor Olav
--
mailto:tor### [at] hotmailcom
http://www.crosswinds.net/~tok/tokrays.html
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
