Hi good people of the POV community!

In my current project, of wich i yet say nothing further, I experience
weird "effects" or "artefacts" in my used sphere_sweep, when viewing it from
certain angles. I have no image, but maybe this is a known problem? Question
is, can these things be removed? I tried raising tolerance, but it's still
there. This is the code i use:

sphere_sweep {
  linear_spline

  16,
  < 0.24,  3.19, 0>, 0.027
  < 0.5,   3.20, 0>, 0.027
  < 0.75,  3.22, 0>, 0.027
  < 1.0,   3.24, 0>, 0.027
  < 1.25,  3.26, 0>, 0.027
  < 1.5,   3.30, 0>, 0.027
  < 1.75,  3.35, 0>, 0.027
  < 2.0,   3.45, 0>, 0.027
  < 2.25,  3.55, 0>, 0.027
  < 2.5,   3.65, 0>, 0.027
  < 2.75,  3.75, 0>, 0.027
  < 3.0,   3.82, 0>, 0.027
  < 3.25,  3.88, 0>, 0.027
  < 3.5,   3.92, 0>, 0.027
  < 3.75,  3.94, 0>, 0.027
  < 3.974, 3.95, 0>, 0.027
  tolerance 0.00001

texture {T_Brass_5E } texture {Rust scale 0.1   finish {ambient 0.001}   }
rotate <0,0,0> translate <0,0,0> }

Post a reply to this message

"RusHHouR" <gee### [at] mailnu> wrote:
> Hi good people of the POV community!
>
> In my current project, of wich i yet say nothing further, I experience
> weird "effects" or "artefacts" in my used sphere_sweep, when viewing it from
> certain angles. I have no image, but maybe this is a known problem? Question
> is, can these things be removed? I tried raising tolerance, but it's still
> there. This is the code i use:
>
> sphere_sweep {
>   linear_spline
>
>   16,
>   < 0.24,  3.19, 0>, 0.027
>   < 0.5,   3.20, 0>, 0.027
>   < 0.75,  3.22, 0>, 0.027
>   < 1.0,   3.24, 0>, 0.027
>   < 1.25,  3.26, 0>, 0.027
>   < 1.5,   3.30, 0>, 0.027
>   < 1.75,  3.35, 0>, 0.027
>   < 2.0,   3.45, 0>, 0.027
>   < 2.25,  3.55, 0>, 0.027
>   < 2.5,   3.65, 0>, 0.027
>   < 2.75,  3.75, 0>, 0.027
>   < 3.0,   3.82, 0>, 0.027
>   < 3.25,  3.88, 0>, 0.027
>   < 3.5,   3.92, 0>, 0.027
>   < 3.75,  3.94, 0>, 0.027
>   < 3.974, 3.95, 0>, 0.027
>   tolerance 0.00001
>
> texture {T_Brass_5E } texture {Rust scale 0.1   finish {ambient 0.001}   }
> rotate <0,0,0> translate <0,0,0> }


Hi.

What are your camera settings? With a camera looking at the middle point of
your spline, it is OK!

Post a reply to this message

Apparently the small size has something to do with it. I can see why Bruno 
probably didn't see anything wrong, I rendered it and got a mostly okay line 
except for a perpendicular dashed line intersecting it a little to the left 
of center.

I don't get many renderings made lately but I do have a recent scene file 
using a sphere_sweep to outline some property shown against aerial photos 
and I was starting with a scale of 1870 by 1750 pixels for the entire area 
but the property itself is only a fraction of that size. The sphere sweep 
broke into pieces when decimal numbers, similar to yours there, are used and 
I had to scale the whole thing upward to remove the breaks. Likewise, 
setting a tolerence wasn't helping it.

It might not seem reasonable for the sphere_sweep to be rendered incorrectly 
at a not-so-extremely small 0.027 radius compared to some other common 
objects but it wasn't too many POV versions ago that a sphere {<0,0,0>, 
0.02} had potential problems being rendered. I think the sphere_sweep might 
still be suffering a little from something like that, so the solution for 
you is probably going to be an increase of the scene scale. Looks to me like 
maybe a 0.1 radius could be okay, possibly just 0.08 (closest to where I 
couldn't see a problem while zoomed in on a defective part), or about three 
times, or more, that current radius.

If I'm wrong about this, anyone, please go ahead and debate my answer but 
that's what I found after some rescaling.  ;)

-- 
Bob H  www.3digitaleyes.com
http://3digitaleyes.com/imagery/

Post a reply to this message

"Bob Hughes" answered:

Hi!
Glad you saw it too!
Thanks for your answer. I will try it out and see if it works for me.
But, if it does, rescaling the scene.. seems a bit timeconsuming... o_0
Is there any other clever way of creating the same shape?

Post a reply to this message

"Bruno Cabasson" <bru### [at] alcatelaleniaspacefr> sang:
> Hi.
>
> What are your camera settings? With a camera looking at the middle point of
> your spline, it is OK!

You should view it with camera in -x and look at the +x direction.
That's when I see it. You find it too?

Post a reply to this message

"RusHHouR" <gee### [at] mailnu> wrote in message 
news:web.440fae135b3b05b847d3ae5e0@news.povray.org...
> "Bob Hughes" answered:
>
> Thanks for your answer. I will try it out and see if it works for me.

okay, happy to help.

> But, if it does, rescaling the scene.. seems a bit timeconsuming... o_0

You could union {} the entire scene except for the camera, just multiplying 
the location and look_at by the same amount you scale by.

> Is there any other clever way of creating the same shape?

A spline path of lotsa spheres. Maybe something like this:

camera {location <2,3,-4> look_at <1.9,3.2,0>}
light_source {<10,10,-100>,1}

#local i = 0.05; // smaller, more spheres; larger, less

#declare SphSwp=spline {
  linear_spline
  1,< 0.24,  3.19, 0>
  2,< 0.5,   3.20, 0>
  3,< 0.75,  3.22, 0>
  4,< 1.0,   3.24, 0>
  5,< 1.25,  3.26, 0>
  6,< 1.5,   3.30, 0>
  7,< 1.75,  3.35, 0>
  8,< 2.0,   3.45, 0>
  9,< 2.25,  3.55, 0>
  10,< 2.5,   3.65, 0>
  11,< 2.75,  3.75, 0>
  12,< 3.0,   3.82, 0>
  13,< 3.25,  3.88, 0>
  14,< 3.5,   3.92, 0>
  15,< 3.75,  3.94, 0>
  16,< 3.974, 3.95, 0>
}

union {
#local I=1;
#while (I<=16)
sphere {
 SphSwp(I),0.027
}
#local I=I+i;
#end
texture {pigment {rgb 1}}
}

Post a reply to this message

"Bob Hughes" <omniverse@charter%net> wrote:

Wow, lot's of "#", but looks manageble.
Thank you very much for your help! =D

Post a reply to this message