I'm currently making a 3D engine and I want to use some of the features of
POV-Ray to make textures. I already have some great results by using NKFlare
for sparkles and such. However, I want to make repeatable textures for the
walls and ground.

How can this be done in POV-Ray?

Now, I know I can setup two mirror planes that cross and then we have a
repeatable textures that looks like it was made with mirrors. But there are
textures that look like dirt but are repeatable and the lines inbetween are
not visible.

Can this be done in POV-Ray? I imagine so but I need a nudge in the right
direction.

Thanks in advance!

Post a reply to this message

> How can this be done in POV-Ray?
You could render to an image &
then make tilable using the GIMP or maybe photoshop &
then use the image as an imagemap.

Other than that you would have to rely on the texture gurus around here.

Post a reply to this message

This should do what you want:
http://www.geocities.com/ccolefax/tilegen.html

All the best,

Andy Cocker


"Chris Becker" <top### [at] cshritedu> wrote in message
news:3d097b03@news.povray.org...
> I'm currently making a 3D engine and I want to use some of the features of
> POV-Ray to make textures. I already have some great results by using
NKFlare
> for sparkles and such. However, I want to make repeatable textures for the
> walls and ground.
>
> How can this be done in POV-Ray?
>
> Now, I know I can setup two mirror planes that cross and then we have a
> repeatable textures that looks like it was made with mirrors. But there
are
> textures that look like dirt but are repeatable and the lines inbetween
are
> not visible.
>
> Can this be done in POV-Ray? I imagine so but I need a nudge in the right
> direction.
>
> Thanks in advance!
>
>

Post a reply to this message

If you want to repeat textures along one direction only, it's very easy.
Just apply the texture to a hollow cylinder and place a 360 degree
cylindrical camera inside the cylinder. (The axis of the cylinder and
the axis of the cylindrical camera should be the same of course.)

If you need to repeat the texture both horizontally and vertically at
the same time, you need to use other tricks such as Chris Colefax's
utility as mentioned elsewhere in this thread. However, tiling textures
with the technique that Chris' utility uses can lead to blending, which
dependent on your texture may look very good or not very good.

Rune
--
3D images and anims, include files, tutorials and more:
Rune's World:  http://rsj.mobilixnet.dk (updated May 20)
POV-Ray Users: http://rsj.mobilixnet.dk/povrayusers/
POV-Ray Ring:  http://webring.povray.co.uk

Post a reply to this message

It's easier to do with pov3.5 than the answers already given may make you
think:

// Create a pattern function which is tileable inside <0,0,0>-<1,1,0>
#macro MakeXYTileablePatternFunc(PatternFunc)
  function
  { (PatternFunc(x,y,z)*(1-x)+PatternFunc(x-1,y,z)*x)*(1-y) +
    (PatternFunc(x,y-1,z)*(1-x)+PatternFunc(x-1,y-1,z)*x)*y
  }
#end

// Example:
// -------

#declare GranitePattern = function { pattern { granite noise_generator 1 } }

#declare TileableGranite = MakeXYTileablePatternFunc(GranitePattern)

#declare Tile =
  box
  { 0,<1,1,.1>
    pigment
    { function { TileableGranite(x,y,z) }
      color_map { [0 rgb z][1 rgb 1] }
    }
  }

// Create 4x4 boxes:
#declare IndY = -2;
#while(IndY < 2)
  #declare IndX = -2;
  #while(IndX < 2)
    object { Tile translate <IndX, IndY, 0> }
    #declare IndX = IndX+1;
  #end
  #declare IndY = IndY+1;
#end

camera { location -z*9 look_at 0 angle 35 }
light_source { -z*100, 1 }


-- 
#macro M(A,N,D,L)plane{-z,-9pigment{mandel L*9translate N color_map{[0rgb x]
[1rgb 9]}scale<D,D*3D>*1e3}rotate y*A*8}#end M(-3<1.206434.28623>70,7)M(
-1<.7438.1795>1,20)M(1<.77595.13699>30,20)M(3<.75923.07145>80,99)// - Warp -

Post a reply to this message

3d097b03@news.povray.org...
> Can this be done in POV-Ray? I imagine so but I need a nudge in the right
> direction.

Image maps are already repeated in the x-y plane, so there's nothing special
to do there.

Procedural textures can be repeated using the "repeat" warp.
 pigment {
    wood
    warp { repeat 2*x }
  }

G.

--

**********************
http://www.oyonale.com
**********************
- Graphic experiments
- POV-Ray and Poser computer images
- Posters

Post a reply to this message

Gilles Tran <tra### [at] inapginrafr> wrote:
> Procedural textures can be repeated using the "repeat" warp.
>  pigment {
>     wood
>     warp { repeat 2*x }
>   }

  I think he meant that there shouldn't be visible lines.

-- 
#macro N(D)#if(D>99)cylinder{M()#local D=div(D,104);M().5,2pigment{rgb M()}}
N(D)#end#end#macro M()<mod(D,13)-6mod(div(D,13)8)-3,10>#end blob{
N(11117333955)N(4254934330)N(3900569407)N(7382340)N(3358)N(970)}//  - Warp -

Post a reply to this message

3d0a28af@news.povray.org...
> Gilles Tran <tra### [at] inapginrafr> wrote:
> > Procedural textures can be repeated using the "repeat" warp.
> >  pigment {
> >     wood
> >     warp { repeat 2*x }
> >   }
>
>   I think he meant that there shouldn't be visible lines.

OK, OK, so it's

pigment{
    bozo
    warp{repeat 2*x flip x}
    warp{repeat 2*z flip z} // depending on the tiling direction
}

G.
--

**********************
http://www.oyonale.com
**********************
- Graphic experiments
- POV-Ray and Poser computer images
- Posters

Post a reply to this message

Excellent. Thanks a bunch!

"Andrew Cocker" <mai### [at] mariner9net> wrote in message
news:3d09bbca$1@news.povray.org...
> This should do what you want:
> http://www.geocities.com/ccolefax/tilegen.html
>
> All the best,
>
> Andy Cocker
>
>
> "Chris Becker" <top### [at] cshritedu> wrote in message
> news:3d097b03@news.povray.org...
> > I'm currently making a 3D engine and I want to use some of the features
of
> > POV-Ray to make textures. I already have some great results by using
> NKFlare
> > for sparkles and such. However, I want to make repeatable textures for
the
> > walls and ground.
> >
> > How can this be done in POV-Ray?
> >
> > Now, I know I can setup two mirror planes that cross and then we have a
> > repeatable textures that looks like it was made with mirrors. But there
> are
> > textures that look like dirt but are repeatable and the lines inbetween
> are
> > not visible.
> >
> > Can this be done in POV-Ray? I imagine so but I need a nudge in the
right
> > direction.
> >
> > Thanks in advance!
> >
> >
>
>

Post a reply to this message