POV-Ray : Newsgroups : irtc.stills : Uploaded source has dissappeared Server Time
28 Mar 2024 11:47:06 EDT (-0400)
  Uploaded source has dissappeared (Message 1 to 10 of 12)  
Goto Latest 10 Messages Next 2 Messages >>>
From: Nekar Xenos
Subject: Uploaded source has dissappeared
Date: 2 Jul 2010 07:49:51
Message: <op.ve7sg5vgufxv4h@go-dynamite>
I uploaded my source files as a zip file, when submitting my entry. Now I  
see there is no source file available when voting.

-Nekar Xenos-


Post a reply to this message

From: Nekar Xenos
Subject: Re: Uploaded source has dissappeared
Date: 2 Jul 2010 08:12:15
Message: <op.ve7tihvdufxv4h@go-dynamite>
On Fri, 02 Jul 2010 13:49:43 +0200, Nekar Xenos <nek### [at] gmailcom>  
wrote:

> I uploaded my source files as a zip file, when submitting my entry. Now  
> I see there is no source file available when voting.
>
> -Nekar Xenos-

I also had this problem with my entry to the "space" round.

-Nekar Xenos-


Post a reply to this message

From: Paolo Gibellini
Subject: Re: Uploaded source has dissappeared
Date: 2 Jul 2010 10:34:29
Message: <4c2df8f5$1@news.povray.org>
>Nekar Xenos  on date 02/07/2010 14:12 wrote:
> On Fri, 02 Jul 2010 13:49:43 +0200, Nekar Xenos <nek### [at] gmailcom>
> wrote:
>
>> I uploaded my source files as a zip file, when submitting my entry.
>> Now I see there is no source file available when voting.
>>
>> -Nekar Xenos-
>
> I also had this problem with my entry to the "space" round.
>
> -Nekar Xenos-
I hope that your sources will re-appear soon: I like a lot your image 
and I'm curious to see the soil texture.
;-)
Paolo


Post a reply to this message

From: Nekar Xenos
Subject: Re: Uploaded source has dissappeared
Date: 3 Jul 2010 02:42:21
Message: <op.ve88wrpaufxv4h@xena>
On Fri, 02 Jul 2010 16:34:49 +0200, Paolo Gibellini  
<p.g### [at] gmailcom> wrote:

>  >Nekar Xenos  on date 02/07/2010 14:12 wrote:
>> On Fri, 02 Jul 2010 13:49:43 +0200, Nekar Xenos <nek### [at] gmailcom>
>> wrote:
>>
>>> I uploaded my source files as a zip file, when submitting my entry.
>>> Now I see there is no source file available when voting.
>>>
>>> -Nekar Xenos-
>>
>> I also had this problem with my entry to the "space" round.
>>
>> -Nekar Xenos-
> I hope that your sources will re-appear soon: I like a lot your image  
> and I'm curious to see the soil texture.
> ;-)
> Paolo

Here it is - just in case it doesn't get sorted out ;)

////////////////////////Begin code/////////////////////////

// First define the colours with a spline
  #declare Fract_colors =spline {linear_spline 2,<.11,.1,.09>*.001,   
7,<.15,.13,.1> };

#macro FracTex(Recursions)
      #local Count=0;

      #while (Count<Recursions)
       crackle
       //rotate Count*30
       //triangle_wave
       warp{turbulence .3}
       scale .5
       texture_map{[0 pigment{ rgb Fract_colors(Count)}
                      normal{crackle (Recursions-Count)*.5 slope_map {[0  
<-1,1>][.1 <1,-1>][1 <0,0>]}}
                    ]
                   [.1

       #local Count=Count+1;
      #end

      pigment{rgb  Fract_colors(Count) }
      normal{ crackle  Count/.5 slope_map {[0 <-1,1>][.1 <1,-1>][1 <0,0>]} }

      #while (Count>0)
       ]
       }
      #local Count=Count-1;
      #end


#end


plane{y,0 texture{Fractex(5)}}


//////////////end code//////////////////////////

-- 
-Nekar Xenos-

"The spoon is not real"


Post a reply to this message

From: Nekar Xenos
Subject: Re: Uploaded source has dissappeared
Date: 3 Jul 2010 12:09:04
Message: <op.ve9y5dmvufxv4h@xena>
On Fri, 02 Jul 2010 13:49:43 +0200, Nekar Xenos <nek### [at] gmailcom>  
wrote:

> I uploaded my source files as a zip file, when submitting my entry. Now  
> I see there is no source file available when voting.
>
> -Nekar Xenos-

I've uploaded the source-code to povray.binaries.scene-files for anyone  
that's interested.

-- 
-Nekar Xenos-

"The spoon is not real"


Post a reply to this message

From: Paolo Gibellini
Subject: Re: Uploaded source has dissappeared
Date: 5 Jul 2010 03:24:55
Message: <4c3188c7$1@news.povray.org>
>Nekar Xenos  on date 03/07/2010 08:42 wrote:
> On Fri, 02 Jul 2010 16:34:49 +0200, Paolo Gibellini
> <p.g### [at] gmailcom> wrote:
>
>> >Nekar Xenos on date 02/07/2010 14:12 wrote:
>>> On Fri, 02 Jul 2010 13:49:43 +0200, Nekar Xenos <nek### [at] gmailcom>
>>> wrote:
>>>
>>>> I uploaded my source files as a zip file, when submitting my entry.
>>>> Now I see there is no source file available when voting.
>>>>
>>>> -Nekar Xenos-
>>>
>>> I also had this problem with my entry to the "space" round.
>>>
>>> -Nekar Xenos-
>> I hope that your sources will re-appear soon: I like a lot your image
>> and I'm curious to see the soil texture.
>> ;-)
>> Paolo
>
> Here it is - just in case it doesn't get sorted out ;)
>
Thank you, I'll study it carefully,
;-)
Paolo


Post a reply to this message

From: Thomas de Groot
Subject: Re: Uploaded source has dissappeared
Date: 22 Jul 2010 05:04:34
Message: <4c4809a2$1@news.povray.org>
"Nekar Xenos" <nek### [at] gmailcom> schreef in bericht 
news:op.ve88wrpaufxv4h@xena...
> Here it is - just in case it doesn't get sorted out ;)
>
> ////////////////////////Begin code/////////////////////////
>
> // First define the colours with a spline
>  #declare Fract_colors =spline {linear_spline 2,<.11,.1,.09>*.001, 
> 7,<.15,.13,.1> };
>
> #macro FracTex(Recursions)
>      #local Count=0;
>
>      #while (Count<Recursions)
>       crackle
>       //rotate Count*30
>       //triangle_wave
>       warp{turbulence .3}
>       scale .5
>       texture_map{[0 pigment{ rgb Fract_colors(Count)}
>                      normal{crackle (Recursions-Count)*.5 slope_map {[0 
> <-1,1>][.1 <1,-1>][1 <0,0>]}}
>                    ]
>                   [.1
>
>       #local Count=Count+1;
>      #end
>
>      pigment{rgb  Fract_colors(Count) }
>      normal{ crackle  Count/.5 slope_map {[0 <-1,1>][.1 <1,-1>][1 
> <0,0>]} }
>
>      #while (Count>0)
>       ]
>       }
>      #local Count=Count-1;
>      #end
>
>
> #end
>
>
> plane{y,0 texture{Fractex(5)}}
>
>
> //////////////end code//////////////////////////

Hm.... this does not seem to work, possibly because the while loops are 
nested in a bizarre way (at least to me)? When using *as is* I get a parse 
error.

Thomas


Post a reply to this message

From: Thomas de Groot
Subject: Re: Uploaded source has dissappeared
Date: 22 Jul 2010 05:13:33
Message: <4c480bbd@news.povray.org>
"Nekar Xenos" <nek### [at] gmailcom> schreef in bericht 
news:op.ve88wrpaufxv4h@xena...
> plane{y,0 texture{Fractex(5)}}
>

From reading your source file, this is the offending line :-)

Fractex() should be called inside a texture_map instead.

Thomas


Post a reply to this message

From: Nekar Xenos
Subject: Re: Uploaded source has dissappeared
Date: 23 Jul 2010 07:08:05
Message: <op.vgamja01ufxv4h@go-dynamite>
On Thu, 22 Jul 2010 11:13:32 +0200, Thomas de Groot  
<tDOTdegroot@interdotnlanotherdotnet> wrote:

>
> "Nekar Xenos" <nek### [at] gmailcom> schreef in bericht
> news:op.ve88wrpaufxv4h@xena...
>> plane{y,0 texture{Fractex(5)}}
>>
>
> From reading your source file, this is the offending line :-)
>
> Fractex() should be called inside a texture_map instead.
>
> Thomas
>
>
My apologies, I was in a rush. try this:


///////////////////////////////////////////////////////////////////////////////

global_settings {
   radiosity{normal on}
}

// ----------------------------------------

camera {
   location  <0.0, 1, -4.0>
   direction 1.5*z
   right     x*image_width/image_height
   look_at   <0.0, 1,  0.0>
}

sky_sphere {
   pigment {
     gradient y
     color_map {
       [0.0 rgb <0.6,0.7,1.0>]
       [0.7 rgb <0.0,0.1,0.8>]
     }
   }
}

light_source {
   <0, 0, 0>            // light's position (translated below)
   color rgb <1, 1, 1>  // light's color
   translate <-30, 30, -30>
}

// ----------------------------------------



// ----------------------------------------




// First define the colours with a spline
  #declare Fract_colors =spline {linear_spline 2,<.11,.1,.09>*.001,   
7,<.15,.13,.1>*9 };

#macro FracTex(Recursions)
      #local Count=0;

      #while (Count<Recursions)
       crackle
       //rotate Count*30
       //triangle_wave
       warp{turbulence .3}
       scale .5
       texture_map{[0 pigment{ rgb Fract_colors(Count)}
                      normal{crackle (Recursions-Count)*.5 slope_map {[0  
<-1,1>][.1 <1,-1>][1 <0,0>]}}
                    ]
                   [.1

       #local Count=Count+1;
      #end

      pigment{rgb  Fract_colors(Count) }
      normal{ crackle  Count/.5 slope_map {[0 <-1,1>][.1 <1,-1>][1 <0,0>]} }


      #while (Count>0)
       ]
       }
      #local Count=Count-1;
      #end


#end


plane{y,0 texture{FracTex(5)} scale .5}

  #declare Fract_colors =spline {linear_spline 2,<.3,.02,.01>,  9,<1,.4,.2>  
};

sphere {
   0.0, 1
   texture{FracTex(7)}
translate y
}

//////////////end code//////////////////////////


Post a reply to this message

From: Thomas de Groot
Subject: Re: Uploaded source has dissappeared
Date: 24 Jul 2010 02:55:29
Message: <4c4a8e61$1@news.povray.org>
"Nekar Xenos" <nek### [at] gmailcom> schreef in bericht 
news:op.vgamja01ufxv4h@go-dynamite...
> My apologies, I was in a rush. try this:

Thnak you indeed! This works fine. Very ingenious code I must say. I shall 
have to study it a bit longer before I fully understand it though. That is 
part of the never ending learning process :-)

Thomas


Post a reply to this message

Goto Latest 10 Messages Next 2 Messages >>>

Copyright 2003-2023 Persistence of Vision Raytracer Pty. Ltd.