I've given this some thought and I suggest using a normal in the camera
statement, with a pattern like ripples being oriented in relation to
where the meteor path line of sight is at.  Might take a normal map of
some ingenious design to accomplish.
Well, maybe not ingenious, however here's something I tried just now.

Bob

/* example of creating shockwave in air (no vapor) */

global_settings {
        number_of_waves 0
}

#declare Amplitude=0.333; // amount of shockwave effect
#declare Frequency=6; // number of peaks and troughs
#declare xSize=0.5; // lengthwise curvature (or size)
#declare zSize=0.25; // crosswise curvature (more curve when less than
xSize)
#declare xPos=-2; // move ripples off-center
#declare Width=0.45; // pie-slice region of air displacement (<1.0 but
>0.5)
#declare EntryAngle=-30; // angle of attack
#declare Placement=<0.25,-0.075,0>; // offset from center, small values
of x and y (no z)

#declare N0=normal {ripples 0} // dummy normal
#declare N1=normal {ripples Amplitude frequency Frequency scale
<xSize,1,zSize> translate xPos*x}

camera {
        location 0
        look_at 1*z
        normal {radial normal_map {
                [Width N0][0.5 N1][1-Width N0]
        } ramp_wave rotate 90*x
         rotate EntryAngle*z translate Placement}
}

light_source {<10,10,-10>, 1}

sphere {0,1
        pigment {gradient y color_map {
                [0 color rgb <.9,.6,.3>]
                [.1 color rgb <.6,.3,.6>]
                [.3 color rgb <.4,.6,.8>]
                [.6 color rgb <.2,.4,.6>]
        }}
       finish {ambient .5}
    scale 1000
}

// meteor (test object: note that this really messes up if shockwave is
intense)
cone {-x,1,0,.1 scale <100,10,10>
        pigment {granite color_map {
                [0 color rgb <.9,.8,.7>]
                [1 color rgb <.7,.6,.4>]
        }}
       finish {ambient .75}
     rotate EntryAngle*z translate <25,-5,100> // placing this is only a
guess
 no_shadow
}

"kane" <ann### [at] mindspringcom> wrote in message
news:392b3ffd@news.povray.org...
|     I'm trying to create the disturbance to the atmosphere as a meteor
| passes through it. Kind of like ripples in the air, that sort of
thing. Is
| there any way in Pov or MegPov to do this?

Post a reply to this message