When a blob component with an individual texture is transformed after the
texture statement, the texture is transformed twize. It should only be
transformed once, so it follows the component.

I'm using beta 7 but the bug is also there in POV-Ray 3.1.

Example animation to demonstrate problem:

// +w160 +h120 +kff20
light_source {<1,2,-3>*1000, color 1.5}
background {color <0.3,0.5,0.8>}
blob {
   threshold 1
   sphere {
      0, 1, 2 scale <1,3,1>
      pigment {planar color_map {[0.9,color rgb 1][0.9,color red 1]}}
      translate y*clock // pigment translated twize!
   }
   translate <-3,0,7>
}
blob {
   threshold 1
   sphere {
      0, 1, 2 scale <1,3,1>
      pigment {planar color_map {[0.9,color rgb 1][0.9,color red 1]}}
      rotate 90*z*clock // pigment rotated twize!
   }
   translate <0,0,7>
}
blob {
   threshold 1
   sphere {
      0, 1, 2 scale <1,3,1>
      pigment {gradient y color_map {[0.8,color rgb 1][0.8,color red 1]}}
      scale 1+0.5*clock // pigment scaled twize!
   }
   translate <3,0,7>
}

Rune

Post a reply to this message

Rune wrote:

> When a blob component with an individual texture is transformed after the
> texture statement, the texture is transformed twize. It should only be
> transformed once, so it follows the component.

Hmm. Consider:

#include "colors.inc"
light_source {<1,2,-3>*1000, color 1.5}
background {color <0.3,0.5,0.8>}

#declare OddScale=<2.5,2.5,2.499999999999999>;
#declare OKScale= <2.5,2.5,2.4999999999999999>;

#declare piggy=pigment{
        gradient y
        pigment_map{
                [0.5 Red]
                [0.5 Yellow]
                }
                scale 4 }

blob {
   threshold .5
   sphere {0, 1, 1 scale OddScale
          texture{pigment {piggy}}
          translate y*1 // pigment translated twize!
          }
   translate <-3,2,10>
}
blob {
   threshold .5
   sphere {0, 1, 1 scale OddScale
          texture{pigment {piggy}}
          }
   translate <0,2,10>
   translate y*1 // pigment OK!
}
blob {
   threshold .5
   sphere {0, 1, 1 scale OddScale
          texture{pigment {piggy}}
          }
   translate <3,2,10>
}

blob {
   threshold .5
   sphere {0, 1, 1 scale OKScale
          texture{pigment {piggy}}
          translate y*1// pigment OK!
          }
   translate <-3,-2,10>
}
blob {
   threshold .5
   sphere {0, 1, 1 scale OKScale
          texture{pigment {piggy}}
          }
   translate <0,-2,10>
   translate y*1 // pigment OK!
}
blob {
   threshold .5
   sphere {0, 1, 1 scale OKScale
          texture{pigment {piggy}}
          }
   translate <3,-2,10>         // pigment OK!
}

cylinder{<-10, 6,10>,<10, 6,10>,.07 }
cylinder{<-10, 4,10>,<10, 4,10>,.07 }
cylinder{<-10, 2,10>,<10, 2,10>,.07 }
cylinder{<-10, 0,10>,<10, 0,10>,.07 }
cylinder{<-10,-2,10>,<10,-2,10>,.07 }
cylinder{<-10,-4,10>,<10,-4,10>,.07 }
cylinder{<-10,-6,10>,<10,-6,10>,.07}

Post a reply to this message

"Greg M. Johnson" wrote:
> Hmm. Consider:

Interesting that variance in the scaling can trigger the bug...

Here's a shorter and clearer example:

light_source {<1,2,-3>*1000, color 1.5}
background {color <0.3,0.5,0.8>}
#declare OddScale=<2.5,2.5,2.499999999999999>;
#declare OKScale= <2.5,2.5,2.4999999999999999>;
#declare piggy=
pigment{
   gradient y
   pigment_map{[0.5,red 1][0.5,rgb <1,1,0>]}
}
blob {
   threshold .5
   sphere {
      0, 2, 1 scale OKScale
      texture {pigment {piggy}}
      rotate 45*z // pigment OK!
   }
   translate <+3,0,10>
}
blob {
   threshold .5
   sphere {
      0, 2, 1 scale OddScale
      texture {pigment {piggy}}
      rotate 45*z // pigment rotated twize!
   }
   translate <-3,0,10>
}

Post a reply to this message

Could somebody please confirm this bug?

Rune
--
3D images and anims, include files, tutorials and more:
Rune's World:    http://rsj.mobilixnet.dk (updated Nov 5)
POV-Ray Users:   http://rsj.mobilixnet.dk/povrayusers/
POV-Ray Webring: http://webring.povray.co.uk

Post a reply to this message

> Could somebody please confirm this bug?

I'm not sure whether Greg Johnson's post confirmed the bug, but anyway, I
can confirm it. POV-Ray 3.5 beta 8, Win98 SE, Athlon 700, 256 MB.

Post a reply to this message

"Anders K." wrote:
> I'm not sure whether Greg Johnson's post confirmed the bug

I think it did, but the bug was just listed as not confirmed today, so I
guessed somebody had to explicitly say "I confirm".

Anyway, thanks for confirming, both.

Rune
--
3D images and anims, include files, tutorials and more:
Rune's World:    http://rsj.mobilixnet.dk (updated Nov 5)
POV-Ray Users:   http://rsj.mobilixnet.dk/povrayusers/
POV-Ray Webring: http://webring.povray.co.uk

Post a reply to this message