It's no doubt something that can't be described easily, it kind of sounds
like you expect radiosity to be a light source.

When you say "too dark" that means you aren't seeing a brightness you
expect, something which others might not expect to see in a sunlit room with
no other light sources except for the Sun through a window. If the room has
dark texturing it will of course still be darkened even though sunlight
shines in, and if it is a bright white interior it could almost glow in
places where the sunlight shines. However, it's a visual thing. The eyes
adjust to it in various ways. Try the following scene and see what you
think; you'll probably need to show a rendering of what you don't want and
describe how it should be altered, or make changes to it to show how it
ought to look.
You mentioned diffuse values up to 1 but not over one. Perfectly legal to
use diffuse 1.1 and beyond. I'm thinking that the problem there is how the
radiosity is going to blend everything together. It usually shows most at
very short distances and tapers off abruptly. I'm not sure of how to go
about counteracting that effect and instead get a uniform, farther reaching
effect.

#version 3.5;

global_settings {
        radiosity {
                brightness 0.9
                recursion_limit 3
                gray_threshold 0.3
                media on
        }
}

// ----------------------------------------

camera {
  location  <-1, 2, -6>
  right     x*image_width/image_height
  look_at   <0,0,0>
}

// sky
sphere {
        0,1
  pigment {
    gradient y
    color_map {
      [0 rgb <0.8,0.9,1.0>]
      [0.7 rgb <0.3,0.5,0.9>]
      [1 rgb <0.2,0.4,0.7>]
    }
  }
  finish {ambient 0.9 diffuse 0.1}
  scale 9999
 hollow
}

// sunlight
light_source {
        0,<1.5,1.3,1.1>
        looks_like {
                sphere {0,99 pigment {rgb 1} finish {ambient 1 diffuse 1}}
                }
        parallel
        point_at z
 translate -999*z rotate <30,45,0>
}

// ground
plane {
  y, -0.01
  pigment { color rgb <0.3,0.7,0.4> }
}

// ----------------------------------------

// visibility test objects
#local W=5;
#while (W>-5)
sphere {
  0,0.5
  translate W*z
        pigment {checker color rgb 0 color rgb 1 scale 0.25}
        finish {ambient 0.1 diffuse 0.6} // defaults
}
#local W=W-1;
#end

// room with 4 windows
difference {
box {
        <-3,0,-9>,<3,3,3>
}
box {
        <-3,0.1,-9>/1.1,<3,3,3>/1.1
}
box {
        <-3.1,1,-2>,<3.1,2,-1>
}
box {
        <-3.1,1,1>,<3.1,2,2>
}

        pigment {rgb 0.9}
        finish {ambient 0.25 diffuse 0.75 specular 0.1 roughness 0.1}
 hollow
}

// air in room
box {
        <-3,0,-9>,<3,3,3>
        pigment {rgbf 1}
        interior {
                media {
                        emission 0.6
                        absorption 0.9
                        scattering {
                                5,3
                                eccentricity 0.3 // use with type 5
                                extinction 0
                        }
                        density {
                                rgb 0.1
                        }
                        samples 30,60
                }
        }
 hollow
}

Post a reply to this message