|
 |
Bob Hughes <per### [at] aol com?subject=pov-news:> wrote:
: I'm missing Fe. and Mar. here, I was looking for those related postings too.
: Warp was faking it with multiple cylinders if IIRC.
FAKING!!! Who do you think I am? Those are TRUE photons. Period :)
The image can be found here: http://www.cs.tut.fi/~warp/photontest.jpg
And if you don't believe it's made with photons, here is the proof: The
source code:
#version Unofficial MegaPov 0.5;
#include "colors.inc"
#include "textures.inc"
#declare UsePhotons=yes;
global_settings
{
max_trace_level 8
#if(UsePhotons)
photons
{ count 20000
autostop 0
media 100
}
#end
}
box
{ <-4,-3,-1.5>,<8,3,1.5> hollow
pigment { rgbt 1 }
photons { pass_through }
interior
{ media
{ intervals 10
scattering { 1, rgb .5 extinction .01 }
method 3
}
}
}
sphere
{ 0,70 inverse
pigment
{ bozo color_map { [0 rgb 0][1 rgb <1,.5,0>] }
scale <5,10,5>
}
}
camera
{ location -z*20 look_at 0 angle 35
}
light_source
{ <50,2,0> 1
spotlight point_at y*2 radius .5 falloff .6
}
light_source
{ <100,100,-100>*.3 .8 media_interaction off
#if(UsePhotons)
photons { reflection off refraction off }
#end
}
#declare MirrorBox=
union
{ difference
{ box { <-.5,-1.8,-1.8><.1,1.8,1.8> }
box { <-.1,-1.5,-1.5><.11,1.5,1.5> }
pigment { DMFWood4 }
}
box
{ <-.1,-1.5,-1.5><0,1.5,1.5>
pigment { rgb 0 }
finish { reflection 1 diffuse 0 ambient 0 }
#if(UsePhotons)
photons
{ target
refraction off
reflection on
ignore_photons
}
#end
}
}
object
{ MirrorBox
rotate z*-45
translate <-3,2,0>
}
object
{ MirrorBox
rotate z*45
translate <-3,-2,0>
}
box
{ <-.5,-1.5,-1.5><0,1.5,1.5>
pigment { Cherry_Wood scale .5 }
rotate z*180
translate <5,-2,0>
}
sphere
{ 0,1.3 scale <.3,1,1>
pigment { rgbf <.7,.9,1,.9> }
finish { specular .5 reflection .1 }
interior { ior 1.5 }
translate <2,-2,0>
#if(UsePhotons)
photons
{ target
refraction on
reflection on
}
#end
}
--
main(i,_){for(_?--i,main(i+2,"FhhQHFIJD|FQTITFN]zRFHhhTBFHhhTBFysdB"[i]
):_;i&&_>1;printf("%s",_-70?_&1?"[]":" ":(_=0,"\n")),_/=2);} /*- Warp -*/
Post a reply to this message
|
|
|
|
> Renders fine for me. Maybe you should check your .ini settings and make
> sure you're not using quality 1 or something.
Believe me, I'm sure ;)
There was nothing specified, which means it should default to 9, which it
does indicate in the messages window, but still it was black. So I tried
putting +Q9 as command line parameter, still black. +Q10, still black.
Anyway, it's not too important.
On an unrelated note, you mentioned that you modified the source code to get
uv_mapping working for type 2 bicubic patches, could you send me the
files?(Actually to someone else ;) I know someone who has successfully
compiled POV (Win) and is willing to try with this modification. If you
agree, I'll let you know his e-mail so you can send it to him directly,
avoiding the middle man :)
Post a reply to this message
|
|
