Hi guys, I was wondering if anyone has attempted to create the Matrix bullet
time effect. Or if someone has an idea on how to do it.

Kind Regards

Fidel.

Post a reply to this message

> Hi guys, I was wondering if anyone has attempted to create the Matrix
bullet
> time effect. Or if someone has an idea on how to do it.

// predeclare objects agent, bullet, and neo
object {agent translate z*10}
object {bullet translate z*(10 - 20*clock)}
object {neo translate -z*5}

camera {
    location <0,10-7*clock,-(10-5*clock)>
    look_at 0
    rotate y*360*clock
    translate -z*5
}

Heh... untested code, btw.

 - Slime
[ http://www.slimeland.com/ ]

Post a reply to this message

Slime wrote:
> 
> > Hi guys, I was wondering if anyone has attempted to create the Matrix
> bullet
> > time effect. Or if someone has an idea on how to do it.
> 
> // predeclare objects agent, bullet, and neo
> object {agent translate z*10}
> object {bullet translate z*(10 - 20*clock)}
> object {neo translate -z*5}
> 
> camera {
>     location <0,10-7*clock,-(10-5*clock)>
>     look_at 0
>     rotate y*360*clock
>     translate -z*5
> }
> 
> Heh... untested code, btw.
> 
>  - Slime
> [ http://www.slimeland.com/ ]

I couldn't see it...
;)

(no light)

Remco

Post a reply to this message

> I couldn't see it...

neither could Greg

-tgq

Post a reply to this message

Hi Slime, 
Thanks for your reply, but I was actually interested in the effect of the
bullet. That is the wave trails it leaves in the air.
The bullet is  travelling and leaving trails. That's what I am looking for.

Thanks once againg.

Fidel.

in article 3db9d52f@news.povray.org, Slime at slm### [at] slimelandcom wrote on
26/10/02 12:35 am:

>> Hi guys, I was wondering if anyone has attempted to create the Matrix
> bullet
>> time effect. Or if someone has an idea on how to do it.
> 
> // predeclare objects agent, bullet, and neo
> object {agent translate z*10}
> object {bullet translate z*(10 - 20*clock)}
> object {neo translate -z*5}
> 
> camera {
> location <0,10-7*clock,-(10-5*clock)>
> look_at 0
> rotate y*360*clock
> translate -z*5
> }
> 
> Heh... untested code, btw.
> 
> - Slime
> [ http://www.slimeland.com/ ]
> 
>

Post a reply to this message

IIRC, this may be quite difficult.  I think that there were rings of
"turbulence" or whatever coming out as the bullet went through the air -
quite simple if you can get a nice looking transparent texture.
However, I also recall them distorting the background, ie refracting,
but without a solid edge.  This is the only case that I can think of (so
far) where variable IOR would be nice to have.  Perhaps the effect could
be re-created with a set of lens objects, becoming very thin and flat at
the edges (for no distortion), with a sort of ring-like bulge that moves
outwards.  Definitiely a case for isosurfaces or meshes here.


"Fidel viegas" <fid### [at] artrecognitioncouk> wrote in message
news:B9E04BB0.5B66%fid### [at] artrecognitioncouk...
> Hi Slime,
> Thanks for your reply, but I was actually interested in the effect of
the
> bullet. That is the wave trails it leaves in the air.
> The bullet is  travelling and leaving trails. That's what I am looking
for.
>
> Thanks once againg.
>
> Fidel.
>
> in article 3db9d52f@news.povray.org, Slime at slm### [at] slimelandcom wrote
on
> 26/10/02 12:35 am:
>
> >> Hi guys, I was wondering if anyone has attempted to create the
Matrix
> > bullet
> >> time effect. Or if someone has an idea on how to do it.
> >
> > // predeclare objects agent, bullet, and neo
> > object {agent translate z*10}
> > object {bullet translate z*(10 - 20*clock)}
> > object {neo translate -z*5}
> >
> > camera {
> > location <0,10-7*clock,-(10-5*clock)>
> > look_at 0
> > rotate y*360*clock
> > translate -z*5
> > }
> >
> > Heh... untested code, btw.
> >
> > - Slime
> > [ http://www.slimeland.com/ ]
> >
> >
>

Post a reply to this message

Fidel viegas wrote:
> Thanks for your reply, but I was actually interested
> in the effect of the bullet. That is the wave trails
> it leaves in the air.

Not finished code ready for the purpose, but maybe something that can
get you started:

#include "transforms.inc"
camera {location <2,3,-8> look_at 0}
light_source {<0,10,0>, color 1}
global_settings {max_trace_level 100}
sky_sphere {pigment {gradient y color_map {[0,rgb 1][1,blue 1]}}}
plane {y, 0 pigment {checker rgb 0.3 rgb 0.9} normal {quilted 0.5}}

#macro BulletWave(Location,Normal,Radius,Strength,Ior)
   intersection {
      cylinder {
         -0.0001*y, 0.0001*y, 1
         pigment {rgbf 1.0}
         normal {cylindrical Strength sine_wave phase -1/4}
      }
      cylinder {
         -0.0002*y, 0*y, 1.2
         pigment {rgbf 1.0}
      }
      interior {ior Ior}
      scale Radius
      transform {Point_At_Trans(Normal)}
      translate Location
   }
#end

#declare StartP = <0,2,-8>;
#declare DirV   = <0.2,0.1,1>/4;
#declare C = 0;
#declare Waves = 100;
#while (C<Waves)
   BulletWave(StartP+C*DirV,DirV,0.3+0.1*sin(C/2),0.02,2)
   #declare C = C+1;
#end


Rune
--
3D images and anims, include files, tutorials and more:
rune|vision:  http://runevision.com (updated Oct 19)
POV-Ray Ring: http://webring.povray.co.uk

Post a reply to this message

in article 3dbaeb9b$1@news.povray.org, Run### [at] runejohansen@mobilixnet.dk
> Not finished code ready for the purpose, but maybe something that can
> get you started:
> 
> #include "transforms.inc"
> camera {location <2,3,-8> look_at 0}
> light_source {<0,10,0>, color 1}
> global_settings {max_trace_level 100}
> sky_sphere {pigment {gradient y color_map {[0,rgb 1][1,blue 1]}}}
> plane {y, 0 pigment {checker rgb 0.3 rgb 0.9} normal {quilted 0.5}}
> 
> #macro BulletWave(Location,Normal,Radius,Strength,Ior)
> intersection {
> cylinder {
> -0.0001*y, 0.0001*y, 1
> pigment {rgbf 1.0}
> normal {cylindrical Strength sine_wave phase -1/4}
> }
> cylinder {
> -0.0002*y, 0*y, 1.2
> pigment {rgbf 1.0}
> }
> interior {ior Ior}
> scale Radius
> transform {Point_At_Trans(Normal)}
> translate Location
> }
> #end
> 
> #declare StartP = <0,2,-8>;
> #declare DirV   = <0.2,0.1,1>/4;
> #declare C = 0;
> #declare Waves = 100;
> #while (C<Waves)
> BulletWave(StartP+C*DirV,DirV,0.3+0.1*sin(C/2),0.02,2)
> #declare C = C+1;
> #end

Thank you all for the replies. Rune, that is definitely a start. I'll play
around with it. Thanks a lot.

All the best

Fidel.

Post a reply to this message

Remco de Korte <rem### [at] onwijscom> wrote in 
news:3DB9F151.C368ED78@onwijs.com

> I couldn't see it...
> ;)
> (no light)

Neo has ambient and is illuminating sorrounding bullets and agent :)



-- 
#macro g(U,V)(.4*abs(sin(9*sqrt(pow(x-U,2)+pow(y-V,2))))*pow(1-min(1,(sqrt(
pow(x-U,2)+pow(y-V,2))*.3)),2)+.9)#end#macro p(c)#if(c>1)#local l=mod(c,100
);g(2*div(l,10)-8,2*mod(l,10)-8)*p(div(c,100))#else 1#end#end light_source{
y 2}sphere{z*20 9pigment{function{p(26252423)*p(36455644)*p(66656463)}}}//M

Post a reply to this message

Fidel viegas schrieb:
> Hi guys, I was wondering if anyone has attempted to create the Matrix bullet
> time effect. Or if someone has an idea on how to do it.

Just have a look at this site:

http://www.jefflew.com/articles.html

It's not done in POV-Ray, but perhaps it helps.

Bonsai


-- 
<--------------------------->
    ___ __ __  _ ___ ___  _
   | _ )  \  \( )  _) _ )( )
   | _ \() |\ \ |\ \/ _ \| |
   |___/__/_)\__)___)/ \_)_)

        www.b0n541.net
<--------------------------->

Post a reply to this message