I've recently been working on a way to do metal wear and patina.  I
figured out a way to do it, using the blob_pattern.  It renders
extremely fast, and looks great too.
Here's an example image.  All textures Are procedural, no texmaps used.
Enjoy!


H.E. Day
<><

Post a reply to this message

Attachments:
Download 'fb.jpg' (17 KB)

Preview of image 'fb.jpg'

H.E. Day wrote:
> 
> I've recently been working on a way to do metal wear and patina.  I
> figured out a way to do it, using the blob_pattern.  It renders
> extremely fast, and looks great too.
> Here's an example image.  All textures Are procedural, no texmaps used.
> Enjoy!

I assume you're going to share this with us. If not...

(NOTE: This is an open threat mostly because I'm not very creative. I
want the code, though.)


Simon

Post a reply to this message

I'm with Simon ;)

It looks great!


Jon Hoskins

--
=====================================
 A webring for the artist in all of us:
 http://gxworkshop.9ug.com/webring.htm

 http://gxworkshop.9ug.com
=====================================
"Simon de Vet" <sde### [at] istarca> wrote in message
news:3A97FBE4.AED27AA4@istar.ca...
> H.E. Day wrote:
> >
> > I've recently been working on a way to do metal wear and patina.  I
> > figured out a way to do it, using the blob_pattern.  It renders
> > extremely fast, and looks great too.
> > Here's an example image.  All textures Are procedural, no texmaps used.
> > Enjoy!
>
> I assume you're going to share this with us. If not...
>
> (NOTE: This is an open threat mostly because I'm not very creative. I
> want the code, though.)
>
>
> Simon

Post a reply to this message

In article <3A97F575.E9C16D76@heday.freeservers.com>, "H.E. Day" 
<The### [at] hedayfreeserverscom> wrote:

> I've recently been working on a way to do metal wear and patina.  I
> figured out a way to do it, using the blob_pattern.  It renders
> extremely fast, and looks great too.

Hmm, a macro that uses the object pattern to place blob pattern 
components inside the object?

-- 
Christopher James Huff
Personal: chr### [at] maccom, http://homepage.mac.com/chrishuff/
TAG: chr### [at] tagpovrayorg, http://tag.povray.org/

<><

Post a reply to this message

"Chris Huff" wrote:
> "H.E. Day" wrote:
>
> > I've recently been working on a way to do metal wear and patina.
> > I figured out a way to do it, using the blob_pattern. It renders
> > extremely fast, and looks great too.
>
> Hmm, a macro that uses the object pattern to place blob pattern
> components inside the object?

Seems so. A brilliant idea indeed! Simple, flexible, easy to use, and
according to H.E. Day, fast.

Rune
--
\ Include files, tutorials, 3D images, raytracing jokes,
/ The POV Desktop Theme, and The POV-Ray Logo Contest can
\ all be found at http://rsj.mobilixnet.dk (updated January 28)
/ Also visit http://www.povrayusers.org

Post a reply to this message

You give me far too much credit.  This is simply a texture that reads the
information stored in a macro (cylinders in blob pattern format).
Bingo.  Instant metal wear.  I'll post code tomorrow. :)

H.E. Day
<><

Post a reply to this message

Looks pretty good. At the rate you're going a year from now we won't be able
to tell your stuff from photographs!

--
David Fontaine  <dav### [at] faricynet>  ICQ 55354965
My raytracing gallery:  http://davidf.faricy.net/

Post a reply to this message

This is excellent.

The way the edges and the centre of the surfaces have been polished, but
just in from the edges has a darker appearance ... Brilliant. The scratches
and scuffy on the surface I think are perhaps unneccesary, but do add to the
effect.

The only thing I would suggest is to turn the whole effect down a little,
but I'm sure you have only made the effect this strong for testing and
demonstration purposes.

Cant figure out how how you have done it, but I look forward to examining
the code when posted :)

Very good, I am much impressed.
--
Duncan Gray
(warning: may contain traces of nut)

Post a reply to this message

Here's the stuff I promised.  Note that in order for this to work, you need to
know where the edges of your object are.  But hey, you built it, right??

//Code Start, Simple Cube
#version unofficial MegaPov 0.7;
camera {
location <-3,2.5,-5>
direction 1
look_at 0
}
light_source {<20,20,-40>*200 rgb 1}
light_source {<20,20,-40>*200 rgb .5 shadowless}
light_source {<-10,2,0>*200 rgb .5 shadowless}
#declare Scratching =
texture {
pigment {bozo color_map {[.2 rgb 1.25][.25 rgbt 1]} scale <20,20,1> scale
1/10  rotate 71657}
finish {ambient 0 diffuse 1 phong .25 metallic}
}
#declare Scortching =
texture {
pigment {bozo color_map {[.275 rgbt <0,0,0,.75>][.375 rgbt <0,0,0,.625>][1
rgbt <0,0,0,1>]} scale <1,1,5> warp {turbulence 1/2} scale 1/3}
finish {ambient 0 diffuse 1 phong .25 metallic}
}
#declare Dirt =
texture {
pigment {bozo color_map {[0 rgbt <.5,.3,.2,.5>][.25 rgbt <.5,.3,.2,.875>][.5
rgbt <.5,.3,.2,1>]} scale <1,1,3> warp {turbulence 1} translate 45 scale 1/4}
finish {ambient 0 diffuse 1 phong .25 metallic}
}

#declare Base_Tex1 =
texture {
pigment {rgb 1/2}
finish {ambient 0 diffuse 1 phong .75 metallic}
}
texture {Scratching}
texture {Scratching rotate -56767}
texture {Scratching rotate 8967}
texture {Scortching scale 2*z}

#declare ScratchingPig =
pigment_map {[.25 rgbt 1][.35 bozo color_map {[.55 rgbt 1][.6 rgb 1]} scale
1/8 turbulence 1][.75 rgb 1.25]}
#declare DirtPig =
pigment_map {[0 rgbt <0,0,0,1>][.5 bozo color_map {[.25 rgbt <0,0,0,1>][.75
rgb <0,0,0,.625>]} scale 1/4 turbulence 1/2]}



#macro Edges(Radius,Strength)
//Upper
cylinder {<-1,1,-1>,<-1,1,1>,Radius, strength Strength density_function 0, 1}
cylinder {<-1,1,1>,<1,1,1>,Radius, strength Strength density_function 0, 1}
cylinder {<1,1,1>,<1,1,-1>,Radius, strength Strength density_function 0, 1}
cylinder {<1,1,-1>,<-1,1,-1>,Radius, strength Strength density_function 0, 1}
//Lower
cylinder {<-1,-1,-1>,<-1,-1,1>,Radius, strength Strength density_function 0,
1}
cylinder {<-1,-1,1>,<1,-1,1>,Radius, strength Strength density_function 0, 1}
cylinder {<1,-1,1>,<1,-1,-1>,Radius, strength Strength density_function 0, 1}
cylinder {<1,-1,-1>,<-1,-1,-1>,Radius, strength Strength density_function 0,
1}
//Middle
cylinder {<0,-1,0>,<0,1,0>,Radius, strength Strength density_function 0, 1
translate <1,0,1>}
cylinder {<0,-1,0>,<0,1,0>,Radius, strength Strength density_function 0, 1
translate <-1,0,1>}
cylinder {<0,-1,0>,<0,1,0>,Radius, strength Strength density_function 0, 1
translate <1,0,-1>}
cylinder {<0,-1,0>,<0,1,0>,Radius, strength Strength density_function 0, 1
translate <-1,0,-1>}
#end


box {-1,1
texture {Base_Tex1 scale 1/2 rotate 657}
texture {
pigment {
blob {Edges(.25,.75) threshold .1 max_density 1}
pigment_map {DirtPig}
}
finish {ambient 0 diffuse 1 phong .25 metallic}
}
texture {
pigment {
blob {Edges(.075,.75) threshold .1 max_density 1}
pigment_map {ScratchingPig}
}
finish {ambient 0 diffuse 1 phong .25 metallic}
}
}
//Code End

Have fun, and I hope this helps!


H.E. Day
<><

Post a reply to this message

In article <3A998895.8C45A04F@heday.freeservers.com>, "H.E. Day" 
<The### [at] hedayfreeserverscom> wrote:

> Here's the stuff I promised.  Note that in order for this to work, 
> you need to know where the edges of your object are.  But hey, you 
> built it, right??

I've made an attempt at a macro that automatically positions blob 
components using the object pattern to decide if a point was inside the 
object and how close to an edge it was. However, the parsing slowed down 
a lot, and the quality was pretty bad...and it wouldn't be as flexible 
as your method, anyway, since your method allows you to specify exactly 
where the "scorching" goes and what areas have been rubbed off.

-- 
Christopher James Huff
Personal: chr### [at] maccom, http://homepage.mac.com/chrishuff/
TAG: chr### [at] tagpovrayorg, http://tag.povray.org/

<><

Post a reply to this message