On Wed, 18 Apr 2001 08:54:51 +0200, Anton Raves wrote:
>I thought it would be quicker if I could find an URL in which they show
>one, the following address below shows a transparent green one at the
>rear of that model.
>
>http://www.brickshelf.com/scans/2000/2964/2964-15.html

This is a little close.  I adapted it from my golf ball code, so if there
are any variables with funny names, that's why:

#local Angle=12;
#local BandAngle=10;
#local Radius=2.33;

#local Alt=0;
#local AzOfs=0;

#declare HalfSphere=intersection {
  plane {-y,0}         
  #while (Alt <= 90)
    #local Az=AzOfs;
    #while (Az < 360)
      plane {y, Radius
        bounded_by {sphere {Radius*y, Radius/8}}
        rotate <0,0,90-Alt>
        rotate <0,Az,0>
      }
      #local Az=Az+Angle;
    #end
    #if (Alt >= 30)
      #if ( Angle < 72 )
        #local Angle=360/(360/Angle-5);
      #else
        #local Angle=360;
      #end                 
    #else
      #local AzOfs=Angle/2-AzOfs;
    #end
    #local Alt=Alt+BandAngle;
  #end
    
  bounded_by { sphere {0, Radius * 1.1}}
}

object {HalfSphere pigment {color rgb 1}}
camera {location <0,3,-6> look_at 0}
light_source {<-200,200,-200> color rgb 1}

-- 
Ron Parker   http://www2.fwi.com/~parkerr/traces.html
My opinions.  Mine.  Not anyone else's.

Post a reply to this message