|
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Hi,
thanks for everybody's help, but now I face a different problem.
I'm trying to make an effect of the light coming in through the clouds,
but something in the media is wrong. Here is the source for the light,
media and clouds:
light_source
{
0*x // light's position (translated below)
color red 1.0 green 1.0 blue 1 // light's color
translate <-20000, 30000, 20>
fade_distance 3000
fade_power 2
}
//media
sphere {<0,00,0>, 1 scale <20000, 20000, 20000> translate -9999*y
texture {
pigment {color rgbf <1,1,1,1>}
}
interior {
media {
intervals 1
samples 3, 3
confidence 0.9
variance 1/128
ratio 1
scattering {3, rgb <0.4,0.4,1> extinction 0.0001}
method 3
aa_level 4 aa_threshold 0.1
}
}
hollow on
}
#end
//clouds
sphere {<0,00,0>, 1 scale <10100, 10100, 10100> translate -9999*y
texture {
pigment {
agate
color_map {
[0.3 rgbft <1, 1, 1, 1>]
[1.0 rgbft <1, 1, 1, 0>]
/*[0.3 rgbft <1, 1, 1, 0,1>]
[0.7 rgbft <1, 1, 1, 0,0.1>]
[1.0 rgbft <1, 1, 1, 0,1>]*/
}
turbulence 0.03
ramp_wave
phase clock
scale 270
}
finish {
ambient 1
}
}
hollow on
}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Diregard scattering color and exctinction settings, they were just a
test, however I do need to know what settings will work!
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
In article <38E924B7.D1B40321@netvision.net.il>, Lewis
<nle### [at] netvisionnetil> wrote:
> Hi,
> thanks for everybody's help, but now I face a different problem.
> I'm trying to make an effect of the light coming in through the clouds,
> but something in the media is wrong. Here is the source for the light,
> media and clouds:
Try something like this:
//media and clouds
sphere {<0,0,0>, 1 scale <10100, 10100, 10100> translate -10000*y
texture {
pigment {agate
color_map {
[0.0 rgbf <1, 1, 1, 1>]
[0.3 rgbf <1, 1, 1, 0>]
[1.0 rgbf <1, 1, 1, 0>]
}
turbulence 0.3
ramp_wave
phase clock
scale 270
rotate y*80
}
}
interior {
media {
intervals 1
samples 12, 12
confidence 0.9
variance 1/128
scattering {3, color rgb 0.01 extinction 0.25}
method 3
aa_level 4 aa_threshold 0.1
}
}
hollow on
double_illuminate
}
light_source {<-20000, 30000, 20000> color rgb < 1, 1, 1>}
--
Christopher James Huff - Personal e-mail: chr### [at] yahoocom
TAG(Technical Assistance Group) e-mail: chr### [at] tagpovrayorg
Web page: http://chrishuff.dhs.org/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Nice!
Can you explain?
Chris Huff wrote:
>
> In article <38E924B7.D1B40321@netvision.net.il>, Lewis
> <nle### [at] netvisionnetil> wrote:
>
> > Hi,
> > thanks for everybody's help, but now I face a different problem.
> > I'm trying to make an effect of the light coming in through the clouds,
> > but something in the media is wrong. Here is the source for the light,
> > media and clouds:
>
> Try something like this:
> //media and clouds
> sphere {<0,0,0>, 1 scale <10100, 10100, 10100> translate -10000*y
> texture {
> pigment {agate
> color_map {
> [0.0 rgbf <1, 1, 1, 1>]
> [0.3 rgbf <1, 1, 1, 0>]
> [1.0 rgbf <1, 1, 1, 0>]
> }
> turbulence 0.3
> ramp_wave
> phase clock
> scale 270
> rotate y*80
> }
> }
> interior {
> media {
> intervals 1
> samples 12, 12
> confidence 0.9
> variance 1/128
> scattering {3, color rgb 0.01 extinction 0.25}
> method 3
> aa_level 4 aa_threshold 0.1
> }
> }
> hollow on
> double_illuminate
> }
>
> light_source {<-20000, 30000, 20000> color rgb < 1, 1, 1>}
>
> --
> Christopher James Huff - Personal e-mail: chr### [at] yahoocom
> TAG(Technical Assistance Group) e-mail: chr### [at] tagpovrayorg
> Web page: http://chrishuff.dhs.org/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
In article <38E930DF.34C53EA2@netvision.net.il>, Lewis
<nle### [at] netvisionnetil> wrote:
> Nice!
> Can you explain?
Ehh, not really, I just chose what seemed to be right, but I will try:
You don't need to use the ratio keyword, as I understand it, it only
affects spotlights and cylinder lights. Since you will have rays of
light coming through the clouds, you need to raise the samples to get
the smaller details.
You had separate objects for the cloud layer and the media container.
This was just unnecessary and harder to adjust, so I put them both in
one container. The only times you would want the media container to
extend outside the cloud layer is when you are attempting a complete
simulation of the atmosphere, and then you would probably want a
separate media for the outer part.
I added double_illuminate to the cloud/media container because the light
is on the other side of it, this illuminates the visible side of the
cloud texture. You can adjust the falloff of the illumination by
changing the brilliance value in the finish.
I also changed the color_map on the clouds to use filtering only(I
rarely use transmit, filter seems more realistic for nearly everything).
I moved the light_source so it was shining toward the camera, this makes
the media show up better(since you aren't using an isometric scattering
model). This is what produces that nice glow where the "sun" is.
Other than that, I just tuned the density and extinction values to look
right.
--
Christopher James Huff - Personal e-mail: chr### [at] yahoocom
TAG(Technical Assistance Group) e-mail: chr### [at] tagpovrayorg
Web page: http://chrishuff.dhs.org/
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|