In article <3a186773@news.povray.org>, "David Vincent-Jones" 
<geo### [at] galaxynetcom> wrote:

> I am using a series of coloured lights as a part of the scene that 
> are not used to illuminate the area around. Rather like street lights 
> during the daylight hours........ I am using the Light_Fading to keep 
> control over the output.
> 
> However, from any distance the light simply gets lost so I need some 
> sort of a 'halo' effect to juice up the local area.

There are several options:
The "highlight glow" method: You can put a transparent sphere with a 
highlight around the light, the highlight will make a glow that appears 
to surround the light source.
sphere {LightPos, MaxGlowSize
    texture {
        pigment {color White filter 1}
        finish {specular 1 roughness 0.025}
    }
}
Adjust the size of the sphere and the roughness value to get the desired 
effect. Phong highlights should work as well, I just prefer to use 
specular. :-)
One problem: if you have multiple light sources, you will get multiple 
highlights on each sphere. You might be able to get around this, or at 
least reduce it, with fancy bounding, or you may decide it isn't a 
problem...


The "media ball" method: You can put a sphere filled with a spherical 
density emitting media around the light source:
sphere {LightPos, MaxGlowSize
    texture {pigment {color White filter 1}}
    hollow
    interior {
        media {
            emission color LightColor
            density {spherical color_map {[0 rgb 0][1 rgb 1]}}
        }
    }
}
Emitting media is fairly fast, and this method is very versatile because 
you can do many effects with different color_maps and turbulence.


The glow patch: A recent addition to MegaPOV is the glow patch:
light_source {...
    glow {size 1 type 0}
}
You can simply specify the glows separately, if you don't need actual 
light sources, which can be useful because many lights can really slow 
things down. Using this patch is probably the easiest way, but the glow 
patch is still quite unfinished. It will give results that are a bit 
more accurate than the "highlight glow" or "media ball" methods


And most accurate but slowest, you can fill your scene with scattering 
media, the best way is usually to put the media in a box or other 
container surrounding your scene.

Parameters for media will depend on your scene and what version of POV 
you are using. You may want to get MegaPOV for it's glow patch or the 
new media sampling methods, which can let you get much smoother and 
faster results from media.

-- 
Christopher James Huff
Personal: chr### [at] maccom, http://homepage.mac.com/chrishuff/
TAG: chr### [at] tagpovrayorg, http://tag.povray.org/

<><

Post a reply to this message