Bonsai <bon### [at] b0n541net> wrote:
> PM 2Ring wrote:
> > This engraved glass globe was done using normals... and a little dispersion.
>
> Very nice. Is it possible to get the source or a bigger version for
> destop background?

Ok, I've pretty-much reconstructed the scene file, although the photons are
not exactly the same. I think my area-light parameter AL needs to be
higher.

I only have a slow processor & 256M RAM here at home, so if someone would
like to render this at high AA 1024x768 and post it here, I would
appreciate it. I'm currently rendering a closeup version (comment out the *
1.5 in camera location).

// ----------------------------------------
// Persistence of Vision Ray Tracer Scene Description File
// File: EarthKA.pov
// Vers: 3.6
// Desc: Translucent globe of the Earth, 'engraved' using bump_map
//       Image file from NASA's Blue Marble page
//
// Date: 2004.11.23
// Auth: PM 2Ring
//
// +W1024 +H768 +A0.025 +AM2 +R4 -D
//
// -f -A0.5 +AM2 +R1
//

#version 3.6; //Uses photons, fresnel & conserve_energy: buggy in 3.5

#declare Radio = 1;
#declare Photons = 1;
#declare Area_Lights = 1;

global_settings {
  assumed_gamma #if(Radio) 1 #else .45 #end

  #if(Photons)
    #declare PhotonFile = "EarthKA.ph";
    photons{
      #if(file_exists(PhotonFile))
        load_file PhotonFile
      #else
        save_file PhotonFile
      #end

      count 180000 / 4
      autostop 0
    }
  #end

  #if(Radio)
    radiosity {
      //pretrace_start 0.08
      pretrace_end   0.04
      count 180 // 250

      error_bound 1.15      //default 1.8
      low_error_factor 0.6
      adc_bailout 0.01

      always_sample off
      //normal on
  }
  #end

  max_trace_level 50
}

// ---Camera & Lights----------------------

camera {
  location  <-0.25, .5, -5> * .89 * 1.5
  right     x*image_width/image_height up y
  direction 2*z
  look_at   0
}

light_source {
  <-8, 30, .75> * .125
  rgb 1

  #if(Area_Lights)
    #declare AL = 7; //21;
    #declare ASize = .2;
    area_light x*ASize, z*ASize, AL, AL
    adaptive 1 //3
    jitter
    circular
    orient
  #end

  photons {
    reflection on
    refraction on
    #if(Area_Lights) area_light #end
  }
}

// ---Textures-----------------------------

#declare Reflective =
finish{
  specular 1 roughness 1e-4
  //metallic
  reflection {0.01, 1 fresnel on}
  ambient 0 diffuse 0
  conserve_energy
}

#declare NLand =
normal{
  bump_map{
    jpeg "land_shallow_topo_2048.jpg"
    map_type 1
    interpolate 2

    bump_size 5
  }
}

// ---Objects------------------------------

#declare Globe =
sphere {
  0, 1

  texture{
    pigment{rgbf 1}
    finish{Reflective}
    normal{NLand}
  }

  interior{
    ior 1.5
    #if(1)
      dispersion 1.02
      dispersion_samples 5

      fade_color rgb<0,0,1>
      fade_distance  6
      fade_power 1001
    #end
    #if(!Photons)caustics .3 #end
  }

 photons {
  target
  refraction on
  reflection on
  collect off
 }

  //rotate y * 235      //Atlantic
  rotate y * -90        //Africa
  //rotate y * 62       //Australia
  rotate x * -6 // 22.5
}

#declare Rad = 10;
#declare Room =
union{
  sphere{0, Rad inverse }
  box{<-Rad, -2,-Rad>, <Rad, -1, Rad>}

  pigment{rgb .75}
  finish{ambient 0.05 diffuse .65}
}

//---Scene--------------------------------

object{Room}
object{Globe}

// ----------------------------------------

Post a reply to this message

Attachments:
Download 'earthka7.jpg' (10 KB)

Preview of image 'earthka7.jpg'