|
![](/i/fill.gif) |
"Marc-Hendrik Bremer" <Mar### [at] t-online de> wrote in message
news:3a8ae765@news.povray.org...
> Interesting! How is it done? Can you built a brick texture out of this -
> with less gradient than the build-in one? :-)
>
> Marc-Hendrik
>
>
It is actually a layered checker texture. Feel free to take a look at the
code.
About the brick I don't know, I was trying to make cloth to begin with and
thought about how to make it look like a weave. The code is brand new for
today.
/* Starts here pov 3.1G */
light_source {<10,10,10> rgb 2}
camera {location <3,3,3> look_at <2,2,0>}
#declare Weav_Scale = <.05,.05,10>;
/* RBG Brightness for color maps (srtings) */
#declare Wb_1 = 0;
#declare Wb_2 = 0.3;
#declare Wb_3 = 0.5;
#declare Wb_4 = 1.0;
#declare Wb_5 = 0.5;
#declare Wb_6 = 0.3;
#declare Wb_7 = 0;
/* RGB Color for color maps (strings)*/
/*Horizontal Color */
#declare Wc_R1 = .5;
#declare Wc_G1 = 0;
#declare Wc_B1 = 1;
/* Vertical Color */
#declare Wc_R2 = 1;
#declare Wc_G2 = .2;
#declare Wc_B2 = .5;
/* Color Map Distances */
#declare Wd_1=0.00;
#declare Wd_2=0.05;
#declare Wd_3=0.25;
#declare Wd_4=0.50;
#declare Wd_5=0.75;
#declare Wd_6=0.95;
#declare Wd_7=1.00;
#declare Weav_String1=pigment{
marble
rotate <0,0,90>
scale 2
color_map{
[Wd_1 rgbf <1,1,1,1>]
[Wd_2 rgbf <1,1,1,1>]
[Wd_2 rgb <Wc_R1 * Wb_2 ,Wc_G1 * Wb_2 ,Wc_B1 * Wb_2 >]
[Wd_3 rgb <Wc_R1 * Wb_3 ,Wc_G1 * Wb_3 ,Wc_B1 * Wb_3 >]
[Wd_4 rgb <Wc_R1 * Wb_4 ,Wc_G1 * Wb_4 ,Wc_B1 * Wb_4 >]
[Wd_5 rgb <Wc_R1 * Wb_5 ,Wc_G1 * Wb_5 ,Wc_B1 * Wb_5 >]
[Wd_6 rgb <Wc_R1 * Wb_6 ,Wc_G1 * Wb_6 ,Wc_B1 * Wb_6 >]
[Wd_6 rgbf <1,1,1,1>]
[Wd_7 rgbf <1,1,1,1>]
}}
#declare Weav_String2=pigment{
marble
scale 2
color_map{
[Wd_1 rgbf <1,1,1,1>]
[Wd_2 rgbf <1,1,1,1>]
[Wd_2 rgb <Wc_R2 * Wb_2 ,Wc_G2 * Wb_2 ,Wc_B2 * Wb_2 >]
[Wd_3 rgb <Wc_R2 * Wb_3 ,Wc_G2 * Wb_3 ,Wc_B2 * Wb_3 >]
[Wd_4 rgb <Wc_R2 * Wb_4 ,Wc_G2 * Wb_4 ,Wc_B2 * Wb_4 >]
[Wd_5 rgb <Wc_R2 * Wb_5 ,Wc_G2 * Wb_5 ,Wc_B2 * Wb_5 >]
[Wd_6 rgb <Wc_R2 * Wb_6 ,Wc_G2 * Wb_6 ,Wc_B2 * Wb_6 >]
[Wd_6 rgbf <1,1,1,1>]
[Wd_7 rgbf <1,1,1,1>]
}}
/* Bottom Layer */
#declare Weav_l1= texture{pigment { checker
pigment {Weav_String2}
,
pigment {Weav_String1}
scale Weav_Scale
}}
/*Top Layer*/
#declare Weav_l2= texture{ pigment {checker
pigment {Weav_String1}
,
pigment {Weav_String2}
scale Weav_Scale
}}
#declare Weav=
texture {pigment {rgb <1,1,0> }}
texture {Weav_l1}
texture {Weav_l2}
box { <-2,-2,-1>,<2,2,.2>
texture {Weav rotate <45,45,0>}
}
sphere {<0,0,0>,1
texture {Weav translate <-1,0,-1>}
rotate <0,0,45>
translate <-1,0,1>
}
background {rgb 1}
Post a reply to this message
|
![](/i/fill.gif) |