Yesterday I posted this to the new users newsgroup... Today it looks like,
it fits better into the advanced users newsgroup:

I wondered how I could get a picture e. g. of scenes/camera/camera1a.png
(without the brown area it stands on; i mean: just the metallic bubbles and
cans -- I call it A), that shows

1.
either the 360 degrees picture on the inside of a hollow 100%-reflective
(just reflective for the camera, while the camera can't see anything else
than that reflection) cylinder, that has been put over that metallic object
A (this might be something similar to a cylindrical camera, that shows the
picture on its inside, while it surrounds the scene)

2.
or some kind of 2D projection (I have seen orange-skin-piece-projection and
that projection that morphs the upper and lower parts and of an elliptic
projection on various geographic maps) of the inside of a hollow
100%-reflective (see above) sphere, that has been wrapped around that object
A (this might be something similar to a spherical camera, that encloses the
scene and shows the picture on its inside).


Both could be used to make a map of a 3D scene like seen in some school
books and so on (world maps, ...)...

And after some wondering and reading I found, that I would have to write a
script (for version 1), that takes the middle part of each picture of an
animation. But that sounds too complicated.

Does somebody here know how to do it nicely?

Thanks.

-Arne

Post a reply to this message

RBRiddick <nomail@nomail> wrote:
> 1.
> either the 360 degrees picture on the inside of a hollow 100%-reflective
> (just reflective for the camera, while the camera can't see anything else
> than that reflection) cylinder, that has been put over that metallic object
> A (this might be something similar to a cylindrical camera, that shows the
> picture on its inside, while it surrounds the scene)

  As a side note, you seem to have a common misconception about "hollow"
objects in povray.
  All "objects" in povray are "hollow". They are just surfaces, nothing
else. Surfaces do not contain anything inside them, just empty space.
There are no "solids" in povray, just surfaces.
  The keyword 'hollow' has nothing to do with the "solidness" of objects
and has only an effect on media and fog, nothing else. (A different keyword
could be less confusing for this.)

  Anyways, this might be what you want, if I understood you correctly:

#declare UseSphericalProjection = no;

#if(UseSphericalProjection)
  camera { spherical location 0 look_at -x angle 360 }
  sphere
  { 0, 100 inverse
    pigment { rgb 0 }
    finish { reflection 1 diffuse 0 }
  }
#else
  camera { location -z*5 look_at 0 angle 35 }
#end

light_source { <10, 20, -30>, 1 }
light_source { <-20, 5, 10>, <.5, .3, 0> }
light_source { <10, -10, 20>, <0, .3, .5> }

#declare Pigm =
  pigment
  { object
    { text
      { ttf "timrom" "Hello there!" 2, 0
        scale <.2, .4, 1>
        translate y*.4
      }
      rgb 0, rgb 1
    }
    warp { spherical }
  };

// The object:
sphere
{ 0, 1
  pigment
  { pigment_pattern { Pigm }
    pigment_map
    { [0 granite color_map { [0 rgb 1][1 rgb .5] }]
      [1 granite color_map { [0 rgb x][1 rgb 0] } scale .5 ]
    }
  }
  finish { specular .5 }

  #if(UseSphericalProjection)
    no_image
  #end
}


-- 
                                                          - Warp

Post a reply to this message

>  As a side note, you seem to have a common misconception about "hollow"
> objects in povray.
>
Yes, u were right... Now I understand it better, I think...

>   Anyways, this might be what you want, if I understood you correctly:
>
Yup! :-))

That is version 2...
I will see, if I can do version 1 on my own...
Maybe something with panoramic camera and a cylinder around the scene...

Thank you!

It looks a little bit morphed in my own scene (even in the middle)...
But I think, its normal under these conditions... :-))

Bye

Post a reply to this message