 |
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Anthony D. Baye" <Sha### [at] spamnomore hotmailcom> wrote:
> I need a water material that looks good under multiple light sources but doesn't
> bog down when I render it with radiosity.
>
> The water in my scene is taking forever to render, and I've disabled everything
> but the normal pattern.
>
> Part of the problem might be a low aa threshold combined with a small focal
> blur, but the rest of the scene renders acceptably quickly.
A reaonable fast water material is the one from the povray benchmark:
#declare RMF = function {f_ridged_mf (x,y,z, 0.07, 2.2, 7, 0.6, 0.9, 1)}
#declare M_Watx4 =
material {
texture {
pigment {color rgbt <0.21,0.2,0.3,0.96>}
finish {
diffuse 0
ambient 0
reflection {0.1, 0.95 fresnel on exponent 0.8}
conserve_energy
specular 0.1*10
roughness 0.007
metallic 0+0.5
}
normal {
function {RMF (x,y,z)} 0.2
scale 0.07
}
}
interior {
ior 1.31
fade_distance 0.8
fade_power 1001
fade_color <0.02,0.2,0.06>
}
}
Imho the diffuse value of 0 is very important.
If it seems too dark, rising the fade_color value is helpful.
Norbert
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Am 03.08.2015 um 15:43 schrieb Norbert Kern:
> A reaonable fast water material is the one from the povray benchmark:
>
> #declare RMF = function {f_ridged_mf (x,y,z, 0.07, 2.2, 7, 0.6, 0.9, 1)}
>
> #declare M_Watx4 =
> material {
> texture {
> pigment {color rgbt <0.21,0.2,0.3,0.96>}
In theory it should be "rgbt <0.0,0.0,0.0, 1.0>"
> finish {
> diffuse 0
> ambient 0
Those two are important indeed.
> reflection {0.1, 0.95 fresnel on exponent 0.8}
At least theoretically that should be "reflection { 1.0 fresnel on }"
> conserve_energy
Very important.
> specular 0.1*10
> roughness 0.007
To better match the reflection, it should be "specular albedo 1.0"
(provided you go for the theoretical value).
If you use a new (semi-official) version of POV-Ray, placing an
additional "fresnel on" here would also help for more realism.
> metallic 0+0.5
In theory it shouldn't be metallic.
> }
> normal {
> function {RMF (x,y,z)} 0.2
> scale 0.07
> }
> }
> interior {
> ior 1.31
> fade_distance 0.8
> fade_power 1001
> fade_color <0.02,0.2,0.06>
For realism, you should also have some scattering component (read:
scattering media) in the interior.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Le 15-08-03 03:16, Le_Forgeron a écrit :
> Le 03/08/2015 05:27, Anthony D. Baye a écrit :
>> I need a water material that looks good under multiple light sources
>> but doesn't
>> bog down when I render it with radiosity.
>>
>> The water in my scene is taking forever to render, and I've disabled
>> everything
>> but the normal pattern.
>>
>> Part of the problem might be a low aa threshold combined with a small
>> focal
>> blur, but the rest of the scene renders acceptably quickly.
>>
>> I'd appreciate any help.
>>
>> Regards,
>> A.D.B.
>>
>>
> A bit more context please: is it water for indoor (such as inside tube,
> glass, bottle) or outdoor (and kind of latitude: the sea of polynesia is
> far different from the waves of scotland, same water, yet not the same
> final colour).
>
> Maybe also limiting the trace level, if it does not impact too much the
> result, might provided a speed up. Default is 5, which in 3.7 counts for
> the reflexion but not the transmission when the ior does not change. If
> you have a kind of echo chamber (two partially reflecting surfaces on
> each other) it might skyrocket the number of ray to launch, and the
> render time. Tunning down the max_trace_level can reduces that echo
> effect (but might impact realism if it's an important aspect of your
> scene).
>
> Are you using media in your water ? why is there a normal pattern ?
> (what is the normal pattern in use ? can it be simplified or removed ?)
>
>
I often find it beter to increase adc_bailout than reduce max_trace_level.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On Mon, 03 Aug 2015 05:27:58 +0200, Anthony D. Baye
<Sha### [at] spamnomorehotmailcom> wrote:
> I need a water material that looks good under multiple light sources but
> doesn't
> bog down when I render it with radiosity.
>
> The water in my scene is taking forever to render, and I've disabled
> everything
> but the normal pattern.
>
> Part of the problem might be a low aa threshold combined with a small
> focal
> blur, but the rest of the scene renders acceptably quickly.
>
> I'd appreciate any help.
>
> Regards,
> A.D.B.
>
>
Have you tried adding no_radiosity to the water?
--
-Nekar Xenos-
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Le_Forgeron <lef### [at] freefr> wrote:
> Le 03/08/2015 05:27, Anthony D. Baye a écrit :
> > I need a water material that looks good under multiple light sources but doesn't
> > bog down when I render it with radiosity.
> >
> > The water in my scene is taking forever to render, and I've disabled everything
> > but the normal pattern.
> >
> > Part of the problem might be a low aa threshold combined with a small focal
> > blur, but the rest of the scene renders acceptably quickly.
> >
> > I'd appreciate any help.
> >
> > Regards,
> > A.D.B.
> >
> >
> A bit more context please: is it water for indoor (such as inside tube,
> glass, bottle) or outdoor (and kind of latitude: the sea of polynesia is
> far different from the waves of scotland, same water, yet not the same
> final colour).
>
Right. Because of the salts dissolved in the water.
That said: It's nothing special.
pigment { rgbft <1.000, 1.000, 1.000, 1.000, 0.618> }
finish {
diffuse 0.3
specular 0.8
reflection { 0.3, 1 falloff 5 }
conserve_energy
}
normal {
function {
f_ridged_mf(x,y,z, 0.1, 3.0, 7.0, 0.7, 0.7, 2)
} 0.3
scale <4.68, 3.2, 4.68>/12
}
interior {
ior 1.33
fade_distance 3
fade_power 2
fade_color rgb <0.235, 0.318, 0.618>
dispersion 1.016
dispersion_samples 10
}
it's intended to be indoors, but may be lighted with external (natural) light
sources. At the moment, I have six light sources surrounding it.
I used a normal as a substitute for actual geometry (Originally, I was using an
isosurface)
my trace level is default.
I tried commenting out the interior and the finish, to no avail, so either it's
the normal, or a combination of other things.
@Nekar
>
> Have you tried adding no_radiosity to the water?
>
> --
> -Nekar Xenos-
it doesn't matter. The water takes forever to render even with radiosity turned
off.
Regards,
A.D.B.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Anthony D. Baye" <Sha### [at] spamnomorehotmailcom> wrote:
> it's intended to be indoors, but may be lighted with external (natural) light
> sources. At the moment, I have six light sources surrounding it.
I'm going to guess that there's your big problem. Have you tried cutting out
some of the lights and seeing if you get a proportional increase in speed? In
my experience, multiple lights are bad enough - once you have reflection and
transparency, things get S-L-O-W.
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
On Tue, 04 Aug 2015 00:04:37 +0200, Anthony D. Baye
<Sha### [at] spamnomorehotmailcom> wrote:
> Le_Forgeron <lef### [at] freefr> wrote:
>> Le 03/08/2015 05:27, Anthony D. Baye a écrit :
>> > I need a water material that looks good under multiple light source
s
>> but doesn't
>> > bog down when I render it with radiosity.
>> >
>> > The water in my scene is taking forever to render, and I've disable
d
>> everything
>> > but the normal pattern.
>> >
>> > Part of the problem might be a low aa threshold combined with a sma
ll
>> focal
>> > blur, but the rest of the scene renders acceptably quickly.
>> >
>> > I'd appreciate any help.
>> >
>> > Regards,
>> > A.D.B.
>> >
>> >
>> A bit more context please: is it water for indoor (such as inside tub
e,
>> glass, bottle) or outdoor (and kind of latitude: the sea of polynesia
is
>> far different from the waves of scotland, same water, yet not the sam
e
>> final colour).
>>
> Right. Because of the salts dissolved in the water.
> That said: It's nothing special.
>
> pigment { rgbft <1.000, 1.000, 1.000, 1.000, 0.618> }
> finish {
> diffuse 0.3
> specular 0.8
> reflection { 0.3, 1 falloff 5 }
> conserve_energy
> }
> normal {
> function {
> f_ridged_mf(x,y,z, 0.1, 3.0, 7.0, 0.7, 0.7, 2)
> } 0.3
> scale <4.68, 3.2, 4.68>/12
> }
> interior {
> ior 1.33
> fade_distance 3
> fade_power 2
> fade_color rgb <0.235, 0.318, 0.618>
> dispersion 1.016
> dispersion_samples 10
> }
>
> it's intended to be indoors, but may be lighted with external (natural
)
> light
> sources. At the moment, I have six light sources surrounding it.
>
> I used a normal as a substitute for actual geometry (Originally, I was
> using an
> isosurface)
>
> my trace level is default.
>
> I tried commenting out the interior and the finish, to no avail, so
> either it's
> the normal, or a combination of other things.
>
> @Nekar
>>
>> Have you tried adding no_radiosity to the water?
>>
>> --
>> -Nekar Xenos-
>
> it doesn't matter. The water takes forever to render even with
> radiosity turned
> off.
>
> Regards,
> A.D.B.
>
>
Maybe you could try and render the scene without the water and your focu
s
objects as a spherical hdri. Then use that image mapped to a sphere as i
n
the old MegaPov example
http://megapov.inetart.net/manual-1.1/tutorials_hdri.html
--
-Nekar Xenos-
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
"Anthony D. Baye" <Sha### [at] spamnomorehotmailcom> wrote:
> pigment { rgbft <1.000, 1.000, 1.000, 1.000, 0.618> }
> finish {
> diffuse 0.3
> specular 0.8
> reflection { 0.3, 1 falloff 5 }
> conserve_energy
> }
> normal {
> function {
> f_ridged_mf(x,y,z, 0.1, 3.0, 7.0, 0.7, 0.7, 2)
> } 0.3
> scale <4.68, 3.2, 4.68>/12
> }
> interior {
> ior 1.33
> fade_distance 3
> fade_power 2
> fade_color rgb <0.235, 0.318, 0.618>
> dispersion 1.016
> dispersion_samples 10
> }
I see some issues like a transparency of 161.8 %, but this does not slow your
render down, at least it doesn't in my standard setup.
Even turning fresnel on or diffuse 0 doesn't have any effect on render time.
But turning dispersion off decreased render time to less than 20 %.
Norbert
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Sorry for the delay.
I almost always use the following material for (outside) water which
renders reasonably fast and looks good. See my Not Islay scene in p.b.i.
material {
texture {
pigment {rgbft <0,0,0,1,1>}
finish {
conserve_energy
diffuse albedo 0.2
specular albedo 0.2
roughness 0.001
ambient 0
reflection {
0.0, 0.2
fresnel on
metallic off
#if (Uber)
roughness 0.001
#end
}
}
normal {crackle 0.15 scale <0.45*4,0.25,0.25>*4 turbulence 0.5 }
//normal {ripples 0.15 scale <0.45,0.25,0.25>*2 turbulence 0.5 }
}
interior {
ior 1.33
media {
method 3
absorption 0.3
density {rgb 1/FD}
}
media {
method 3
samples 100
jitter 0.5
scattering {3, 0.05}
density {
granite
color_map {
[0.30 rgb <0.2, 0.2, 0.2>]
[0.70 rgb <0.7, 0.7, 0.7>]
}
scale 1/2
//warp {turbulence <6, 0.5, 2>}
warp {turbulence <8, 2, 2>}
scale 2
}
}
}
}
--
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
You need also this before using the material:
#declare Dist = 10;
//determines the depth transparency of the water column
#declare FD = -(Dist/(6*25.4))/ln(0.58);
//fade distance (formula by Trevor Quayle)
--
Thomas
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
|
|
