M_a_r_c wrote:

> 

> news:44831f90@news.povray.org...
>> Probably this should go to p.newusers, but I can't seem
>> to find anything in the manual.
>>
> You could want to have a look at this page :-)
> http://www.oyonale.com/ressources/english/sources09.htm
> 
> Marc

Having tried this, it got me half way there,
The isosurface takes the image_map function and looks
fine, but I needed to duplicate the technique to get
the ambient map to colour the surface.

I now have:

#local hf_fn = function {
    pigment {
        image_map {
            jpeg "moonbump4k"
            map_type 1
            interpolate 2
        }
    }
}

#local pg_fn = function {
    pigment {
        image_map {
            jpeg "albedo.simp750.jpeg"
            map_type 1
            interpolate 2
        }
    }
}

#local rs = 0.002;

#declare Luna = isosurface {
    function{
        f_sphere(x, y, z, 1) + rs - hf_fn(x,y,z).gray * rs
    }
    // contained_by { sphere { 0, 1.2 } }
    max_gradient 1.810
    texture {
        pigment {
            function { pg_fn(x, y, z).gray }
        }
        finish {
            ambient VeryDarkBlue
            diffuse 1.0
            specular 0.1
            roughness 0.35
        }
    }
    rotate -90 * y
}


Weird thing is the contained_by { sphere 0, 1 }  was clipping,
I had to change it to sphere { 1, 1.2 } to reduce that, then
commenting it out altogether seemed to fix it.

I am using megapov, maybe there's a difference in behaviour.
Anyway, I have a moon that looks great, so thanks again for
the pointers.

-- 
Bill Hails
http://billhails.net/

Post a reply to this message