in news:3B2F6AFD.128F9B9F@gmx.net Thomas wrote:

> But since I'm
> using a big angle (80) I get a bit of a distorted image, things that
> should look straight are pointing inwards.

See example below.
You can also wrap your whole scene in a union and 'shear' that in the 
opposite direction.

---%<------%<---
//use -uv on commandline
#version 3.1;
global_settings {assumed_gamma 1.0}
light_source {<500,500,-500>,1}

#declare Shear= transform {
   matrix <  1,  0,  0,
             0,  1,  0.3333, //= look_at.y/location.z
             0,  0,  1,
             0,  0,  0 >
}

camera {
   location  <0.0, 0.01,-1.5>
   look_at   <0.0, 0.5, 0.0>
   angle 95
   transform Shear
}

plane { 
  y, 0
  texture {
    pigment {
        checker color rgb 1, color rgb <0, 0, 1> 
        scale 0.25
    }
  }
}
box {
  <-0.5,0,-0.5>,<0.5,1,0.5>
  pigment {rgb 1}
}
box {
  <-0.5,0,-0.5>,<0.5,1,0.5>
  scale 0.5
  translate <0.75,0,-0.5>
  pigment {rgb 1}
}
---%<------%<---

Ingo

-- 
Photography: http://members.home.nl/ingoogni/
Pov-Ray    : http://members.home.nl/seed7/

Post a reply to this message