On 21-7-2011 10:16, kiwon wrote:
>    #declare myvolume = union {
>      box {0, 1 clipped_by {mysurface}}
>      mysurface
>    }
>


Try:

#declare myvolume = union {
   box {0, 1 clipped_by {mysurface}}
   object {mysurface}
}

Thomas

Post a reply to this message

Thomas de Groot <tenDOTlnDOTretniATtoorgedDOTt> wrote:
> On 21-7-2011 10:16, kiwon wrote:
> >    #declare myvolume = union {
> >      box {0, 1 clipped_by {mysurface}}
> >      mysurface
> >    }
> >
>
>
> Try:
>
> #declare myvolume = union {
>    box {0, 1 clipped_by {mysurface}}
>    object {mysurface}
> }

Tried, but the same error msg on the "clipped_by" line:
Parse Error: Illegal texture or patch in clip, bound or object pattern.
The clipped_by doesn't seem to work with mesh2.

Post a reply to this message

"kiwon" <nomail@nomail> wrote:
> Thomas de Groot <tenDOTlnDOTretniATtoorgedDOTt> wrote:
> > On 21-7-2011 10:16, kiwon wrote:
> > >    #declare myvolume = union {
> > >      box {0, 1 clipped_by {mysurface}}
> > >      mysurface
> > >    }
> > >
> >
> >
> > Try:
> >
> > #declare myvolume = union {
> >    box {0, 1 clipped_by {mysurface}}
> >    object {mysurface}
> > }
>
> Tried, but the same error msg on the "clipped_by" line:
> Parse Error: Illegal texture or patch in clip, bound or object pattern.
> The clipped_by doesn't seem to work with mesh2.

If I put *inside_vector y* (because the surface's average normal direction is y
direction) in mysurface, it seems to construct what I intend. But the rendering
result has noise on that solid mesh.

Post a reply to this message

On 21-7-2011 14:29, kiwon wrote:
> Thomas de Groot<tenDOTlnDOTretniATtoorgedDOTt>  wrote:
>> On 21-7-2011 10:16, kiwon wrote:
>>>     #declare myvolume = union {
>>>       box {0, 1 clipped_by {mysurface}}
>>>       mysurface
>>>     }
>>>
>>
>>
>> Try:
>>
>> #declare myvolume = union {
>>     box {0, 1 clipped_by {mysurface}}
>>     object {mysurface}
>> }
>
> Tried, but the same error msg on the "clipped_by" line:
> Parse Error: Illegal texture or patch in clip, bound or object pattern.
> The clipped_by doesn't seem to work with mesh2.
>
>
>
>
What about:

#declare myvolume =
intersection {
   box {0, 1}
   object {mysurface}
}


Thomas

Post a reply to this message

"kiwon" <nomail@nomail> wrote:
> If I put *inside_vector y* (because the surface's average normal direction is y

That's not how inside_vector works.

It simply defines the specified point to be *inside* the object, thus
determining its inside and outside.

Post a reply to this message

Thomas de Groot <tenDOTlnDOTretniATtoorgedDOTt> wrote:
> On 21-7-2011 14:29, kiwon wrote:
> > Thomas de Groot<tenDOTlnDOTretniATtoorgedDOTt>  wrote:
> >> On 21-7-2011 10:16, kiwon wrote:
> >>>     #declare myvolume = union {
> >>>       box {0, 1 clipped_by {mysurface}}
> >>>       mysurface
> >>>     }
> >>>
> >>
> >>
> >> Try:
> >>
> >> #declare myvolume = union {
> >>     box {0, 1 clipped_by {mysurface}}
> >>     object {mysurface}
> >> }
> >
> > Tried, but the same error msg on the "clipped_by" line:
> > Parse Error: Illegal texture or patch in clip, bound or object pattern.
> > The clipped_by doesn't seem to work with mesh2.
> >
> >
> >
> >
> What about:
>
> #declare myvolume =
> intersection {
>    box {0, 1}
>    object {mysurface}
> }

Doesn't work. It keep only mysurface. The following are a simple test codes
for my purpose:

#version 2.7

global_settings {
  assumed_gamma 1.33
  max_trace_level 30
}

camera {
  right -x*image_width/image_height
  location <0.0, 2.2, 2.7>
  look_at <0.0, 0.5, 0.5>
}

light_source {
  <500, 500, -200>
  color rgb 1.3
}


#declare myF = finish {
  ambient 0
  diffuse 0
  phong 1
  phong_size 200
  reflection {
    0.01, 1
    fresnel on
  }
  conserve_energy
}

#declare myT = texture {
  pigment { rgbf <0.9,0.3,0.3 0.95> }
  finish { myF }
}

#declare myI = interior {
  ior 1.33
  fade_distance 10
  fade_power 2
}

#declare myM = material {
  interior{myI}
  texture {myT}
}

#declare TestSurf = mesh2 {
  vertex_vectors {
    4,
    <0, 0.5, 0>,
    <1, 0.5, 0>,
    <0, 0.5, 1>,
    <1, 0.4, 1>,
  }
  face_indices {
    2,
    <0, 1, 3>,
    <0, 3, 2>,
  }
  inside_vector y
}

#declare TestVol = union {
  box{0, 1 clipped_by{TestSurf}}
  TestSurf
}

#declare TestObj = object {
  TestVol
  translate <-0.5, -0.5, -0.5>
  material {myM}
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6, 0.7, 1.0>]
      [0.7 rgb <0.0, 0.1, 0.8>]
    }
  }
}

plane {
  y, -0.2
  texture {
    pigment { color rgb <1.0, 0.8, 0.6> }
    finish { ambient 0 diffuse 1 }
  }
}

object {
  TestObj
  translate <0, 0.5, 0.5>
}

Post a reply to this message

"Roman Reiner" <lim### [at] gmxde> wrote:
> "kiwon" <nomail@nomail> wrote:
> > If I put *inside_vector y* (because the surface's average normal direction is y
>
> That's not how inside_vector works.
>
> It simply defines the specified point to be *inside* the object, thus
> determining its inside and outside.

Really? I don't think so. Please check the manual *3.4.2.3.1 Solid Mesh* it
says:
.....
To determine if a point is inside a triangle mesh, POV-Ray shoots a ray from the
point in some arbitrary direction. If this vector intersects an odd number of
triangles, the point is inside the mesh. If it intersects an even number of
triangles, the point is outside of the mesh. You can specify the direction of
this vector. For example, to use +z as the direction, you would add the
following line to the triangle mesh description (following all other mesh data,
but before the object modifiers).
  inside_vector <0, 0, 1>
This change does not have any effect on unions of triangles, these will still be
always hollow.
.....

Post a reply to this message

Roman Reiner <lim### [at] gmxde> wrote:
> "kiwon" <nomail@nomail> wrote:
> > If I put *inside_vector y* (because the surface's average normal direction is y

> That's not how inside_vector works.

> It simply defines the specified point to be *inside* the object, thus
> determining its inside and outside.

  Nope. inside_vector defines a *direction*, not a point.

  When determining if a point is inside the mesh or not, a ray will be
shot in that specified direction from that point, and the number of
intersections with the mesh counted. (If the count is odd, then the point
is determined to be inside.)

  For closed meshes in theory there's little significance on which direction
you choose. Basically any direction would work equally well. There are certain
pathological circumstances where the chosen direction becomes crucial, though.
For example, if you have a triange that's exactly on the xy plane, choosing
an inside_vector x (or any other vector that's on the xy plane) can cause
the insideness calculations to fail for points on that plane. While this is
quite unlikely to happen and show visible effects, in theory it can happen.
That's why you should try to choose a direction that is not tangential to
any of the triangles, if possible.

-- 
                                                          - Warp

Post a reply to this message

Warp <war### [at] tagpovrayorg> wrote:
>   For closed meshes in theory there's little significance on which direction
> you choose.

  I forgot to mention the other situation, ie. open meshes: In this case
the chosen direction is *very* crucial, as it determines which direction
the endless "interior" of the open mesh will face. For example, if you have
a "heightfield" built up as a mesh, placed on the xz plane, you want its
interior to be below it, ie. pointing to the negative y direction. In that
case you would use "inside_vector y" (which means that interior testing
rays are shot right up).

  (Solid open meshes can often be useful in conjunction with csg, and
perhaps sometimes even on their own, even though in this case you have
to take into account that the "interior" of the mesh will extend to
infinity at the opposite direction of the inside_vector.)

-- 
                                                          - Warp

Post a reply to this message

> Dear POV-Ray users,
>
> when there is only a surface mesh, is there any way to construct a solid
> (volumetric) mesh covered by other solid object boundary such as box?
>
> This codes are what I'm just trying, but doesn't seem to work:
>
>    #declare mysurface = mesh2 {
>      ... surface data
>    }
>
>    #declare myvolume = union {
>      box {0, 1 clipped_by {mysurface}}
>      mysurface
>    }
>
> Thanks
>
> Tested in Persistence of Vision(tm) Ray Tracer Version 3.7.0.RC3
> Issued: Parse Error: Illegal texture or patch in clip, bound or object pattern.
>
>
>

I see absolutely no logical to use that kind of construction.

clipped_by cuts a hole in your box and leave it open. You then plug it 
with your mysurface object.
If mysurface don't cover exactly the wanted opening, there will be bits 
of the parent object sticking or bits of the mesh protuding around.

If you use this:
intersection{
  box{0, 1}
  object{mysurface}
  texture{...}
}

With a mysurface that have a proper inside_vector, you will have the 
same result.

Also, mysurface can now be defined with a texture if you want to, or 
need it (like when using an UV maped texture)


Alain

Post a reply to this message