|
![](/i/fill.gif) |
OK, so I spend 2 hours rounding the S. Here is the result, rendered
without radiosity and with photons. (Changed light source position also.)
What do you think?
By the way, I would like to share with you the scene description of the
letter "S" object:
#declare ObjectS_Top =
merge
{
difference
{
merge
{
difference
{
merge
{
cylinder {<0*cm, +2*cm, -1*cm>, <0*cm, +2*cm,
+1*cm>, 3*cm + Radius} // Outside (Middle)
cylinder {<0*cm, +2*cm, -1*cm - Radius>, <0*cm, +2*cm, +1*cm
+ Radius>, 3*cm} // Outside (Edges)
torus {3*cm, Radius rotate +90*x translate <0*cm, +2*cm,
-1*cm>} // Front outer rounding
torus {3*cm, Radius rotate +90*x translate <0*cm, +2*cm,
+1*cm>} // Back outer rounding
}
cylinder {<0*cm, +2*cm, -2*cm>, <0*cm, +2*cm, +2*cm>, 1*cm -
Radius} // Center
cylinder {<0*cm, +2*cm, -1*cm>, <0*cm, +2*cm, -2*cm>, 1*cm} //
Front edge
cylinder {<0*cm, +2*cm, +1*cm>, <0*cm, +2*cm, +2*cm>, 1*cm} //
Back edge
}
torus {1*cm, Radius rotate +90*x translate <0*cm, +2*cm,
-1*cm>} // Front inner rounding
torus {1*cm, Radius rotate +90*x translate <0*cm, +2*cm,
+1*cm>} // Back inner rounding
}
box {<0*cm, -5*cm, -2*cm>, <+5*cm, +2*cm, +2*cm>} // Cutout
}
sphere {<+1*cm, +2*cm, -1*cm>, Radius} // Front Left Corner
sphere {<+3*cm, +2*cm, -1*cm>, Radius} // Front Right Corner
sphere {<+1*cm, +2*cm, +1*cm>, Radius} // Back Left Corner
sphere {<+3*cm, +2*cm, +1*cm>, Radius} // Back Right Corner
cylinder {<+1*cm, +2*cm, -1*cm>, <+3*cm, +2*cm, -1*cm>, Radius} //
Front Edge
cylinder {<+1*cm, +2*cm, +1*cm>, <+3*cm, +2*cm, +1*cm>, Radius} //
Back Edge
cylinder {<+1*cm, +2*cm, -1*cm>, <+1*cm, +2*cm, +1*cm>, Radius} //
Inside Edge
cylinder {<+3*cm, +2*cm, -1*cm>, <+3*cm, +2*cm, +1*cm>, Radius} //
Outside Edge
box {<+1*cm, +2*cm - Radius, -1*cm>, <+3*cm, +2*cm, +1*cm>}
}
#declare ObjectS =
merge
{
object {ObjectS_Top}
object {ObjectS_Top rotate 180*z}
}
The final object contains 8 spheres, 18 cylinders, 4 boxes and 8 torii.
That's a grand total of 38 objects.
...you can see why I only placed 19 of those by hand, and had POV-Ray
duplicate the rest for me! >_<
Note also the multiple levels of merges and differences necessary to
achieve the correct effect. (The innermost part is nested 6 levels deep!
Eeeps!!)
Post a reply to this message
Attachments:
Download 'invisible20.jpg' (49 KB)
Preview of image 'invisible20.jpg'
![invisible20.jpg](/povray.binaries.images/attachment/%3C447b5895%40news.povray.org%3E/invisible20.jpg?ttop=443866&toff=4450&preview=1)
|
![](/i/fill.gif) |