"Chris Huff" wrote:
> "Rune" wrote:
>
> > Isn't lowering the strength of all components basically the same as
> > increasing the threshold? I think multiplying the strengths of all the
> > components with 2 give the same result as dividing the threshold with 2.
> > Is that correct?
>
> Not quite. The falloff curve is kind of S-shaped, it isn't linear, so
> the way the components blob together and the distance of the surface
> from their centers will change.

The shape of the falloff curve is irrelevant.

As long as 2 function remains the same *relative to each other*
the intersection points remains the same. The code below proves it.

The first row shows blobs where both the threshold and the strengths
increase with the same amount from left to right. The blob remain the same.

The second row shows blobs with increasing threshold, and the third row
shows blobs with decreasing strength. You can see that the two rows look
exactly the same.

light_source {<1,2,-3>*10, color 1}
#default {pigment {color rgb 1}}
#declare X = 1;
#declare Y = 7;
#while (X<Y)
   blob {
      threshold 1*X
      sphere {x, 1.5, 2*X rotate 000*z}
      sphere {x, 1.5, 2*X rotate 120*z}
      sphere {x, 1.5, 2*X rotate 240*z}
      scale 0.2
      translate <(X/Y)*6-3,+1.5,5>
   }
   blob {
      threshold 1*X
      sphere {x, 1.5, 8 rotate 000*z}
      sphere {x, 1.5, 8 rotate 120*z}
      sphere {x, 1.5, 8 rotate 240*z}
      scale 0.2
      translate <(X/Y)*6-3,0,5>
   }
   blob {
      threshold 1
      sphere {x, 1.5, 8/X rotate 000*z}
      sphere {x, 1.5, 8/X rotate 120*z}
      sphere {x, 1.5, 8/X rotate 240*z}
      scale 0.2
      translate <(X/Y)*6-3,-1.5,5>
   }
   #declare X = X+1;
#end

Greetings,

Rune
--
Updated June 12: http://rsj.mobilixnet.dk
3D images, include files, stereograms, tutorials,
The POV Desktop Theme, The POV-Ray Logo Contest,
music, 350+ raytracing jokes, and much more!

Post a reply to this message