Slawek:

Here's a diamond macro I wrote some time back.  I believe I used ideal values when I
created it.
It's been a while, so I don't recall for sure if everything is accurate.  You're
welcome to use it
in any way that you see fit.


//------------------------------------------------------------
// diamond macro
//------------------------------------------------------------

#macro RoundBrilliantDiamond ()
  #local Loop = 0;
  difference {
    box { -<0.5, 1, 0.5>, <0.5, 0.162, 0.5> }
    #while ( Loop < 8 )
      // bezel
      plane { -y, 0 rotate x * -34.5 translate -z * 0.500 rotate y * Loop * 45 }
      // star
      plane { -y, 0 rotate x * -19.5 translate -z * 0.700 rotate y * (Loop * 45 +
22.5) }
      // upper girdle
      plane { -y, 0 rotate x * -39.0 translate -z * 0.491 rotate y * (Loop * 45 +
11.25) }
      plane { -y, 0 rotate x * -39.0 translate -z * 0.491 rotate y * (Loop * 45 -
11.25) }
      // pavilion
      plane { y, 0 rotate x * 41 translate -z * 0.500 rotate y * Loop * 45 }
      // lower girdle
      plane { y, 0 rotate x * 43 translate -z * 0.491 rotate y * (Loop * 45 + 11.25) }
      plane { y, 0 rotate x * 43 translate -z * 0.491 rotate y * (Loop * 45 - 11.25) }
      #local Loop = Loop + 1;
    #end
  }
#end



Kyle

Post a reply to this message