Still playing with the X', tying to make a texture with it. But I encounter 
black lines and can't find a reason for it in the scene. What causes it? Or 
is it inaccuracy of Povray (MegaPov)?

Ingo

#version unofficial MegaPov 0.5;
global_settings {assumed_gamma 1.0}
light_source {
   < 500,500,-500>
   rgb 1
}
camera {
   location  <0,0,-6.0>
   look_at   <0,0, 0.0>
}

#declare Letter= text {
//X: <0,0,0>,<0.70314,0.6773,1>
   ttf                       
   "times.ttf"
   "X"
   1,0
   scale <1/0.7,1/0.66,1> //<1/0.7,1/0.665,1>
   translate <0,0,-0.5>
}

/*#declare xPigm= function {
   pigment {
   	proximity {
   	   Letter, 0.2
   		method 0
   		samples 5  //25
   		sample_bailout 500
   		max_density 1.0 	
   		type 1				
   		sides 1				
   	}
      warp {repeat x}
      warp {repeat y}   	
   }
}*/

#declare xPigm= function {
   pigment {
      object { 
         Letter
         pigment {rgb 1}
         pigment {rgb 0}
      }
      warp {repeat x}
      warp {repeat y}
   } 
}

#declare xWrink= function {
   pigment {
      agate
      colour_map {
         [0, rgb 0]
         [1, rgb 0.8]
      }
   }
}

#declare XsinPigm= pigment {
   function {xPigm(sin(x),sin(y)^2,z) & xWrink(x,y,z)}
   scale 1  //0.6
   //rotate <90,0,0>
   colour_map {
      [0, rgb 1]
      [1, rgb 0]
   }
}

box {
   <-7.5,-5,0>,<7.5,5,0.1>
   pigment {XsinPigm}
}


-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message

Attachments:
Download 'XXX#3.jpg' (22 KB)

Preview of image 'XXX#3.jpg'

In article <8F3BD8EFAseed7@204.213.191.228>, ing### [at] homenl (ingo) 
wrote:

> Still playing with the X', tying to make a texture with it. But I 
> encounter black lines and can't find a reason for it in the scene. 
> What causes it? Or is it inaccuracy of Povray (MegaPov)?

It is a precision problem, similar to the coincident surfaces problem. 
Try replacing xPigm with this version, scaled and translated to avoid 
the problem:
#declare xPigm =
function {
    pigment {
        object {Letter
            pigment {rgb 1}
            pigment {rgb 0}
        }
        warp {repeat x}
        warp {repeat y}
        scale < 1, 1.00002, 1>
        translate < 0,-0.00001, 0>
    } 
}

-- 
Christopher James Huff - Personal e-mail: chr### [at] yahoocom
TAG(Technical Assistance Group) e-mail: chr### [at] tagpovrayorg
Personal Web page: http://chrishuff.dhs.org/
TAG Web page: http://tag.povray.org/

Post a reply to this message

Chris Huff wrote:

>It is a precision problem, similar to the coincident surfaces problem. 
>Try replacing xPigm with this version, scaled and translated to avoid 
>the problem:
>

Thanks Chris, that does the trick.

Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message

I tried it with arial.ttf and i get them too....  strange... maybe it is the
way Povray(Megapov) reads the files....

ingo wrote:

> Still playing with the X', tying to make a texture with it. But I encounter
> black lines and can't find a reason for it in the scene. What causes it? Or
> is it inaccuracy of Povray (MegaPov)?
>
> Ingo
>
> #version unofficial MegaPov 0.5;
> global_settings {assumed_gamma 1.0}
> light_source {
>    < 500,500,-500>
>    rgb 1
> }
> camera {
>    location  <0,0,-6.0>
>    look_at   <0,0, 0.0>
> }
>
> #declare Letter= text {
> //X: <0,0,0>,<0.70314,0.6773,1>
>    ttf
>    "times.ttf"
>    "X"
>    1,0
>    scale <1/0.7,1/0.66,1> //<1/0.7,1/0.665,1>
>    translate <0,0,-0.5>
> }
>
> /*#declare xPigm= function {
>    pigment {
>         proximity {
>            Letter, 0.2
>                 method 0
>                 samples 5  //25
>                 sample_bailout 500
>                 max_density 1.0
>                 type 1
>                 sides 1
>         }
>       warp {repeat x}
>       warp {repeat y}
>    }
> }*/
>
> #declare xPigm= function {
>    pigment {
>       object {
>          Letter
>          pigment {rgb 1}
>          pigment {rgb 0}
>       }
>       warp {repeat x}
>       warp {repeat y}
>    }
> }
>
> #declare xWrink= function {
>    pigment {
>       agate
>       colour_map {
>          [0, rgb 0]
>          [1, rgb 0.8]
>       }
>    }
> }
>
> #declare XsinPigm= pigment {
>    function {xPigm(sin(x),sin(y)^2,z) & xWrink(x,y,z)}
>    scale 1  //0.6
>    //rotate <90,0,0>
>    colour_map {
>       [0, rgb 1]
>       [1, rgb 0]
>    }
> }
>
> box {
>    <-7.5,-5,0>,<7.5,5,0.1>
>    pigment {XsinPigm}
> }
>
> --
> Photography: http://members.home.nl/ingoogni/
> Pov-Ray    : http://members.home.nl/seed7/
>
>                 Name: XXX#3.jpg
>    XXX#3.jpg    Type: unspecified type (application/octet-stream)
>             Encoding: x-uuencode

Post a reply to this message