I've run across a couple of problems while rendering a few of my
scenes in the new beta.  My system's a PIII 733MHz with 256MB RAM,
and I'm running POV for Windows version 3.5 beta 1 on Windows 2000. 

First, I'm seeing some sort of corruption on an object using the
crackle pattern for both the pigment and normal aspects of the
texture.  Specifically, there are lots of horizontal streaks
running across the surface of the object in one area of it.  I
haven't seen anything like this rendering the same scene under
either version 3.1g or MegaPov 0.7 (also for Windows). 

Second, I also use Chris Colefax's Galaxy include file for many of
the scenes I do, and at least some of the backgrounds it generates
have a weird seam under 3.5 beta 1.  Basically, there's a randomly
curving horizontal boundary going across the whole background
starting somewhere near the middle.  You can see it because the
colors in the background appear slightly different on each side. 
Again, the same backgrounds didn't display this problem in either
version 3.1g or MegaPov 0.7.

Here's a link to a simple scene that demonstrates both problems I'm
seeing: 

<http://bama.ua.edu/~davis011/bugtest.png>

And here's the code that produced that image:
--------
#declare galaxy_seed = 15982;
#include "GALAXY.INC" 

camera {
	location <-20, 20, -20>
	look_at	 <-10, 20, 3>
}

light_source { <-5, 20, 3> + 0.3*<10, 0, 23> + <0, 20, 0> rgb 1.0 }
 

#local Tex1 = texture {
	pigment {
		crackle
		scale 1.25
		color_map {
			[0.00 rgb <0.00, 0.10, 0.10> ]
			[0.10 rgb <0.00, 0.30, 0.30> ]
			[0.50 rgb <0.20, 0.60, 0.60> ]
			[1.00 rgb <0.30, 0.70, 0.70> ]
		}
	}
	normal {
		crackle 2.0
		scale 1.25
	}
	finish {
		reflection 0.3
		specular 0.2 roughness 0.1
		
	}
}

#local Piece1 = union {
	#local NumRings=7;
	#local i=0;
	#while (i<NumRings)
	torus {
		0.9, 0.1
		scale <6.25, 1.25, 6.25>
		rotate z*180*i/NumRings
		translate <0, 0, -9.375>
		texture { Tex1 }
	}
	#local i=i+1;
	#end
}

#local Piece2 = sphere {
	<0,0,0>,1
	scale <7.5, 1.875, 12.5>
	texture { Tex1 }
}
	
union
{
	object { Piece1 }
	object { Piece2 }
	rotate <0, 180, 0>
	rotate <0, 0, 25>
	rotate <0, 15, 0>
	rotate <-35, 0, 0>
	translate <-5, 20, 3> + 0.3*<10, 0, 23>
}
-------
If there is something that changed that would cause this behavior
that is documented somewhere, I apologize for wasting everyone's
time, but I haven't found anything yet that would explain it.  If
it is a bug, I hope this will help track down the cause of it. 

-- 
Michael Davis
siv### [at] mindspringcom

Post a reply to this message

On 5 Sep 2001 21:18:22 -0400, Michael Davis wrote:
>First, I'm seeing some sort of corruption on an object using the
>crackle pattern for both the pigment and normal aspects of the
>texture.  Specifically, there are lots of horizontal streaks
>running across the surface of the object in one area of it.  I
>haven't seen anything like this rendering the same scene under
>either version 3.1g or MegaPov 0.7 (also for Windows). 

Any chance you can provide a scene file that shows just this effect 
without all of the other stuff?

>Second, I also use Chris Colefax's Galaxy include file for many of
>the scenes I do, and at least some of the backgrounds it generates
>have a weird seam under 3.5 beta 1.  Basically, there's a randomly
>curving horizontal boundary going across the whole background
>starting somewhere near the middle.  You can see it because the
>colors in the background appear slightly different on each side. 
>Again, the same backgrounds didn't display this problem in either
>version 3.1g or MegaPov 0.7.

This seems to be because the behavior of the "gradient" pattern has 
changed in 3.5, to get rid of the reflection about the axes.  To fix
it, you'll have to figure out where in the include file gradient is 
being used and substitute the macro that is provided for backward 
compatibility (I've forgotten the name of the macro, unfortunately.)
Alternatively, you may have to wait until Mr. Colefax gets the include
file updated for 3.5.

-- 
#macro R(L P)sphere{L F}cylinder{L P F}#end#macro P(V)merge{R(z+a z)R(-z a-z)R(a
-z-z-z a+z)torus{1F clipped_by{plane{a 0}}}translate V}#end#macro Z(a F T)merge{
P(z+a)P(z-a)R(-z-z-x a)pigment{rgbt 1}hollow interior{media{emission T}}finish{
reflection.1}}#end Z(-x-x.2y)Z(-x-x.4x)camera{location z*-10rotate x*90}

Post a reply to this message

ron### [at] povrayorg (Ron Parker) wrote in
<slr### [at] fwicom>: 

>On 5 Sep 2001 21:18:22 -0400, Michael Davis wrote:
>>First, I'm seeing some sort of corruption on an object using the
>>crackle pattern for both the pigment and normal aspects of the
>>texture.  Specifically, there are lots of horizontal streaks
>>running across the surface of the object in one area of it.  I
>>haven't seen anything like this rendering the same scene under
>>either version 3.1g or MegaPov 0.7 (also for Windows). 
>
>Any chance you can provide a scene file that shows just this
>effect without all of the other stuff?

Try this one.  It has the same object, and the camera's been moved a 
bit closer, so you should be able to see it better (assuming it isn't 
just a problem on my system).  The effect should be visible in the 
middle portion of the image.

I've played with it a bit more on my own and discovered that the 
problem goes away if you remove Piece1 (the union of 7 tori) from the 
scene, and still seems to appear (although it's harder to see) if 
Piece1 is the only thing in the scene.

------
camera {
	location <-20, 20, -20>-(<-20,20,-20>-<-5,20,3>)/2
	look_at	<-5, 20, 3>
}

light_source { <-5, 20, 3> + 0.3*<10, 0, 23> + <0, 20, 0> rgb 1.0 }  

#local Tex1 = texture {
	pigment {
		crackle
		scale 1.25
		color_map {
			[0.00 rgb <0.00, 0.10, 0.10> ]
			[0.10 rgb <0.00, 0.30, 0.30> ]
			[0.50 rgb <0.20, 0.60, 0.60> ]
			[1.00 rgb <0.30, 0.70, 0.70> ]
		}
	}
	normal {
		crackle 2.0
		scale 1.25
	}
	finish {
		reflection 0.3
		specular 0.2 roughness 0.1
		
	}
}

#local Piece1 = union {
	#local NumRings=7;
	#local i=0;
	#while (i<NumRings)
	torus {
		0.9, 0.1
		sturm
		scale <6.25, 1.25, 6.25>
		rotate z*180*i/NumRings
		translate <0, 0, -9.375>
		texture { Tex1 }
	}
	#local i=i+1;
	#end
}

#local Piece2 = sphere {
	<0,0,0>,1
	scale <7.5, 1.875, 12.5>
	texture { Tex1 }
}
	

union
{
	object { Piece1 }
	object { Piece2 }
	rotate <0, 180, 0>
	rotate <0, 0, 25>
	rotate <0, 15, 0>
	rotate <-35, 0, 0>
	translate <-5, 20, 3> + 0.3*<10, 0, 23>
}
------

I hope this helps.  Let me know if you need anything else.

-- 
Michael Davis
siv### [at] mindspringcom

Post a reply to this message

On 5 Sep 2001 23:52:35 -0400, Michael Davis wrote:
>ron### [at] povrayorg (Ron Parker) wrote in
><slr### [at] fwicom>: 
>
>>On 5 Sep 2001 21:18:22 -0400, Michael Davis wrote:
>>>First, I'm seeing some sort of corruption on an object using the
>>>crackle pattern for both the pigment and normal aspects of the
>>>texture.  Specifically, there are lots of horizontal streaks
>>>running across the surface of the object in one area of it.  I
>>>haven't seen anything like this rendering the same scene under
>>>either version 3.1g or MegaPov 0.7 (also for Windows). 
>>
>>Any chance you can provide a scene file that shows just this
>>effect without all of the other stuff?
>
>Try this one.  It has the same object, and the camera's been moved a 
>bit closer, so you should be able to see it better (assuming it isn't 
>just a problem on my system).  The effect should be visible in the 
>middle portion of the image.
>
>I've played with it a bit more on my own and discovered that the 
>problem goes away if you remove Piece1 (the union of 7 tori) from the 
>scene, and still seems to appear (although it's harder to see) if 
>Piece1 is the only thing in the scene.

Thanks, that was enough to track it down.  For those who are playing along
at home, the crackle pattern keeps a cache of what the pattern looks like
near the most-recently-sampled point, and if the next point is nearby it
uses the cache instead of recalculating the values for every point.  In
the case of #declared crackle pigments and normals, however, the cache
was inadvertently being shared between all instantiations of the #declared
pattern.  

This has been fixed in the development version; the fix should appear in 
a future beta version.  Thanks very much for the report.

-- 
#local R=<7084844682857967,0787982,826975826580>;#macro L(P)concat(#while(P)chr(
mod(P,100)),#local P=P/100;#end"")#end background{rgb 1}text{ttf L(R.x)L(R.y)0,0
translate<-.8,0,-1>}text{ttf L(R.x)L(R.z)0,0translate<-1.6,-.75,-1>}sphere{z/9e3
4/26/2001finish{reflection 1}}//ron.parker@povray.org My opinions, nobody else's

Post a reply to this message