Can i make light spot projector using map .avi file ( or image .png like
diapo) like in 3DS MAX using POVRAY.

Tank's

-- 

-----------------------------------------

Paolo Rudelli
http://paolo.rudelli.lickthetoad.org

Post a reply to this message

"PR" <a> wrote in message news:3fa0be36@news.povray.org...
> Can i make light spot projector using map .avi file ( or image .png like
> diapo) like in 3DS MAX using POVRAY.


Not directly from AVI. Indirectly, yes, if you extract frames. Or yes, if
you use a compatible image file type like PNG. Again, no, not from .avi
unless you extract the frames first.

If you want to create a movie within a movie (POV-Ray animation) effect then
that is possible if you have the individual frames (image files) to input as
a pigment image_map.

You can project the images onto a surface by using filtered transparency in
the image *film*, like when a light shines through a real movie projector
past film and onto screen.

I have a basic (and outdated) example pov and include files of movie within
movie in my "Links" at the website below (please click the [eyes] graphic to
get there).

If you need to know more about something else concerning this just post a
message reply. Especially if you are trying to do more than what I
described.
-- 
Bob H.
http://www.3digitaleyes.com

Post a reply to this message

Thank for info

i tray to do image weare i project light (like vido projector) into a mirror
refleting into a wall.the same image.

I use pov-ray few year a go and now a need again for this project because is
support caustic light (light reflection into a mirror)

if you have some sugestion ...





news:3fa0cea1$1@news.povray.org...
> "PR" <a> wrote in message news:3fa0be36@news.povray.org...
> > Can i make light spot projector using map .avi file ( or image .png like
> > diapo) like in 3DS MAX using POVRAY.
>
>
> Not directly from AVI. Indirectly, yes, if you extract frames. Or yes, if
> you use a compatible image file type like PNG. Again, no, not from .avi
> unless you extract the frames first.
>
> If you want to create a movie within a movie (POV-Ray animation) effect
then
> that is possible if you have the individual frames (image files) to input
as
> a pigment image_map.
>
> You can project the images onto a surface by using filtered transparency
in
> the image *film*, like when a light shines through a real movie projector
> past film and onto screen.
>
> I have a basic (and outdated) example pov and include files of movie
within
> movie in my "Links" at the website below (please click the [eyes] graphic
to
> get there).
>
> If you need to know more about something else concerning this just post a
> message reply. Especially if you are trying to do more than what I
> described.
> -- 
> Bob H.
> http://www.3digitaleyes.com
>
>

Post a reply to this message

"PR" <a> wrote in message news:3fa20cca@news.povray.org...
> Thank for info
>
> i tray to do image weare i project light (like vido projector) into a
mirror
> refleting into a wall.the same image.
>
> I use pov-ray few year a go and now a need again for this project because
is
> support caustic light (light reflection into a mirror)

Okay, what you want to do is use 'photons' for that. Then the light can
reflect off of surfaces such as a mirror. Maybe you already knew that, not
easy to read minds here.

Might be a problem with this, since photons only approximate the behavior of
refracted and reflected light rays. I'll see if I can show an example soon,
just in case you weren't having any success or had not tried that yet.

For the image-within-image effect, the inxframe.zip at my website's links
webpage should work for that, since the example animated gif there does
exactly that. If I remember right (was years ago I did that) you must render
the whole scene as animation first, then reuse the image frames as the
image_map while rendering the animation again.

Bob H.

Post a reply to this message

/* how a slide projector might work in POV 3.5 */

#version 3.5;

global_settings {
  assumed_gamma 1.0
  photons {
   spacing 0.003 // quality (lower better)
  }
}

// ----------------------------------------

camera {
  location  <0, 3, -3>
  right     x*image_width/image_height
  look_at   <0, 1, 0>
}

light_source {
  <0,0,0>, color rgb 1
  looks_like {cone {-x/2,1/4,x/2,1/2 pigment {rgb 1} finish {ambient 0.5}}}
  spotlight
  radius 6 falloff 8
  point_at x
  rotate 45*y translate <-3, 0, 3>
}

// ----------------------------------------

plane {
  y, -1
  texture {
    pigment { checker color rgb 1 color blue 1 scale 0.5 }
  }
  photons {
   collect off // no photons gathered here
  }
}

/* MIRROR */
box {-1,1 scale <1,1,.1>
 pigment {rgb 0}
 finish {ambient 0 diffuse 0 reflection {0.1,1}}
  photons { // make visible to light rays
   target
   reflection on
   refraction off
  }
}

/* SCREEN */
box {-1,1 scale <1,1,.1>
 pigment {rgb 1}
 finish {ambient 0 diffuse 0.5}
 rotate 45*y translate <3,0,3>
  photons { // make visible to light rays
   //target
   collect on
  }
}

/* PICTURE */
box {
  0, 1
  clipped_by {plane {-z,0}}
  texture {
    pigment {
      image_map {
        gif "test.gif"
        interpolate 2 // smooth it
        once   // don't tile image, just one copy
        filter 0 0.5  // make 1st color half transparent
        filter 1 1  // make 2nd color mostly transparent
        filter 2 0.75  // make 3rd color 3/4 transparent
      }
      // transform it to unit-size (-1 to +1)
    }
    finish { ambient 0.3 }
  }
      translate -0.5*(x+y) // center on the origin
      scale 2              // make it unit-sized
      /* now fit in front of light */
  scale <1,1,0.1>/4 rotate -45*y translate <-2,0,2>
  photons { // make visible to light rays
   target
   reflection off
   refraction off
   pass_through // let light pass by
   collect off // no photons gathered here
  }
}

/////////////////////////

There might be such an example scene file someplace else but I went ahead
with my on try anyhow.

Again, you may have already realized how to do this but you did not say
exactly. I wanted to prove it could be done to some extent myself anyhow,
and of course, with enough photons packed into the area the "projected"
could be fine enough. Only slower and slower to parse, perhaps, depending on
the complexity of the objects used.

Bob H.

Post a reply to this message

Thank's for the script i try and is working ...

i have to do some test more i let you know

PR


news:3fa3650d@news.povray.org...
> /* how a slide projector might work in POV 3.5 */
>
> #version 3.5;
>
> global_settings {
>   assumed_gamma 1.0
>   photons {
>    spacing 0.003 // quality (lower better)
>   }
> }
>
> // ----------------------------------------
>
> camera {
>   location  <0, 3, -3>
>   right     x*image_width/image_height
>   look_at   <0, 1, 0>
> }
>
> light_source {
>   <0,0,0>, color rgb 1
>   looks_like {cone {-x/2,1/4,x/2,1/2 pigment {rgb 1} finish {ambient
0.5}}}
>   spotlight
>   radius 6 falloff 8
>   point_at x
>   rotate 45*y translate <-3, 0, 3>
> }
>
> // ----------------------------------------
>
> plane {
>   y, -1
>   texture {
>     pigment { checker color rgb 1 color blue 1 scale 0.5 }
>   }
>   photons {
>    collect off // no photons gathered here
>   }
> }
>
> /* MIRROR */
> box {-1,1 scale <1,1,.1>
>  pigment {rgb 0}
>  finish {ambient 0 diffuse 0 reflection {0.1,1}}
>   photons { // make visible to light rays
>    target
>    reflection on
>    refraction off
>   }
> }
>
> /* SCREEN */
> box {-1,1 scale <1,1,.1>
>  pigment {rgb 1}
>  finish {ambient 0 diffuse 0.5}
>  rotate 45*y translate <3,0,3>
>   photons { // make visible to light rays
>    //target
>    collect on
>   }
> }
>
> /* PICTURE */
> box {
>   0, 1
>   clipped_by {plane {-z,0}}
>   texture {
>     pigment {
>       image_map {
>         gif "test.gif"
>         interpolate 2 // smooth it
>         once   // don't tile image, just one copy
>         filter 0 0.5  // make 1st color half transparent
>         filter 1 1  // make 2nd color mostly transparent
>         filter 2 0.75  // make 3rd color 3/4 transparent
>       }
>       // transform it to unit-size (-1 to +1)
>     }
>     finish { ambient 0.3 }
>   }
>       translate -0.5*(x+y) // center on the origin
>       scale 2              // make it unit-sized
>       /* now fit in front of light */
>   scale <1,1,0.1>/4 rotate -45*y translate <-2,0,2>
>   photons { // make visible to light rays
>    target
>    reflection off
>    refraction off
>    pass_through // let light pass by
>    collect off // no photons gathered here
>   }
> }
>
> /////////////////////////
>
> There might be such an example scene file someplace else but I went ahead
> with my on try anyhow.
>
> Again, you may have already realized how to do this but you did not say
> exactly. I wanted to prove it could be done to some extent myself anyhow,
> and of course, with enough photons packed into the area the "projected"
> could be fine enough. Only slower and slower to parse, perhaps, depending
on
> the complexity of the objects used.
>
> Bob H.
>
>

Post a reply to this message

"PR" <a> wrote in message news:3fa61ac0$1@news.povray.org...
> Thank's for the script i try and is working ...
>
> i have to do some test more i let you know

Great, and I'll probably be here sometimes if you do.  :)

Bob H.

Post a reply to this message