I'd like to create an earth, I've also the needed texture file, but how can
I glue it to a sphere?

The POV-Ray Help file has not been helpful yet...

Pixel [[]]

Post a reply to this message

"Christian Kollross" <cko### [at] lycosde> wrote in message
news:3f7f437c$1@news.povray.org...
> I'd like to create an earth, I've also the needed texture file, but how
can
> I glue it to a sphere?
>
> The POV-Ray Help file has not been helpful yet...

Hmmm, was it helpful before I posted this reply to you?  :-)

The documentation should have been able to show you the answer just by
looking up "image" or "map" in the Index.

Answer:

pigment {
    image_map {
        jpeg "yourimagefile.jpg" // one of the accepted file formats
        map_type 1 // this is spherical wrapping
    }
}

Not saying you aren't smart enough to use the POV-Ray Help, of course. I
realize everyone goes about using it in different ways, and therefore people
don't always find what they are looking for without some reading or learning
how to use the documentation first.

Good luck with the rendered Earth.

Bob H.

Post a reply to this message

// Hi Christian,
//
// renderings of earth and other planets (stand-alone or for an
// orrery) are posted in the POV-Ray newsgroups from time to time,
// for example "rendering mars" in p.b.i., 2003/15/08, by Christoph
// Hormann.
//
// These sections of the documentation will be relevant for you:
//
// 6.7.1.5 Image Maps
// 6.7.12.6.5 Mapping using warps
// 6.7.12.7 Bitmap modifiers
//
// The following code is a complete scene illustrating all this.
// The first (left) sphere has a simple image map; the second
// (right) sphere has a planar image map "warped" onto it; this
// is much more flexible.
//
// Searching for "DEM" or "Digital Elevation Map" in the POV-Ray
// newsgroups will give you some hints for a "bumpy" earth.
//
//    Sputnik



// spheres with image maps

// +SP8 +EP8 +A0.1 +AM2 +R3 -FN +D


sphere { 0, 1
  pigment {
    image_map {
      png "povmap.png" // in standard POV-Ray include directory
      map_type 1 // spherical mapping
      interpolate 2 // bilinear
      }
    }
  finish { ambient .4 diffuse .8 }
  translate -1.3*x
  }


#declare Rows = 4;
#declare Columns = 5;

sphere { 0, 1

  pigment {

    // get a planar image from <0,0> to <1,1>
    image_map {
      png "povmap.png"
      //once
      map_type 0 // planar mapping
      interpolate 2 // bilinear
      }

    // shrink to get Rows*Columns images into <0,0> to <1,1>
    scale <1/Columns, 1/Rows, 1>

    // also try this rotation!
    //rotate 30*z

    // use this translation together with "once" (in image_map above)
    //translate <.75, .5, 0>

    // wrap it around a sphere centered at <0,0,0>
    warp { spherical } // "warp", not "wrap"!

    }//pigment

  finish { ambient .4 diffuse .8 }
  translate 1.3*x

  }//sphere


background { color 1 }
light_source { <-10, 3, -6>, 1 }
camera { location <4, 4, -7> look_at 0 angle 30 }

Post a reply to this message

"Christian Kollross" <cko### [at] lycosde> wrote in message
news:3f7f437c$1@news.povray.org...
> I'd like to create an earth, I've also the needed texture file, but
how can
> I glue it to a sphere?
>
> The POV-Ray Help file has not been helpful yet...


  Hi Christian, take a look here for a great earth image and code,
very useful:

http://www.lancs.ac.uk/postgrad/thomasc1/render/planets/earth.htm


   ~Steve~


>
> Pixel [[]]
>
>

Post a reply to this message

"St." <dot### [at] dotcom> wrote in message
news:3f7ff95e$1@news.povray.org...
>
>   Hi Christian, take a look here for a great earth image and code,
> very useful:
>
> http://www.lancs.ac.uk/postgrad/thomasc1/render/planets/earth.htm

   Oh, sorry, that page has gone and there's a redirection page that
leads to... nothing. Hmm.. I was only on that site last week and
downloaded the .zip. I can mail you the files if you would like?

 (Can anyone else get to the site?)

   ~Steve~

>
>
>    ~Steve~
>
>
> >
> > Pixel [[]]
> >
> >
>

Post a reply to this message

No, that Site seems to be dead...

Thank you, my problem has been solved by another post...

Post a reply to this message

Thank you, that code was exactly what I've been looking for.

I know that I'm not so good at using the POV-Ray Help, but one reason might
be that I don't always find the correct keywords for searching because I
originally speak German. "Picture" would probably have been a great keyword
to use but when thinking of a keyword my brain sowehow blocked and I decided
to use the tree structure where I probably was mislead by some expressions I
understood wrong at first sight...

Thank you all for your quick responses!

Post a reply to this message

"Christian Kollross" <cko### [at] lycosde> wrote in message
news:3f800d0d@news.povray.org...
> No, that Site seems to be dead...
>
> Thank you, my problem has been solved by another post...

     Well, I've found the right site now, and it may still be worth
taking a look. It has three .png images used for the terrain, sea and
clouds - it's good.

    http://members.shaw.ca/evildrganymede/art/planets/earth.htm

   ~Steve~

>
>

Post a reply to this message

"Christian Kollross" <cko### [at] lycosde> wrote in message
news:3f800ee2@news.povray.org...
> Thank you, that code was exactly what I've been looking for.
>
> I know that I'm not so good at using the POV-Ray Help, but one reason
might
> be that I don't always find the correct keywords for searching because I
> originally speak German. "Picture" would probably have been a great
keyword
> to use but when thinking of a keyword my brain sowehow blocked and I
decided
> to use the tree structure where I probably was mislead by some expressions
I
> understood wrong at first sight...

Ah-ha. Makes perfect sense now why you weren't able to find a quick answer
from within the Help.

Bob H.

Post a reply to this message

http://members.shaw.ca/evildrganymede/art/planets/earth.htm

Thank you, that's another good world map, also available as a complete image
file.

Post a reply to this message