Well, I don't post here because I consider myself an advanced user, but
because I need help from advanced users!!!

I'm trying to model water with a closed mesh (for example, the surface of a
sphere), so I want it to have some transparent and with refractive
properties.

However, in my early experiments, I don't think that the mesh is being
refractive, as it seems that POV is only rendering the "skin" of the mesh
and not the interior of it.

Is there any way to make POV think that the mesh is "filled" with
"substance"?

Thanks in advance for your help,

Fernando.

Post a reply to this message

I want to know just the same thing! I'd love to make weird moving mesh2
objects that are filled with smoky media gosts  :-)

I know that with clipping/csg'ing of planes simple mesh-like objects can be
done, but I'm not sure if that would be a nice or good way of doing meshes
of thousands of triangles...

regards,
Apache
http://geitenkaas.dns2go.com/experiments/

Post a reply to this message

> I'm trying to model water with a closed mesh (for example, the surface of a
> sphere), so I want it to have some transparent and with refractive
> properties.

  So apply something like:

pigment { rgbf <1,1,1,.95> }
interior { ior 1.5 }

to the mesh. What is the problem?

-- 
#macro N(D)#if(D>99)cylinder{M()#local D=div(D,104);M().5,2pigment{rgb M()}}
N(D)#end#end#macro M()<mod(D,13)-6mod(div(D,13)8)-3,10>#end blob{
N(11117333955)N(4254934330)N(3900569407)N(7382340)N(3358)N(970)}//  - Warp -

Post a reply to this message

"Warp" <war### [at] tagpovrayorg> wrote in message
news:3c7e2d05@news.povray.org...

> > I'm trying to model water with a closed mesh (for example, the surface
of a
> > sphere), so I want it to have some transparent and with refractive
> > properties.
>
>   So apply something like:
>
> pigment { rgbf <1,1,1,.95> }
> interior { ior 1.5 }
>
> to the mesh. What is the problem?

I don't see that the mesh is having refractive properties, that is, it
doesn't "distort" the image behind the object.

Fernando.

Post a reply to this message

> I don't see that the mesh is having refractive properties, that is, it
> doesn't "distort" the image behind the object.

  I do.
  Here is an example:

----------8<-----------8<-------------8<--------------8<----------8<------
camera { location <-1,2,-5> look_at 0 angle 35 }
light_source { <100,200,-150>, 1 }
plane { y,-1 pigment { checker rgb 1, rgb .5 } }

mesh
{ #declare Ind1 = 0;
  #while(Ind1 < 30)
    #declare Ang1_1 = 360*Ind1/30;
    #declare Ang1_2 = 360*(Ind1+1)/30;
    #declare Ind2 = 0;
    #while(Ind2 < 60)
      #declare Ang2_1 = 360*Ind2/60;
      #declare Ang2_2 = 360*(Ind2+1)/60;
      #declare P1 = vrotate(y, <Ang1_1, Ang2_1>);
      #declare P2 = vrotate(y, <Ang1_1, Ang2_2>);
      #declare P3 = vrotate(y, <Ang1_2, Ang2_1>);
      #declare P4 = vrotate(y, <Ang1_2, Ang2_2>);
      smooth_triangle { P1,P1, P2,P2, P3,P3 }
      smooth_triangle { P2,P2, P3,P3, P4,P4 }
      #declare Ind2 = Ind2+1;
    #end
    #declare Ind1 = Ind1+1;
  #end
  
  pigment { rgbf <1,1,1,.95> }
  finish { specular 1 roughness .01}
  interior { ior 1.5 }
}
----------8<-----------8<-------------8<--------------8<----------8<------

-- 
#macro M(A,N,D,L)plane{-z,-9pigment{mandel L*9translate N color_map{[0rgb x]
[1rgb 9]}scale<D,D*3D>*1e3}rotate y*A*8}#end M(-3<1.206434.28623>70,7)M(
-1<.7438.1795>1,20)M(1<.77595.13699>30,20)M(3<.75923.07145>80,99)// - Warp -

Post a reply to this message

That's a very clever counterexample!

Thanks,

Fernando.

Post a reply to this message

Warp <war### [at] tagpovrayorg> wrote:
>     #declare Ang1_1 = 360*Ind1/30;
>     #declare Ang1_2 = 360*(Ind1+1)/30;

  Oops! That should be:

    #declare Ang1_1 = 180*Ind1/30;
    #declare Ang1_2 = 180*(Ind1+1)/30;

-- 
#macro M(A,N,D,L)plane{-z,-9pigment{mandel L*9translate N color_map{[0rgb x]
[1rgb 9]}scale<D,D*3D>*1e3}rotate y*A*8}#end M(-3<1.206434.28623>70,7)M(
-1<.7438.1795>1,20)M(1<.77595.13699>30,20)M(3<.75923.07145>80,99)// - Warp -

Post a reply to this message