If I'm understanding you correctly, you want a texture that simulates laser
cuts from all angles? Well, I've made one in MegaPov. Most of the effects
shown are holes, but wouldn't that be the case in real life? If you have
time, render the code below to see it. Make sure to render the whole thing
if you do, because there is a nice gash near the bottom of the sphere.

#version unofficial megapov .5;

camera{location<0,5,-14> look_at 0 rotate y*-30}

light_source{<100,200,-50>,1}

#declare V=0;
#declare R=seed(9954);//change to another #'s for other random placements
#declare Dis=20;//change according to how large your object is

#declare Obj=
 union{
  #while(V<200)//change 200 to amount of 'holes 'n' scrapes' you want
   cylinder{
    <rand(R)*Dis-(Dis/2),rand(R)*Dis-(Dis/2),rand(R)*Dis-(Dis/2)>,
    <rand(R)*Dis-(Dis/2),rand(R)*Dis-(Dis/2),rand(R)*Dis-(Dis/2)>,.05
   }
   #declare V=V+1;
  #end
 }

#declare Scrapes= function{pigment{ object{Obj rgb 1, rgb .75} }}

sphere{0,4
 pigment{rgb 1}
 normal{function Scrapes}
}

--
Samuel Benge

E-Mail: STB### [at] aolcom

Visit my isosurface tutorial at http://members.aol.com/stbenge

Post a reply to this message