|
|
|
|
|
|
| |
| |
|
|
|
|
| |
| |
|
|
[Image]
Here is the source - I want something like a lattice here, with all the
'joints' here connected together. I am just trying desperately to tweak
the numbers in.
--
Bryan Valencia
Post a reply to this message
Attachments:
Download 'us-ascii' (1 KB)
Download 'c:\temp\nsmaile6.gif' (1 KB)
Download 'c:\temp\nsmail7u.jpeg.jpg' (51 KB)
Preview of image 'c:\temp\nsmaile6.gif'
Preview of image 'c:\temp\nsmail7u.jpeg.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
oops, here is the source
plane{y,0 pigment{color rgb .5} finish{reflection .2} normal{checker
.4}}
light_source{<-80,100,-90> color rgb 1}
#declare h=1;
#declare mh=100;
blob{threshold .1
#while (h<mh)
#declare f=(mh-h)/mh;
#declare a=sin(h)*5*f;
#declare b=(h)/5;
#declare c=cos(h)*5*f;
sphere{<a,b,c>,f/2,f*20}
#declare h=h+.5;
#end
pigment{color rgb 1}
}
camera{location<0,5,-20> look_at<0,4,0>}
sky_sphere{pigment{color rgb<.5,.1,.8>}}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Hi Bryan.
You need to increase the radii of
your sphere components.
In order for sphere components in a
blob to "connect", they must have so
large radii, that if they were "real"
spheres they would "tuch" each other.
(Hmmm... That's quite bad english,
I suppose :)
--
Best regards,
Tor Olav
mailto:tor### [at] hotmailcom
http://hjem.sol.no/t-o-k/tokpicts.html
http://www.crosswinds.net/~tok
Bryan Valencia wrote:
>
> oops, here is the source
>
> plane{y,0 pigment{color rgb .5} finish{reflection .2} normal{checker
> .4}}
> light_source{<-80,100,-90> color rgb 1}
>
> #declare h=1;
> #declare mh=100;
>
> blob{threshold .1
> #while (h<mh)
> #declare f=(mh-h)/mh;
> #declare a=sin(h)*5*f;
> #declare b=(h)/5;
> #declare c=cos(h)*5*f;
> sphere{<a,b,c>,f/2,f*20}
> #declare h=h+.5;
> #end
>
> pigment{color rgb 1}
>
> }
>
> camera{location<0,5,-20> look_at<0,4,0>}
>
> sky_sphere{pigment{color rgb<.5,.1,.8>}}
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Tor Olav Kristensen wrote:
>
> Hi Bryan.
>
> You need to increase the radii of
> your sphere components.
>
> In order for sphere components in a
> blob to "connect", they must have so
> large radii, that if they were "real"
> spheres they would "tuch" each other.
>...
And of course their summed "field
strength" in the "connection region"
must be greater than the threshold
for the blob.
Best regards,
Tor Olav
mailto:tor### [at] hotmailcom
http://hjem.sol.no/t-o-k/tokpicts.html
http://www.crosswinds.net/~tok
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Bryan Valencia wrote:
> Here is the source - I want something like a lattice here,
> with all the 'joints' here connected together. I am just
> trying desperately to tweak the numbers in.
I fiddled with it a bit ...
blob {
threshold .4
#while (h<mh)
#declare f=(mh-h)/mh;
#declare a=sin(h)*5*f;
#declare b=(h)/5;
#declare c=cos(h)*5*f;
sphere{<a,b,c>,1.5*f,1}
#declare h=h+.5;
#end
pigment {color rgb 1}
}
It appears to me that f (multiplied by whatever constant) is the Wrong
Thing for the component radius, unless you want the lattice to break up
at the top.
--
Anton Sherwood -- br0### [at] p0b0xcom -- http://ogre.nu/
Post a reply to this message
Attachments:
Download 'bryan.jpg' (14 KB)
Preview of image 'bryan.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Anton Sherwood wrote:
> It appears to me that f (multiplied by whatever constant)
> is the Wrong Thing for the component radius, unless you want
> the lattice to break up at the top.
But if the radius is constant, the lattice gets thicker at the top.
I see the problem now: the vertical spacing is constant (0.5) but the
horizontal spacing shrinks (in proportion to the diameter of the cone).
Will elliptical components do?:
#declare h=1;
#declare mh=100;
blob {
threshold .5
#while (h<mh)
#declare f=(mh-h)/mh;
#declare a=sin(h)*5*f;
#declare b=(h)/5;
#declare c=cos(h)*5*f;
// sphere{<a,b,c>,f/2,f*20}
sphere { 0,1.5,1
scale <f,1,f>
translate <5*f,b,0>
rotate y*degrees(h)
}
#declare h=h+.5;
#end
pigment {color rgb 1}
}
--
Anton Sherwood -- br0### [at] p0b0xcom -- http://ogre.nu/
Post a reply to this message
Attachments:
Download 'bryan1.jpg' (13 KB)
Preview of image 'bryan1.jpg'
|
|
| |
| |
|
|
|
|
| |
| |
|
|
This is (MUCH) closerto what I want. Thanks to all who helped.
The effect I am going for is more of an alien "oil rig" (more sinewy, or like
bones) but the concept of the spheres having to touch each other is what I
didnt get. I was trying to "project" the blob out from the spheres, not
encase the 'energy' in the spheres. I have been struggling with this concept
for a while now.
--
Bryan Valencia
Post a reply to this message
|
|
| |
| |
|
|
|
|
| |
| |
|
|
Bryan Valencia wrote:
> The effect I am going for is more of an alien "oil rig"
> (more sinewy, or like bones) ...
alien, eh?
#declare h=1;
#declare mh=100;
#declare goldangle = pi*(3-sqrt(5));
blob {
threshold .86
#declare theta = 0;
#while (h<mh)
#declare f=(mh-h)/mh;
#declare g = sqrt(f);
#declare zed = 20*(1-g);
sphere { 0,1.18,1
translate <5*g,zed,0>
rotate y*degrees(theta)
}
#declare theta = theta + goldangle;
#declare h=h+.5;
#end
pigment { bozo
color_map {
[0 rgb 1]
[1 rgb <0.6,0.2,0>]
}
}
}
--
Anton Sherwood -- br0### [at] p0b0xcom -- http://ogre.nu/
Post a reply to this message
Attachments:
Download 'bryan2.jpg' (15 KB)
Preview of image 'bryan2.jpg'
|
|
| |
| |
|
|
|
|
| |
|
|