POV-Ray : Newsgroups : povray.newusers : How to set the texture of the tiles like in this post? Server Time
28 Mar 2024 08:54:53 EDT (-0400)
  How to set the texture of the tiles like in this post? (Message 1 to 10 of 10)  
From: mathzhaoliang
Subject: How to set the texture of the tiles like in this post?
Date: 31 Jan 2018 08:10:00
Message: <web.5a71bfcf49b5a7c6f40ebf290@news.povray.org>
Hi: I'm trying to render the Penrose tilings like this:
http://news.povray.org/povray.binaries.images/thread/%3C4edaf05f@news.povray.org%3E/

I could compute all the coordinates of the rhombus, but I dont know how to set
the texture of the floor like the ones in the link. Can anyone help me with
this?


Post a reply to this message

From: William F Pokorny
Subject: Re: How to set the texture of the tiles like in this post?
Date: 31 Jan 2018 09:02:17
Message: <5a71cc69$1@news.povray.org>
On 01/31/2018 08:08 AM, mathzhaoliang wrote:
> 
> Hi: I'm trying to render the Penrose tilings like this:
> http://news.povray.org/povray.binaries.images/thread/%3C4edaf05f@news.povray.org%3E/
> 
> I could compute all the coordinates of the rhombus, but I dont know how to set
> the texture of the floor like the ones in the link. Can anyone help me with
> this?
> 
> 
A tiling.pov sample scene is installed along with POV-Ray and in linux 
it can be found at:

<install_dir>/share/povray-3.8/scenes/textures/patterns/tiling.pov

The install directory is normally /usr/local.

You can also find the most current versions of the sample scenes 
directory on github. For example:

https://github.com/POV-Ray/povray/tree/master/distribution/scenes/textures/patterns

Bill P.


Post a reply to this message

From: Alain
Subject: Re: How to set the texture of the tiles like in this post?
Date: 31 Jan 2018 19:12:20
Message: <5a725b64@news.povray.org>
Le 18-01-31 à 08:08, mathzhaoliang a écrit :
> 
> Hi: I'm trying to render the Penrose tilings like this:
> http://news.povray.org/povray.binaries.images/thread/%3C4edaf05f@news.povray.org%3E/
> 
> I could compute all the coordinates of the rhombus, but I dont know how to set
> the texture of the floor like the ones in the link. Can anyone help me with
> this?
> 
> 
It use the tiling number 25. This is a 6 colour pattern.
You need to provide a colour_map with 12 entries : 6 for the faces of 
the tiles and 6 for the grout or space between the faces.
You may omit the grout entry if you want.
If you skip some entries, then you'll get faces with the same colour.

Something like this :
colour_map{
  [0   rgb<1,0,0>][1/6-0.001 rgb 0]
  [1/6 rgb<0,1,0>][2/6-0.001 rgb 0]
  [2/6 rgb<0,0,1>][3/6-0.001 rgb 0]
  [3/6 rgb<1,1,0>][4/6-0.001 rgb 0]
  [4/6 rgb<1,0,1>][5/6-0.001 rgb 0]
  [5/6 rgb<0,1,1>][0.999 rgb 0]
}


Post a reply to this message

From: clipka
Subject: Re: How to set the texture of the tiles like in this post?
Date: 1 Feb 2018 07:24:42
Message: <5a73070a$1@news.povray.org>
Am 01.02.2018 um 01:12 schrieb Alain:
> Le 18-01-31 à 08:08, mathzhaoliang a écrit :
>>
>> Hi: I'm trying to render the Penrose tilings like this:
>>
http://news.povray.org/povray.binaries.images/thread/%3C4edaf05f@news.povray.org%3E/
...
> It use the tiling number 25.

That would be "P1" Penrose tiling. The first image in the thread uses
"P3" Penrose tiling, which in POV-Ray is implemented as tiling number 27.

P1 tiling is demonstrated a few posts later in the same thread.


Post a reply to this message

From: mathzhaoliang
Subject: Re: How to set the texture of the tiles like in this post?
Date: 7 Feb 2018 21:30:00
Message: <web.5a7bb5725130315ecee47e5f0@news.povray.org>
Alain <kua### [at] videotronca> wrote:
> Le 18-01-31 à 08:08, mathzhaoliang a écrit :
> >
> > Hi: I'm trying to render the Penrose tilings like this:
> >
http://news.povray.org/povray.binaries.images/thread/%3C4edaf05f@news.povray.org%3E/
> >
> > I could compute all the coordinates of the rhombus, but I dont know how to set
> > the texture of the floor like the ones in the link. Can anyone help me with
> > this?
> >
> >
> It use the tiling number 25. This is a 6 colour pattern.
> You need to provide a colour_map with 12 entries : 6 for the faces of
> the tiles and 6 for the grout or space between the faces.
> You may omit the grout entry if you want.
> If you skip some entries, then you'll get faces with the same colour.
>
> Something like this :
> colour_map{
>   [0   rgb<1,0,0>][1/6-0.001 rgb 0]
>   [1/6 rgb<0,1,0>][2/6-0.001 rgb 0]
>   [2/6 rgb<0,0,1>][3/6-0.001 rgb 0]
>   [3/6 rgb<1,1,0>][4/6-0.001 rgb 0]
>   [4/6 rgb<1,0,1>][5/6-0.001 rgb 0]
>   [5/6 rgb<0,1,1>][0.999 rgb 0]
> }


My problem is not with the tiling pattern, I have a program that calculates the
coordinates for me. I want to reproduce the texture of the ciremic floors. As a
newbie to pov I just don't know how to set the finish params to get effects lik
e that.


Post a reply to this message

From: mathzhaoliang
Subject: Re: How to set the texture of the tiles like in this post?
Date: 8 Feb 2018 00:40:01
Message: <web.5a7be29a5130315ecee47e5f0@news.povray.org>
clipka <ano### [at] anonymousorg> wrote:
> Am 01.02.2018 um 01:12 schrieb Alain:
> > Le 18-01-31 à 08:08, mathzhaoliang a écrit :
> >>
> >> Hi: I'm trying to render the Penrose tilings like this:
> >>
http://news.povray.org/povray.binaries.images/thread/%3C4edaf05f@news.povray.org%3E/
> ...
> > It use the tiling number 25.
>
> That would be "P1" Penrose tiling. The first image in the thread uses
> "P3" Penrose tiling, which in POV-Ray is implemented as tiling number 27.
>
> P1 tiling is demonstrated a few posts later in the same thread.

Hi clipka: I have just realized you are the author of the images in that thread.
Could you share the code that how you set the texture of the floor tiles?
Thanks!

(I just want the texture because I want to use it in other tiling image)


Post a reply to this message

From: clipka
Subject: Re: How to set the texture of the tiles like in this post?
Date: 8 Feb 2018 04:31:17
Message: <5a7c18e5$1@news.povray.org>
Am 08.02.2018 um 06:39 schrieb mathzhaoliang:

> Hi clipka: I have just realized you are the author of the images in that thread.
> Could you share the code that how you set the texture of the floor tiles?
> Thanks!

I had to dig a little, but here it is:


#declare TILING = 27;
#declare N      = 2;

#declare Nm = normal {
  tiling TILING
  slope_map {
    #for (I,0,N-1)
      [ (I + 0.0)/N <1, 0> ]
      [ (I + 0.8)/N <1, 0> ]
      [ (I + 1.0)/N <0,-1> ]
      [ (I + 1.0)/N <0, 0> ]
    #end
  }
}

#declare Fn = finish {
  ambient 0.1
  diffuse albedo 0.5
  specular albedo 0.3 roughness 0.001
  reflection { 0.3 }
}

#declare Tx1 = texture {
  pigment { color rgb 0.5 }
  finish { Fn }
  normal { Nm }
}

#declare Tx2 = texture {
  pigment { color rgb 0.5 }
  finish { Fn }
  normal { Nm }
}

#declare Tx3 = texture {
  pigment { color rgb 0.5 }
  finish { Fn }
  normal { Nm }
}

#declare Tx4 = texture {
  pigment { color blue 0.5 }
  finish { Fn }
  normal { Nm }
}

#declare Tx5 = texture {
  pigment { color blue 0.5 }
  finish { Fn }
  normal { Nm }
}

#declare Tx6 = texture {
  pigment { color blue 0.5 }
  finish { Fn }
  normal { Nm }
}

#if (N = 2)
  #declare Tx2 = texture { Tx6 }
#end

#declare TxGap = texture {
  pigment { color rgb 0.1 }
  normal { bumps 0.5 scale 0.001 }
}

plane{y,0
  texture{
    tiling TILING
    texture_map {
      [ (0 + 0.00)/N Tx1 ]
      [ (0 + 0.95)/N Tx1 ]
      [ (0 + 0.95)/N TxGap ]
      [ (0 + 1.00)/N TxGap ]
      [ (1 + 0.00)/N Tx2 ]
      [ (1 + 0.95)/N Tx2 ]
      [ (1 + 0.95)/N TxGap ]
      [ (1 + 1.00)/N TxGap ]
      [ (2 + 0.00)/N Tx3 ]
      [ (2 + 0.95)/N Tx3 ]
      [ (2 + 0.95)/N TxGap ]
      [ (2 + 1.00)/N TxGap ]
      [ (3 + 0.00)/N Tx4 ]
      [ (3 + 0.95)/N Tx4 ]
      [ (3 + 0.95)/N TxGap ]
      [ (3 + 1.00)/N TxGap ]
      [ (4 + 0.00)/N Tx5 ]
      [ (4 + 0.95)/N Tx5 ]
      [ (4 + 0.95)/N TxGap ]
      [ (4 + 1.00)/N TxGap ]
      [ (5 + 0.00)/N Tx6 ]
      [ (5 + 0.95)/N Tx6 ]
      [ (5 + 0.95)/N TxGap ]
      [ (5 + 1.00)/N TxGap ]
    }
  }
}


Post a reply to this message

From: mathzhaoliang
Subject: Re: How to set the texture of the tiles like in this post?
Date: 8 Feb 2018 22:45:01
Message: <web.5a7d18b95130315e9eb06e6a0@news.povray.org>
Hi clipka: Thanks for your help! But my problem is still there: my tiling shapes
are not among these built-in ones, it's like the penrose tilings but the
rhombus are arranged in other way (each rhombi is computed and specified by its
4 corners, in fact it's called aperiodic tilings), and I have to set the texture
for each rhombi manually. So the normal type identifier **tiling Tiling** does
not work in my problem.

This is the image what I get using only your finish config:

https://photos.app.goo.gl/SN6FMAxniqNVnrpd2


Post a reply to this message

From: clipka
Subject: Re: How to set the texture of the tiles like in this post?
Date: 9 Feb 2018 06:38:14
Message: <5a7d8826$1@news.povray.org>
Am 09.02.2018 um 04:43 schrieb mathzhaoliang:

> Hi clipka: Thanks for your help! But my problem is still there: my tiling shapes
> are not among these built-in ones, it's like the penrose tilings but the
> rhombus are arranged in other way (each rhombi is computed and specified by its
> 4 corners, in fact it's called aperiodic tilings), and I have to set the texture
> for each rhombi manually. So the normal type identifier **tiling Tiling** does
> not work in my problem.

To be nitpicking, the Penrose tilings /are/ aperiodic tilings. They're
/quasicrystals/ though, which not all aperiodic tilings are.

If your tiling is not a Penrose tiling, then you're out of luck with the
`tiling` pattern: If it's not in the repertoire, you can't get it this way.

It may be possible to achieve your goal with a function pattern, but I'd
expect it to be non-trivial, and also potentially slow to render.

The inbuilt Penrose tiling is not implemented via precomputed rhombus
corners, but rather via an iterative algorithm based on substitution
rules, so this approach cannot be extended to non-regular aperiodic tilings.


Post a reply to this message

From: mathzhaoliang
Subject: Re: How to set the texture of the tiles like in this post?
Date: 9 Feb 2018 10:20:00
Message: <web.5a7dbb165130315e9eb06e6a0@news.povray.org>
clipka <ano### [at] anonymousorg> wrote:
> Am 09.02.2018 um 04:43 schrieb mathzhaoliang:
>
> > Hi clipka: Thanks for your help! But my problem is still there: my tiling shapes
> > are not among these built-in ones, it's like the penrose tilings but the
> > rhombus are arranged in other way (each rhombi is computed and specified by its
> > 4 corners, in fact it's called aperiodic tilings), and I have to set the texture
> > for each rhombi manually. So the normal type identifier **tiling Tiling** does
> > not work in my problem.
>
> To be nitpicking, the Penrose tilings /are/ aperiodic tilings. They're
> /quasicrystals/ though, which not all aperiodic tilings are.
>
> If your tiling is not a Penrose tiling, then you're out of luck with the
> `tiling` pattern: If it's not in the repertoire, you can't get it this way.
>
> It may be possible to achieve your goal with a function pattern, but I'd
> expect it to be non-trivial, and also potentially slow to render.
>
> The inbuilt Penrose tiling is not implemented via precomputed rhombus
> corners, but rather via an iterative algorithm based on substitution
> rules, so this approach cannot be extended to non-regular aperiodic tilings.


Updated work: it's very closed to your image now

https://photos.app.goo.gl/eVfKrhS46Au1vsay1

By aperiodic tilings I mean a large class of generalized Penrose style
tilings consist of rhombus such that any two of them are not locally isomorphic
with each other, it's generated by de
Brujin's penta grid method. The usual Penrose tiling is just a special case of
it.


Post a reply to this message

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.