Josh English wrote:

> Bozo and Crackle? how about something like this, which I adapted from
> Rune's incredible pigment:

Interesting... Not exactly what I'm looking for but this could be useful.
Here is another version  (try the different patterns) :
#version 3.1
#include "colors.inc"
global_settings{  assumed_gamma 1.0}
camera{ location  <0.0, 0.5, -4.0>  direction 1.5*z  right     4/3*x
look_at   <0.0, 0.0,  0.0>}
light_source{  0*x   color red 1.0  green 1.0  blue 1.0    translate <-30,
30, -30>}
#declare MyPigment =
   pigment {
      granite scale 5
//      bozo scale 1
//      wrinkles scale 1.2
//      agate scale 2
//      crackle scale 1.2
//      dents scale 1.5
//      wood triangle_wave rotate <60,40,0> scale 2

      pigment_map {
         #declare X = 0;
         #declare Y = 255;
         #declare rd=seed(0);
         #while (X<Y)
            #declare V = X/Y;
            [V,
               crackle scale (0.3*V+0.2)*0.4 // rotate 30*z
               color_map {
                  [0, color rgb Black]
                  [1, color rgb <rand(rd),1,rand(rd)+0.5>*1.5]
               }
            ]
            #declare X = X+1;
         #end
      }

      scale 0.4
   }

sphere { 0.0, 1 texture {pigment{MyPigment}  finish{specular 0.5 roughness
0.001}} }
plane{z,0 texture {pigment{MyPigment}  finish{specular 0.5 roughness 0.001}}
}

Post a reply to this message