|
![](/i/fill.gif) |
Rebel^v^ wrote:
>I need to help with my diamond material, I still
>can not find the real looking values. (Those does not look well)
Here is my diamond. I tried to make it physically accurate.
----------------------------------------------------------------------
#declare M_Diamond = material {
texture {
pigment {
rgbf <0.95294, 0.95294, 0.90588, 1>
quick_color rgb <0.95294, 0.95294, 0.90588>
}
finish {
ambient 0
diffuse 1
//reflection 0.4011
reflection { 1.0 fresnel }
}
}
interior {
ior 2.418
//caustics 1
dispersion 1.044
dispersion_samples 7
}
}
----------------------------------------------------------------------
I didn't write any highlight because highlights are dependent from
lightning.
Reflection 0.4011 is approximate reflection calculated from fresnel
reflection. You can use it instead of fresnel to get more speed.
Approximate reflection value is also useful when calculating highlight
specular values when using low intensities in lightsources.
Uncomment caustics 1 if you don't use photons. Default dispersion_samples is
7. You can multiply it to get better detail. For perfect dispersion
multiply it with contrast levels of the output image. Example 255 for 24bit
image.
I recommend you to use photons and set max_trace_level high. Please render
your diamond scene to us :)
Matti
Post a reply to this message
|
![](/i/fill.gif) |