"Paul Jones" <pdj### [at] psuedu> wrote in message
news:391A0F33.9C7F229E@psu.edu...
>
> a while back in p.b.i there were some images of
> "lasers" using photons and media... how did you
> guys produce the light source which does not
> have a cone of reflected light associated with
> it??? I can't seem to get one to look good. Any
> special tricks?

Here's a scene I made recently.
http://www.datasync.com/~ericfree/graphics/dls/reflector.jpg

The "laser" was made with a regular point light placed 999900 units along
the X axis and lined up with the center of the laser gun barrel on the Y and
Z.  Just to the right of the laser is a large box with a hole in it to block
all light except that which goes thru the laser gun.

Here's a few code snippets to get you going:

[the mirror surface]
$MirrorMat = material {
  texture {
    pigment {White}
    finish {
      ambient 0
      diffuse 0
      reflection 1
      brilliance 6
      metallic
      reflect_metallic
    }
  }
}

[the box containing the media.  Note that the box stretches right to enclose
the laser light source, is slightly wider than the barrel of the laser gun
(HoleRad*2), and does not touch the wall, floor or ceiling]
$LaserLiteColor = Maroon*15.3;
$   MediaFactor = 0.00125;
box {
  <-RoomX1+0.001,-RoomY+0.001,-HoleRad*2>,
  <999990,RoomY-0.001,HoleRad*2>
  pigment {rgbf 1.0}
  hollow
  interior {
    ior 1
    media {
      intervals 3
      samples 1, 1
      confidence 0.995
      variance 1/256
      scattering {
        1,
        LaserLiteColor*MediaFactor
        extinction 0
      }
    }
  }
}

[the laser light]
light_source {
  <999900,0,0>, LaserLiteColor
  media_attenuation on
  photons {
    refraction off
    reflection on
  }
}

If you need more than this, the entire source code for the scene is in the
MegaPOV 0.5 demo files in the "photons" directory.  Look for "reflector.pov"

> -thanks

Yer welcome.

Eric
--------------------
http://www.datasync.com/~ericfree
--------------------
"I don't like it, and I'm sorry I ever had anything to do with it."
- Erwin Schrodinger talking about Quantum Mechanics.

Post a reply to this message