Very cool.  Inspired me to try it myself.  Lots of tricky settings that 
really fight each other, but I finally got one I'm happy with.  Now I'm 
going to spin it :-)

Thanks for the inspiration.  Keep it up!



PM 2Ring wrote:
> Here's one of my attempts to get a globe vaguely like NASA's Blue Marble
> image
> at http://earthobservatory.nasa.gov/Newsroom/BlueMarble/
> 
> Suggestions welcome!
> 
> 
> ------------------------------------------------------------------------

Post a reply to this message

Attachments:
Download 'earth2.jpg' (35 KB)

Preview of image 'earth2.jpg'

Bonsai <bon### [at] b0n541net> wrote:
> PM 2Ring wrote:
> > This engraved glass globe was done using normals... and a little dispersion.
>
> Very nice. Is it possible to get the source or a bigger version for
> destop background?

Thanks, Alain, Bonsai and Spock for your kind comments. I'll try tomorrow to
post the source, Bonsai. The problem is recreating the exact parameters,
because both of those glass globes were done with the same scene file...
I'm getting close, but I'm too tired, ATM.

In the meantime, here's a slightly larger one, using crackle.

#declare Shiny = finish{specular 1 roughness 3e-5}

#declare Reflective =
finish{
  Shiny
  //brilliance 3
  reflection {0.01, 1 fresnel on }
  ambient 0.1 diffuse 0.1
  conserve_energy
}

#declare TGlass =
texture{
  pigment{rgbf 1}
  finish{Reflective}
}

#declare TOcean =
texture{
  TGlass
}

#declare TLand =
texture{
  TGlass
  //normal{granite .1 scale  .025 bump_size 1}
  normal{crackle 1 scale  .025 bump_size 5}
}

#declare TPlanet =
texture {
  image_pattern{
    sys "EAlpha.bmp"
    map_type 1
    interpolate 2
  }
  texture_map
  {
    [.5 TOcean]
    [.5 TLand]
  }
}

Post a reply to this message

Attachments:
Download 'earthl1.png' (171 KB)

Preview of image 'earthl1.png'

Bonsai <bon### [at] b0n541net> wrote:
> PM 2Ring wrote:
> > This engraved glass globe was done using normals... and a little dispersion.
>
> Very nice. Is it possible to get the source or a bigger version for
> destop background?

Ok, I've pretty-much reconstructed the scene file, although the photons are
not exactly the same. I think my area-light parameter AL needs to be
higher.

I only have a slow processor & 256M RAM here at home, so if someone would
like to render this at high AA 1024x768 and post it here, I would
appreciate it. I'm currently rendering a closeup version (comment out the *
1.5 in camera location).

// ----------------------------------------
// Persistence of Vision Ray Tracer Scene Description File
// File: EarthKA.pov
// Vers: 3.6
// Desc: Translucent globe of the Earth, 'engraved' using bump_map
//       Image file from NASA's Blue Marble page
//
// Date: 2004.11.23
// Auth: PM 2Ring
//
// +W1024 +H768 +A0.025 +AM2 +R4 -D
//
// -f -A0.5 +AM2 +R1
//

#version 3.6; //Uses photons, fresnel & conserve_energy: buggy in 3.5

#declare Radio = 1;
#declare Photons = 1;
#declare Area_Lights = 1;

global_settings {
  assumed_gamma #if(Radio) 1 #else .45 #end

  #if(Photons)
    #declare PhotonFile = "EarthKA.ph";
    photons{
      #if(file_exists(PhotonFile))
        load_file PhotonFile
      #else
        save_file PhotonFile
      #end

      count 180000 / 4
      autostop 0
    }
  #end

  #if(Radio)
    radiosity {
      //pretrace_start 0.08
      pretrace_end   0.04
      count 180 // 250

      error_bound 1.15      //default 1.8
      low_error_factor 0.6
      adc_bailout 0.01

      always_sample off
      //normal on
  }
  #end

  max_trace_level 50
}

// ---Camera & Lights----------------------

camera {
  location  <-0.25, .5, -5> * .89 * 1.5
  right     x*image_width/image_height up y
  direction 2*z
  look_at   0
}

light_source {
  <-8, 30, .75> * .125
  rgb 1

  #if(Area_Lights)
    #declare AL = 7; //21;
    #declare ASize = .2;
    area_light x*ASize, z*ASize, AL, AL
    adaptive 1 //3
    jitter
    circular
    orient
  #end

  photons {
    reflection on
    refraction on
    #if(Area_Lights) area_light #end
  }
}

// ---Textures-----------------------------

#declare Reflective =
finish{
  specular 1 roughness 1e-4
  //metallic
  reflection {0.01, 1 fresnel on}
  ambient 0 diffuse 0
  conserve_energy
}

#declare NLand =
normal{
  bump_map{
    jpeg "land_shallow_topo_2048.jpg"
    map_type 1
    interpolate 2

    bump_size 5
  }
}

// ---Objects------------------------------

#declare Globe =
sphere {
  0, 1

  texture{
    pigment{rgbf 1}
    finish{Reflective}
    normal{NLand}
  }

  interior{
    ior 1.5
    #if(1)
      dispersion 1.02
      dispersion_samples 5

      fade_color rgb<0,0,1>
      fade_distance  6
      fade_power 1001
    #end
    #if(!Photons)caustics .3 #end
  }

 photons {
  target
  refraction on
  reflection on
  collect off
 }

  //rotate y * 235      //Atlantic
  rotate y * -90        //Africa
  //rotate y * 62       //Australia
  rotate x * -6 // 22.5
}

#declare Rad = 10;
#declare Room =
union{
  sphere{0, Rad inverse }
  box{<-Rad, -2,-Rad>, <Rad, -1, Rad>}

  pigment{rgb .75}
  finish{ambient 0.05 diffuse .65}
}

//---Scene--------------------------------

object{Room}
object{Globe}

// ----------------------------------------

Post a reply to this message

Attachments:
Download 'earthka7.jpg' (10 KB)

Preview of image 'earthka7.jpg'

All the spheres in this thread are great! 

Where do you get/generate the spherical mapping bitmap file?

Mike
--
http://povray.tashcorp.net

Post a reply to this message

Mike Kost <con### [at] povraytashcorpnet> wrote:
> All the spheres in this thread are great!

Thankyou! But we still haven't replicated the Blue Marble image...

> Where do you get/generate the spherical mapping bitmap file?

From NASA's Blue Marble page, mentioned in the opening post. There are all
sorts of fun maps there.

The one I've been using is

http://earthobservatory.nasa.gov/Newsroom/BlueMarble/Images/land_shallow_topo_2048.jpg
 (230 KB). There's also a 8192 by 4096 pixels (26.5 MB) TIFF version, if
you're really keen. :)

Here's a refractive translucent one, where the land & ocean have the same
transparency, unlike the first globe I posted.

Post a reply to this message

Attachments:
Download 'earthe1.jpg' (34 KB)

Preview of image 'earthe1.jpg'

I think the thing that's lacking from these Blue Marble attempts is that the
glass has no depth-based colour change.  Most coloured glass gets darker as the
depth increases.  Finding a way to do that which still renders fast could be
tricky though... hmm.

Lance.

Post a reply to this message

Lance Birch wrote:
> I think the thing that's lacking from these Blue Marble attempts is that the
> glass has no depth-based colour change.  Most coloured glass gets darker as the
> depth increases.  Finding a way to do that which still renders fast could be
> tricky though... hmm.
> 
> Lance.
> 
> 

No closer to the target, but now it spins.  Enjoy.

http://ca.geocities.com/spock19@rogers.com/index.html

Post a reply to this message

Lance Birch nous apporta ses lumieres en ce 2005-04-12 11:15:
> I think the thing that's lacking from these Blue Marble attempts is that the
> glass has no depth-based colour change.  Most coloured glass gets darker as the
> depth increases.  Finding a way to do that which still renders fast could be
> tricky though... hmm.
> 
> Lance.
> 
> 
fade_color [some colour]
fade_distance [some value]
fade_power 1 //linear relation, real world value. Suqare (2) is for light_source
fading.

Alain

Post a reply to this message

"Alain" <ele### [at] netscapenet> wrote in message
news:425db5ab$1@news.povray.org...
> Lance Birch nous apporta ses lumieres en ce 2005-04-12 11:15:
> > I think the thing that's lacking from these Blue Marble attempts is that the
> > glass has no depth-based colour change.  Most coloured glass gets darker as
the
> > depth increases.  Finding a way to do that which still renders fast could be
> > tricky though... hmm.
> >
> > Lance.
> >
> >
> fade_color [some colour]
> fade_distance [some value]
> fade_power 1 //linear relation, real world value. Suqare (2) is for
light_source fading.

I don't think this would produce results close enough to the NASA example
though.  I'm thinking media might be a better choice in this instance, to give
it more of a "dense" look.

Lance.

thezone - thezone.firewave.com.au

Post a reply to this message

Lance Birch nous apporta ses lumieres en ce 2005-04-13 23:00:
> "Alain" <ele### [at] netscapenet> wrote in message
> news:425db5ab$1@news.povray.org...
> 
>>Lance Birch nous apporta ses lumieres en ce 2005-04-12 11:15:
>>
>>>I think the thing that's lacking from these Blue Marble attempts is that the
>>>glass has no depth-based colour change.  Most coloured glass gets darker as
> 
> the
> 
>>>depth increases.  Finding a way to do that which still renders fast could be
>>>tricky though... hmm.
>>>
>>>Lance.
>>>
>>>
>>
>>fade_color [some colour]
>>fade_distance [some value]
>>fade_power 1 //linear relation, real world value. Suqare (2) is for
> 
> light_source fading.
> 
> I don't think this would produce results close enough to the NASA example
> though.  I'm thinking media might be a better choice in this instance, to give
> it more of a "dense" look.
> 
> Lance.
> 
> thezone - thezone.firewave.com.au
> 
> 
If you need the tinting to be more intense, you reduce the fade_distance. You may also
increase the 
fade_power.

Alain

Post a reply to this message